1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164 | --
-- Copyright (C) 2022-2023, AdaCore
--
-- SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
--
with Ada.Streams.Stream_IO;
with VSS.Application;
with VSS.Stream_Element_Vectors.Conversions;
with VSS.Strings.Converters.Decoders;
with VSS.Strings.Conversions;
with Test_Support;
procedure Test_String_Decoder is
use type VSS.Strings.Virtual_String;
function Load
(File_Name : VSS.Strings.Virtual_String)
return VSS.Stream_Element_Vectors.Stream_Element_Vector;
procedure Run_Decoder_Block_Mode
(Encoding : VSS.Strings.Virtual_String;
Has_Error : Boolean;
Encoded : VSS.Stream_Element_Vectors.Stream_Element_Vector;
Decoded : VSS.Strings.Virtual_String);
procedure Run_Decoder_Incremental_Mode
(Encoding : VSS.Strings.Virtual_String;
Has_Error : Boolean;
Encoded : VSS.Stream_Element_Vectors.Stream_Element_Vector;
Decoded : VSS.Strings.Virtual_String);
----------
-- Load --
----------
function Load
(File_Name : VSS.Strings.Virtual_String)
return VSS.Stream_Element_Vectors.Stream_Element_Vector
is
use type Ada.Streams.Stream_Element_Offset;
File : Ada.Streams.Stream_IO.File_Type;
Buffer : Ada.Streams.Stream_Element_Array (1 .. 1024);
Last : Ada.Streams.Stream_Element_Offset;
begin
return Result : VSS.Stream_Element_Vectors.Stream_Element_Vector do
Ada.Streams.Stream_IO.Open
(File,
Ada.Streams.Stream_IO.In_File,
VSS.Strings.Conversions.To_UTF_8_String (File_Name));
loop
Ada.Streams.Stream_IO.Read (File, Buffer, Last);
exit when Last < Buffer'First;
Result.Append
(VSS.Stream_Element_Vectors.Conversions.To_Stream_Element_Vector
(Buffer (Buffer'First .. Last)));
end loop;
Ada.Streams.Stream_IO.Close (File);
end return;
end Load;
----------------------------
-- Run_Decoder_Block_Mode --
----------------------------
procedure Run_Decoder_Block_Mode
(Encoding : VSS.Strings.Virtual_String;
Has_Error : Boolean;
Encoded : VSS.Stream_Element_Vectors.Stream_Element_Vector;
Decoded : VSS.Strings.Virtual_String)
is
Decoder : VSS.Strings.Converters.Decoders.Virtual_String_Decoder;
Result : VSS.Strings.Virtual_String;
begin
Decoder.Initialize (Encoding);
Test_Support.Assert (Decoder.Is_Valid);
Result := Decoder.Decode (Encoded);
Test_Support.Assert (Result = Decoded);
Test_Support.Assert (Decoder.Has_Error = Has_Error);
if Has_Error then
Test_Support.Assert (not Decoder.Error_Message.Is_Empty);
else
Test_Support.Assert (Decoder.Error_Message.Is_Empty);
end if;
end Run_Decoder_Block_Mode;
----------------------------------
-- Run_Decoder_Incremental_Mode --
----------------------------------
procedure Run_Decoder_Incremental_Mode
(Encoding : VSS.Strings.Virtual_String;
Has_Error : Boolean;
Encoded : VSS.Stream_Element_Vectors.Stream_Element_Vector;
Decoded : VSS.Strings.Virtual_String)
is
use type Ada.Streams.Stream_Element_Offset;
Decoder : VSS.Strings.Converters.Decoders.Virtual_String_Decoder;
Result : VSS.Strings.Virtual_String;
begin
Decoder.Initialize (Encoding);
Test_Support.Assert (Decoder.Is_Valid);
for J in 1 .. Encoded.Length loop
Result.Append
(Decoder.Decode
(VSS.Stream_Element_Vectors.Conversions
.To_Stream_Element_Vector ([1 => Encoded (J)]),
J = Encoded.Length));
end loop;
Test_Support.Assert (Result = Decoded);
Test_Support.Assert (Decoder.Has_Error = Has_Error);
if Has_Error then
Test_Support.Assert (not Decoder.Error_Message.Is_Empty);
else
Test_Support.Assert (Decoder.Error_Message.Is_Empty);
end if;
end Run_Decoder_Incremental_Mode;
begin
declare
Encoding : constant VSS.Strings.Virtual_String :=
VSS.Application.Arguments.Element (1);
Has_Error : constant Boolean :=
Boolean'Wide_Wide_Value
(VSS.Strings.Conversions.To_Wide_Wide_String
(VSS.Application.Arguments.Element (2)));
Encoded : constant VSS.Stream_Element_Vectors.Stream_Element_Vector :=
Load (VSS.Application.Arguments.Element (3));
Decoded : constant VSS.Strings.Virtual_String :=
VSS.Strings.Conversions.To_Virtual_String
(VSS.Stream_Element_Vectors.Conversions.Unchecked_To_String
(Load (VSS.Application.Arguments.Element (4))));
begin
Test_Support.Assert (not Encoding.Is_Empty);
Test_Support.Assert (not Encoded.Is_Empty);
Test_Support.Assert (not Decoded.Is_Empty);
Run_Decoder_Block_Mode (Encoding, Has_Error, Encoded, Decoded);
Run_Decoder_Incremental_Mode (Encoding, Has_Error, Encoded, Decoded);
end;
end Test_String_Decoder;
|