1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299 | -- --
-- package Object.Archived Copyright (c) Dmitry A. Kazakov --
-- Implementation Luebeck --
-- Summer, 2003 --
-- --
-- Last revision : 20:41 21 Jul 2017 --
-- --
-- This library is free software; you can redistribute it and/or --
-- modify it under the terms of the GNU General Public License as --
-- published by the Free Software Foundation; either version 2 of --
-- the License, or (at your option) any later version. This library --
-- is distributed in the hope that it will be useful, but WITHOUT --
-- ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. You should have --
-- received a copy of the GNU General Public License along with --
-- this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
-- As a special exception, if other files instantiate generics from --
-- this unit, or you link this unit with other files to produce an --
-- executable, this unit does not by itself cause the resulting --
-- executable to be covered by the GNU General Public License. This --
-- exception does not however invalidate any other reasons why the --
-- executable file might be covered by the GNU Public License. --
--____________________________________________________________________--
with Ada.IO_Exceptions; use Ada.IO_Exceptions;
with Object.Archived.Sets; use Object.Archived.Sets;
with System; use System;
package body Object.Archived is
use Dispatch_Tables;
package Link_Handles is
new Object.Handle (Backward_Link, Backward_Link_Ptr);
use Link_Handles;
-- procedure Dump_List (Object : Deposit'Class) is
-- use Ada.Text_IO, Ada.Tags, System.Storage_Elements;
-- function "+" (Value : Address) return Integer_Address
-- renames To_Integer;
-- function Status (Link : Boolean) return String is
-- begin
-- if Link then
-- return "";
-- else
-- return "broken";
-- end if;
-- end Status;
-- This : Backward_Link_Ptr;
-- begin
-- Put_Line
-- ( "Object: "
-- & Expanded_Name (Object'Tag)
-- & " at"
-- & Integer_Address'Image (+Object'Address)
-- );
-- if Object.Delivery = null then
-- Put_Line (" no backward links");
-- else
-- This := Object.Delivery;
-- loop
-- Put_Line
-- ( " "
-- & Expanded_Name (This.all'Tag)
-- & Integer_Address'Image (+This.Prev.all'Address)
-- & " <-"
-- & Status (This.Prev.Next = This)
-- & Integer_Address'Image (+This.all'Address)
-- & " ->"
-- & Status (This.Next.Prev = This)
-- & Integer_Address'Image (+This.Next.all'Address)
-- );
-- This := This.Next;
-- exit when This = Object.Delivery;
-- end loop;
-- end if;
-- end Dump_List;
procedure Attach
( Link : Backward_Link_Ptr;
Object : Deposit_Ptr
) is
begin
Detach (Link.all);
if Object /= null then
Link.Object := Object;
if Object.Delivery = null then
Object.Delivery := Link;
Link.Next := Link;
Link.Prev := Link;
else
Link.Next := Object.Delivery; -- This -> List head
Link.Prev := Link.Next.Prev; -- List tail <- This
Link.Prev.Next := Link;
Link.Next.Prev := Link;
end if;
end if;
end Attach;
procedure Close (Object : in out Deposit'Class) is
This : Backward_Link_Ptr := Object.Delivery;
Lock : Link_Handles.Handle;
begin
while This /= null loop
Set (Lock, This);
Destroyed (This.all);
Detach (This.all);
This := Object.Delivery;
end loop;
end Close;
procedure Create
( Source : String;
Pointer : in out Integer;
Class : String;
List : Deposit_Container'Class;
Object : out Deposit_Ptr
) is
Constructor : Restore;
begin
begin
Constructor := Find (Dispatch_Table, Class);
exception
when End_Error =>
raise Name_Error;
end;
Constructor (Source, Pointer, Class, List, Object);
end Create;
procedure Delete (Object : in out Deposit'Class) is
procedure Free is
new Ada.Unchecked_Deallocation
( Backward_Link'Class,
Backward_Link_Ptr
);
begin
if Object.Delivery /= null then
declare
Set : Deposit_Set;
Handle : Link_Handles.Handle;
This : Backward_Link_Ptr := new Walker_Stub;
Next : Backward_Link_Ptr;
begin
--
-- The list of backward links can be modified while we are
-- walking down it. A stub backward link object is inserted
-- in the list. The object is pointed by This. This.Prev is
-- notified. Then This is moved forward in the list until it
-- becomes next the list head. This prevents list corruption
-- when some list elements are removed from or inserted into
-- the list upon notification.
--
This.Prev := Object.Delivery;
This.Next := Object.Delivery.Next;
This.Next.Prev := This;
This.Prev.Next := This;
This.Object := Object.Delivery.Object;
loop
Link_Handles.Set (Handle, This.Prev);
Deleted (Ptr (Handle).all, Set);
Next := This.Next;
exit when Next = Object.Delivery;
--
-- Moving This forward in the list
-- .______. .______. .______. .______.
-- |This. |-->| |-->| |-->|Next. |
-- | Prev| | This | | Next | | Next|
-- |______|<--|______|<--|______|<--|______|
--
-- .______. .______. .______. .______.
-- | |-->| |-->| |-->| |
-- | | | Next | | This | | |
-- |______|<--|______|<--|______|<--|______|
--
Next.Prev := This.Prev;
This.Prev.Next := Next;
This.Prev := Next;
This.Next := Next.Next;
Next.Next.Prev := This;
Next.Next := This;
end loop;
Free (This);
end;
end if;
end Delete;
procedure Deleted
( Link : in out Walker_Stub;
Temps : in out Deposit_Container'Class
) is
begin
null;
end Deleted;
procedure Destroyed (Link : in out Walker_Stub) is
begin
null;
end Destroyed;
procedure Detach (Link : in out Backward_Link) is
begin
if Link.Object /= null then
if Link.Next = Link.Next.Next then
Link.Object.Delivery := null; -- The only item
else
if Link.Next.Prev = Link.Object.Delivery then
Link.Object.Delivery := Link.Next; -- The first item
end if;
Link.Next.Prev := Link.Prev;
Link.Prev.Next := Link.Next;
end if;
Link.Object := null;
end if;
end Detach;
procedure Finalize (Object : in out Deposit) is
begin
Close (Object);
Finalize (Entity (Object));
end Finalize;
procedure Finalize (Link : in out Backward_Link) is
begin
Detach (Link);
Finalize (Entity (Link));
end Finalize;
procedure Get_Referents
( Object : Deposit;
Container : in out Deposit_Container'Class
) is
begin
null;
end Get_Referents;
function Is_Empty (Container : Deposit_Container'Class)
return Boolean is
begin
return Get_Size (Container) = 0;
end Is_Empty;
function Is_Registered (Class : String) return Boolean is
begin
return IsIn (Dispatch_Table, Class);
end Is_Registered;
procedure Register_Class
( Class : String;
Constructor : Restore
) is
begin
Add (Dispatch_Table, Class, Constructor);
exception
when Name_Error =>
if Find (Dispatch_Table, Class) /= Constructor then
raise;
end if;
end Register_Class;
function Self (Link : Backward_Link) return Backward_Link_Ptr is
begin
if Link.Object = null then
raise Constraint_Error;
else
return Link.Next.Prev;
end if;
end Self;
function This (Link : Backward_Link) return Deposit_Ptr is
begin
if Link.Object = null then
raise Constraint_Error;
else
return Link.Object;
end if;
end This;
function To_Object_Ptr (Link : Backward_Link_Ptr)
return Backward_Link_Ptr is
begin
return Link;
end To_Object_Ptr;
function "<" (Left, Right : Backward_Link_Ptr) return Boolean is
begin
return
( Right /= null
and then
( Left = null
or else
Left.all'Address < Right.all'Address
) );
end "<";
end Object.Archived;
|