1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492 | -- --
-- package Generic_Indefinite_Map Copyright (c) Dmitry A. Kazakov --
-- Implementation Luebeck --
-- Spring, 2012 --
-- --
-- Last revision : 22:41 09 Mar 2020 --
-- --
-- This library is free software; you can redistribute it and/or --
-- modify it under the terms of the GNU General Public License as --
-- published by the Free Software Foundation; either version 2 of --
-- the License, or (at your option) any later version. This library --
-- is distributed in the hope that it will be useful, but WITHOUT --
-- ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. You should have --
-- received a copy of the GNU General Public License along with --
-- this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
-- As a special exception, if other files instantiate generics from --
-- this unit, or you link this unit with other files to produce an --
-- executable, this unit does not by itself cause the resulting --
-- executable to be covered by the GNU General Public License. This --
-- exception does not however invalidate any other reasons why the --
-- executable file might be covered by the GNU Public License. --
--____________________________________________________________________--
with Ada.Unchecked_Deallocation;
package body Generic_Indefinite_Map is
procedure Delete is
new Ada.Unchecked_Deallocation (Key_Type, Key_Type_Ptr);
procedure Delete is
new Ada.Unchecked_Deallocation (Object_Type, Object_Type_Ptr);
procedure Delete is
new Ada.Unchecked_Deallocation (Data, Data_Ptr);
procedure Delete is
new Ada.Unchecked_Deallocation (Token_Array, Token_Array_Ptr);
function Is_Empty (Container : Map) return Boolean is
begin
return
Container.Object = null or else Container.Object.Size = 0;
end Is_Empty;
function Is_In (Container : Map; Key : Key_Type)
return Boolean is
begin
return Find (Container, Key) > 0;
end Is_In;
procedure Replace
( Container : in out Map;
Index : Positive;
Item : Object_Type
) is
begin
if ( Container.Object = null
or else
Index > Container.Object.Size
)
then
raise Constraint_Error;
end if;
if Container.Object.Use_Count > 0 then
Clone (Container);
end if;
declare
Old : Object_Type_Ptr := Container.Object.Vector (Index).Item;
begin
Container.Object.Vector (Index).Item := new Object_Type'(Item);
Delete (Old);
end;
end Replace;
procedure Insert
( Container : in out Map;
Index : Positive;
Key : Key_Type;
Item : Object_Type
) is
begin
if Container.Object = null then
Container.Object := new Data;
elsif Container.Object.Use_Count > 0 then
Clone (Container);
end if;
declare
Object : Data renames Container.Object.all;
This : Token;
begin
This.Key := new Key_Type'(Key);
This.Item := new Object_Type'(Item);
if Object.Vector = null then
Object.Vector := new Token_Array (1..Minimal_Size);
Object.Vector (1) := This;
elsif Object.Size = Object.Vector'Last then
declare
Ptr : constant Token_Array_Ptr :=
new Token_Array
( 1
.. ( Object.Size
+ Natural'Max
( Minimal_Size,
( ( Object.Size
* (100 + Increment)
)
/ 100
) ) ) );
begin
Ptr (1..Index - 1) := Object.Vector (1..Index - 1);
Ptr (Index) := This;
Ptr (Index + 1..Object.Size + 1) :=
Object.Vector (Index..Object.Size);
Delete (Object.Vector);
Object.Vector := Ptr;
end;
else
Object.Vector (Index + 1..Object.Size + 1) :=
Object.Vector (Index..Object.Size);
Object.Vector (Index) := This;
end if;
Object.Size := Object.Size + 1;
exception
when others =>
Delete (This.Key);
Delete (This.Item);
raise;
end;
end Insert;
procedure Add
( Container : in out Map;
Items : Map
) is
begin
if ( Container.Object /= Items.Object
and then
not Is_Empty (Items)
)
then
declare
Vector : Token_Array renames Items.Object.Vector.all;
Index : Integer;
subtype Index_Range is Integer range Vector'Range;
Last : constant Index_Range := Items.Object.Size;
begin
for Item in Vector'First..Last loop
Index := Find (Container, Vector (Item).Key.all);
if Index <= 0 then
Insert
( Container => Container,
Index => -Index,
Key => Vector (Item).Key.all,
Item => Vector (Item).Item.all
);
end if;
end loop;
end;
end if;
end Add;
procedure Add
( Container : in out Map;
Key : Key_Type;
Item : Object_Type
) is
Index : constant Integer := Find (Container, Key);
begin
if Index <= 0 then
Insert
( Container => Container,
Index => -Index,
Key => Key,
Item => Item
);
else
raise Constraint_Error;
end if;
end Add;
procedure Adjust (Container : in out Map) is
begin
if Container.Object /= null then
Container.Object.Use_Count :=
Container.Object.Use_Count + 1;
end if;
end Adjust;
procedure Clone (Container : in out Map) is
begin
if ( Container.Object /= null
and then
Container.Object.Use_Count > 0
)
then
declare
Source : Data renames Container.Object.all;
Copy : constant Data_Ptr := new Data;
begin
Copy.Size := Source.Size;
if 0 /= Source.Size then
Copy.Vector := new Token_Array (1..Source.Size);
Copy.Vector.all := Source.Vector (1..Source.Size);
end if;
Source.Use_Count := Source.Use_Count - 1;
Container.Object := Copy;
end;
end if;
end Clone;
function Create return Map is
Result : Map;
begin
return Result;
end Create;
procedure Erase (Container : in out Map) is
begin
if Container.Object /= null then
if Container.Object.Use_Count > 0 then
Container.Object.Use_Count :=
Container.Object.Use_Count - 1;
Container.Object := null;
elsif Container.Object.Size > 0 then
declare
Vector : Token_Array renames Container.Object.Vector.all;
begin
for Item in 1..Container.Object.Size loop
Delete (Vector (Item).Key);
Delete (Vector (Item).Item);
end loop;
end;
Container.Object.Size := 0;
end if;
end if;
end Erase;
procedure Finalize (Container : in out Map) is
begin
if Container.Object /= null then
if Container.Object.Use_Count > 0 then
Container.Object.Use_Count :=
Container.Object.Use_Count - 1;
else
declare
Vector : Token_Array renames Container.Object.Vector.all;
begin
for Item in 1..Container.Object.Size loop
Delete (Vector (Item).Key);
Delete (Vector (Item).Item);
end loop;
end;
Delete (Container.Object.Vector);
Delete (Container.Object);
end if;
end if;
end Finalize;
function Find
( Vector : Token_Array;
Size : Positive;
Key : Key_Type
) return Integer is
From : Natural := 0;
To : Natural := Size + 1;
This : Natural;
begin
loop
This := (From + To) / 2;
if Key = Vector (This).Key.all then
return This;
elsif Key < Vector (This).Key.all then
if This - From <= 1 then
return -This;
end if;
To := This;
else
if To - This <= 1 then
return - This - 1;
end if;
From := This;
end if;
end loop;
end Find;
function Find (Container : Map; Key : Key_Type)
return Integer is
begin
if Is_Empty (Container) then
return -1;
else
return
Find
( Container.Object.Vector.all,
Container.Object.Size,
Key
);
end if;
end Find;
function Get (Container : Map; Key : Key_Type)
return Object_Type is
Index : constant Integer := Find (Container, Key);
begin
if Index <= 0 then
raise Constraint_Error;
end if;
return Container.Object.Vector (Index).Item.all;
end Get;
function Get (Container : Map; Index : Positive)
return Object_Type is
begin
if ( Container.Object = null
or else
Index > Container.Object.Size
)
then
raise Constraint_Error;
end if;
return Container.Object.Vector (Index).Item.all;
end Get;
function Get_Key (Container : Map; Index : Positive)
return Key_Type is
begin
if ( Container.Object = null
or else
Index > Container.Object.Size
)
then
raise Constraint_Error;
end if;
return Container.Object.Vector (Index).Key.all;
end Get_Key;
function Get_Size (Container : Map) return Natural is
begin
if Container.Object = null then
return 0;
else
return Container.Object.Size;
end if;
end Get_Size;
procedure Remove
( Container : in out Map;
Index : Positive
) is
begin
if ( Container.Object = null
or else
Index > Container.Object.Size
)
then
raise Constraint_Error;
else
Clone (Container);
declare
Object : Data renames Container.Object.all;
begin
Delete (Object.Vector (Index).Key);
Delete (Object.Vector (Index).Item);
Object.Vector (Index..Object.Size - 1) :=
Object.Vector (Index + 1..Object.Size);
Object.Size := Object.Size - 1;
end;
end if;
end Remove;
procedure Remove
( Container : in out Map;
Key : Key_Type
) is
Index : constant Integer := Find (Container, Key);
begin
if Index > 0 then
Remove (Container, Index);
end if;
end Remove;
procedure Remove
( Container : in out Map;
Items : Map
) is
begin
if Container.Object = Items.Object then
Erase (Container);
elsif not Is_Empty (Container) and then not Is_Empty (Items) then
declare
Vector : Token_Array renames Items.Object.Vector.all;
Index : Integer;
subtype Index_Range is Integer range Vector'Range;
Last : constant Index_Range := Items.Object.Size;
begin
for Item in Vector'First..Last loop
Index := Find (Container, Vector (Item).Key.all);
if Index > 0 then
Remove (Container, Index);
end if;
end loop;
end;
end if;
end;
procedure Replace
( Container : in out Map;
Items : Map
) is
begin
if ( Container.Object /= Items.Object
and then
not Is_Empty (Items)
)
then
declare
Vector : Token_Array renames Items.Object.Vector.all;
Index : Integer;
subtype Index_Range is Integer range Vector'Range;
Last : constant Index_Range := Items.Object.Size;
begin
for Item in Vector'First..Last loop
Index := Find (Container, Vector (Item).Key.all);
if Index > 0 then
Replace (Container, Index, Vector (Item).Item.all);
else
Insert
( Container => Container,
Index => -Index,
Key => Vector (Item).Key.all,
Item => Vector (Item).Item.all
);
end if;
end loop;
end;
end if;
end Replace;
procedure Replace
( Container : in out Map;
Key : Key_Type;
Item : Object_Type
) is
Index : constant Integer := Find (Container, Key);
begin
if Index > 0 then
Replace (Container, Index, Item);
else
Insert
( Container => Container,
Index => -Index,
Key => Key,
Item => Item
);
end if;
end Replace;
function "=" (Left, Right : Map) return Boolean is
begin
if Left.Object = Right.Object then
return True;
elsif Left.Object = null or else 0 = Left.Object.Size then
return Right.Object = null or else 0 = Right.Object.Size;
elsif Right.Object = null or else 0 = Right.Object.Size then
return False;
elsif Left.Object.Size /= Right.Object.Size then
return False;
else
declare
First : Token_Array renames Left.Object.Vector.all;
Second : Token_Array renames Right.Object.Vector.all;
begin
for Index in 1..Left.Object.Size loop
if ( First (Index).Key.all /= Second (Index).Key.all
or else
First (Index).Item.all /= Second (Index).Item.all
)
then
return False;
end if;
end loop;
end;
return True;
end if;
end "=";
end Generic_Indefinite_Map;
|