1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
1895
1896
1897
1898
1899
1900
1901
1902
1903
1904
1905
1906
1907
1908
1909
1910
1911
1912
1913
1914
1915
1916
1917
1918
1919
1920
1921
1922
1923
1924
1925
1926
1927
1928
1929
1930
1931
1932
1933
1934
1935
1936
1937
1938
1939
1940
1941
1942
1943
1944
1945
1946
1947
1948
1949
1950
1951
1952
1953
1954
1955
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967
1968
1969
1970
1971
1972
1973
1974
1975
1976
1977
1978
1979
1980
1981
1982
1983
1984
1985
1986
1987
1988
1989
1990
1991
1992
1993
1994
1995
1996
1997
1998
1999
2000
2001
2002
2003
2004
2005
2006
2007
2008
2009
2010
2011
2012
2013
2014
2015
2016
2017
2018
2019
2020
2021
2022
2023
2024
2025
2026
2027
2028
2029
2030
2031
2032
2033
2034
2035
2036
2037
2038
2039
2040
2041
2042
2043
2044
2045
2046
2047
2048
2049
2050
2051
2052
2053
2054
2055
2056
2057
2058
2059
2060
2061
2062
2063
2064
2065
2066
2067
2068
2069
2070
2071
2072
2073
2074
2075
2076
2077
2078
2079
2080
2081
2082
2083
2084
2085
2086
2087 | -- SPDX-License-Identifier: Apache-2.0
--
-- Copyright (c) 2021 onox <denkpadje@gmail.com>
--
-- Licensed under the Apache License, Version 2.0 (the "License");
-- you may not use this file except in compliance with the License.
-- You may obtain a copy of the License at
--
-- http://www.apache.org/licenses/LICENSE-2.0
--
-- Unless required by applicable law or agreed to in writing, software
-- distributed under the License is distributed on an "AS IS" BASIS,
-- WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-- See the License for the specific language governing permissions and
-- limitations under the License.
with Ada.Characters.Latin_1;
with Ada.Strings.Unbounded;
with Ada.Unchecked_Conversion;
with Orka.Numerics.Tensors.Operations;
package body Orka.Numerics.Tensors.SIMD_CPU is
procedure Swap_Rows (Ab : in out CPU_Tensor; I, J : Index_Type) is
begin
if I /= J then
declare
Row_I : constant CPU_Tensor := Ab (I);
Old_J : constant CPU_Tensor := Ab (J);
begin
Set (Ab, J, Row_I);
Set (Ab, I, Old_J);
end;
end if;
end Swap_Rows;
procedure Scale_Row (Ab : in out CPU_Tensor; I : Index_Type; Scale : Element) is
Row_I : constant CPU_Tensor := Ab (I);
begin
if Scale /= 1.0 then
Set (Ab, I, Scale * Row_I);
end if;
end Scale_Row;
procedure Replace_Row (Ab : in out CPU_Tensor; Scale : Element; I, J : Index_Type) is
Row_I : constant CPU_Tensor := Ab (I);
Row_J : constant CPU_Tensor := Ab (J);
begin
if Scale /= 0.0 then
Set (Ab, J, Row_J - Scale * Row_I);
end if;
end Replace_Row;
procedure Forward_Substitute (Ab : in out CPU_Tensor; Index, Pivot_Index : Index_Type) is
Rows : constant Natural := Ab.Rows;
Pivot_Value : constant Element := Ab ((Index, Pivot_Index));
begin
-- Create zeros below the pivot position
for Row_Index in Index + 1 .. Rows loop
Replace_Row (Ab, Ab ((Row_Index, Pivot_Index)) / Pivot_Value, Index, Row_Index);
end loop;
end Forward_Substitute;
procedure Back_Substitute (Ab : in out CPU_Tensor; Index, Pivot_Index : Index_Type) is
begin
Scale_Row (Ab, Index, 1.0 / Ab ((Index, Pivot_Index)));
-- Create zeros above the pivot position
for Row_Index in 1 .. Index - 1 loop
Replace_Row (Ab, Ab ((Row_Index, Pivot_Index)), Index, Row_Index);
end loop;
end Back_Substitute;
function Create_QR
(Q, R : CPU_Tensor;
Determinancy : Matrix_Determinancy) return CPU_QR_Factorization
is (Q_Size => Q.Size,
R_Size => R.Size,
Q => Q,
R => R,
Determinancy => Determinancy);
procedure Make_Upper_Triangular (Object : in out CPU_Tensor; Offset : Integer := 0) is
Rows : constant Natural := Object.Rows;
Columns : constant Natural := Object.Columns;
begin
if Offset >= -(Rows - 2) then
-- Make matrix upper triangular by zeroing out the elements in the
-- lower triangular part
for Row_Index in Index_Type'First + 1 - Integer'Min (1, Offset) .. Rows loop
for Column_Index in 1 .. Natural'Min (Row_Index - 1 + Offset, Columns) loop
Object.Set ((Row_Index, Column_Index), 0.0);
end loop;
end loop;
end if;
end Make_Upper_Triangular;
package Operations is new Orka.Numerics.Tensors.Operations
(CPU_Tensor, Make_Upper_Triangular, Scale_Row, Swap_Rows, Forward_Substitute, Back_Substitute,
Expression_Type, CPU_QR_Factorization, Create_QR, Q, R);
----------------------------------------------------------------------------
function Convert is new Ada.Unchecked_Conversion (Vector_Type, Integer_Vector_Type);
function Convert is new Ada.Unchecked_Conversion (Integer_Vector_Type, Vector_Type);
function From_Last (Offset : Natural) return Vector_Index_Type is
(Vector_Index_Type'Val (Vector_Index_Type'Pos (Vector_Index_Type'Last) - Offset));
function Data_Vectors (Index : Natural) return Natural is
((Index + (Vector_Type'Length - 1)) / Vector_Type'Length);
function Data_Vectors (Shape : Tensor_Shape) return Natural is
(Data_Vectors (Elements (Shape)));
function Data_Offset (Index : Positive) return Vector_Index_Type is
(Vector_Index_Type'Val ((Index - 1) mod Vector_Type'Length
+ Vector_Index_Type'Pos (Vector_Index_Type'First)));
function Data_Padding (Size, Count : Natural) return Natural is
(Size * Vector_Type'Length - Count);
function To_Index (Index : Tensor_Index; Columns : Positive) return Index_Type is
(To_Index (Index, (Index (1), Columns)))
with Pre => Index'Length = 2;
-- Index (1) isn't used for 2-D Index except in Pre condition of To_Index in parent package
function Reset_Padding
(Object : CPU_Tensor;
Padding : Natural;
Value : Element_Type) return Vector_Type
is
Last_Vector : Vector_Type := Object.Data (Object.Data'Last);
begin
if Padding /= 0 then
Last_Vector (From_Last (Padding - 1) .. Last_Vector'Last) := (others => Value);
end if;
return Last_Vector;
end Reset_Padding;
function Disable_Padding (Object : CPU_Tensor) return Vector_Type is
Padding : constant Natural :=
Data_Padding (Size => Object.Size, Count => Object.Elements);
begin
return Reset_Padding (Object, Padding, 0.0);
end Disable_Padding;
function Without_Data
(Object : CPU_Tensor;
Kind : Data_Type := Float_Type) return CPU_Tensor;
-- This silly definition is needed to avoid "length check failed" in GNAT FSF 11.1
function Without_Data
(Object : CPU_Tensor;
Kind : Data_Type := Float_Type) return CPU_Tensor
is
((Axes => Object.Axes,
Size => Object.Size,
Kind => Kind,
Shape => Object.Shape,
Data => <>));
function Without_Data
(Shape : Tensor_Shape;
Kind : Data_Type := Float_Type) return CPU_Tensor
is
((Axes => Shape'Length,
Size => Data_Vectors (Shape),
Kind => Kind,
Shape => Shape,
Data => <>));
----------------------------------------------------------------------------
-- Expressions --
----------------------------------------------------------------------------
function Identity_Vector_Type (Value : Element) return Vector_Type is (others => Value);
function Identity_Element (Value : Element) return Element is (Value);
function Apply is new Generic_Apply (Vector_Type, Identity_Vector_Type);
function Apply is new Generic_Apply (Element, Identity_Element,
Min => Element'Min, Max => Element'Max, Sqrt => EF.Sqrt);
----------------------------------------------------------------------------
overriding function Kind (Object : CPU_Tensor) return Data_Type is (Object.Kind);
overriding
function Get (Object : CPU_Tensor; Index : Index_Type) return Element renames Operations.Get;
overriding
function Get (Object : CPU_Tensor; Index : Index_Type) return Boolean renames Operations.Get;
overriding function Get (Object : CPU_Tensor; Index : Index_Type) return CPU_Tensor is
Count : constant Positive := Object.Columns;
Shape : constant Tensor_Shape := (1 => Count);
begin
if Index > Object.Rows then
raise Constraint_Error with
"Stop index (" & Trim (Index) & ") out of bounds (1 .. " & Trim (Object.Rows) & ")";
end if;
-- Returning the row of a 2D tensor as a vector instead of a (1, n) 2D tensor
return Result : CPU_Tensor := Without_Data (Shape, Object.Kind) do
declare
Result_Data : Element_Array (1 .. Count)
with Import, Convention => Ada, Address => Result.Data'Address;
Object_Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
Base_Index : constant Natural := (Index - 1) * Count;
begin
Result_Data (1 .. Count) := Object_Data (Base_Index + 1 .. Base_Index + Count);
end;
end return;
end Get;
overriding procedure Set
(Object : in out CPU_Tensor;
Index : Index_Type;
Value : CPU_Tensor) renames Operations.Set;
overriding procedure Set
(Object : in out CPU_Tensor;
Index : Range_Type;
Value : CPU_Tensor) renames Operations.Set;
overriding
procedure Set (Object : in out CPU_Tensor; Index : Tensor_Range; Value : CPU_Tensor) is
Full_Index : constant Tensor_Range := Full_Range (Object.Shape, Index);
Full_Value : constant Tensor_Shape := Full_Shape (Object.Axes, Value.Shape, Right);
pragma Assert (Full_Value = Shape (Full_Index));
begin
-- If the value (and shape of index) has the full depth/height/width except
-- for the first axis, then the memory to which the data will be written
-- is contiguous, which means it has no gaps.
--
-- For example, if shape of Value is (2, 3) and you have the following
-- object and index (in brackets):
--
-- 1 [ 2 3 4] 5
-- 6 [ 7 8 9] 10
-- 11 12 13 14 15
--
-- then there is a gap (positions 5 and 6). Howerver, if the shape
-- of Value is (2, 5) (with a matching Index) then there are no gaps.
--
-- Another case in which there are are no gaps is when all but the last
-- axis have a shape equal to 1. For example if the index is
-- ((2, 2), (7, 9)), which has the shape (1, 3).
if Is_Equal (Object.Shape, Full_Value, 1)
or else (for all D in Full_Value'First .. Full_Value'Last - 1 => Full_Value (D) = 1)
then
declare
Start_Index : Tensor_Index (Full_Index'Range);
Stop_Index : Tensor_Index (Full_Index'Range);
begin
for Axis in Full_Index'Range loop
Start_Index (Axis) := Full_Index (Axis).Start;
Stop_Index (Axis) := Full_Index (Axis).Stop;
end loop;
declare
Start_Index_Flattened : constant Index_Type := To_Index (Start_Index, Object.Shape);
Stop_Index_Flattened : constant Index_Type := To_Index (Stop_Index, Object.Shape);
Count : constant Natural := Value.Elements;
pragma Assert (Stop_Index_Flattened - Start_Index_Flattened + 1 = Count);
Row_Data : Element_Array (1 .. Count)
with Import, Convention => Ada, Address => Value.Data'Address;
Object_Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
begin
Object_Data (Start_Index_Flattened .. Stop_Index_Flattened) := Row_Data;
end;
end;
else
raise Program_Error with "Not implemented yet"; -- FIXME
end if;
end Set;
function Flattened_Index (Object : CPU_Tensor; Index : Tensor_Index) return Index_Type is
begin
for Axis in Index'Range loop
declare
Index_Dim : constant Natural := Index (Axis);
Shape_Dim : constant Natural := Object.Shape (Axis);
begin
if Index_Dim > Shape_Dim then
raise Constraint_Error with
"Index (" & Trim (Index_Dim) & ") out of bounds (1 .. " & Trim (Shape_Dim) & ")";
end if;
end;
end loop;
return To_Index (Index, Object.Shape);
end Flattened_Index;
overriding procedure Set
(Object : in out CPU_Tensor;
Index : Index_Type;
Value : Element) renames Operations.Set;
overriding procedure Set
(Object : in out CPU_Tensor;
Index : Index_Type;
Value : Boolean) renames Operations.Set;
overriding procedure Set (Object : in out CPU_Tensor; Index : Tensor_Index; Value : Element) is
Index_Flattened : constant Index_Type := Flattened_Index (Object, Index);
begin
Object.Data (Data_Vectors (Index_Flattened)) (Data_Offset (Index_Flattened)) := Value;
end Set;
overriding procedure Set (Object : in out CPU_Tensor; Index : Tensor_Index; Value : Boolean) is
Index_Flattened : constant Index_Type := Flattened_Index (Object, Index);
Zero_Vector : constant Vector_Type := (others => 0.0);
Mask : constant Integer_Vector_Type := Convert (Zero_Vector = Zero_Vector);
Booleans : Integer_Vector_Type := Convert (Object.Data (Data_Vectors (Index_Flattened)));
begin
Booleans (Data_Offset (Index_Flattened)) := (if Value then Mask (Mask'First) else 0);
Object.Data (Data_Vectors (Index_Flattened)) := Convert (Booleans);
end Set;
overriding function Get (Object : CPU_Tensor; Index : Tensor_Index) return Element is
Object_Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
begin
return Object_Data (Flattened_Index (Object, Index));
end Get;
overriding function Get (Object : CPU_Tensor; Index : Tensor_Index) return Boolean is
Index_Flattened : constant Index_Type := Flattened_Index (Object, Index);
One_Vector : constant Integer_Vector_Type := (others => 1);
Mask : constant Integer_Vector_Type :=
Convert (Object.Data (Data_Vectors (Index_Flattened)));
Ones_Zeros : constant Integer_Vector_Type := Mask and One_Vector;
begin
return Ones_Zeros (Data_Offset (Index_Flattened)) = 1;
end Get;
overriding
function Get (Object : CPU_Tensor; Index : Range_Type) return CPU_Tensor renames Operations.Get;
overriding function Get (Object : CPU_Tensor; Index : Tensor_Range) return CPU_Tensor is
Rows : constant Natural := Object.Rows;
Row_Start : constant Index_Type := Index (1).Start;
Row_Stop : constant Index_Type := Index (1).Stop;
Result_Rows : constant Positive := Row_Stop - Row_Start + 1;
begin
case Object.Axes is
when 1 =>
declare
Count : constant Positive := Result_Rows;
Size : constant Positive := Data_Vectors (Count);
Shape : constant Tensor_Shape := (1 => Count);
begin
if Row_Stop > Rows then
raise Constraint_Error with
"Stop index (" & Trim (Row_Stop) & ") out of bounds (1 .. " &
Trim (Rows) & ")";
end if;
return Result : CPU_Tensor := Without_Data (Shape, Object.Kind) do
if Data_Offset (Row_Start) = Vector_Index_Type'First then
Result.Data (1 .. Size) :=
Object.Data (Data_Vectors (Row_Start) .. Data_Vectors (Row_Stop));
else
declare
Result_Data : Element_Array (1 .. Count)
with Import, Convention => Ada, Address => Result.Data'Address;
Object_Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
begin
Result_Data (1 .. Count) := Object_Data (Row_Start .. Row_Stop);
end;
end if;
end return;
end;
when 2 =>
declare
Columns : constant Natural :=
(if 2 in Object.Shape'Range then Object.Columns else 1);
Index_Shape : constant Tensor_Shape := Shape (Index);
Result_Columns : constant Positive :=
(if 2 in Index_Shape'Range then Index_Shape (2) else Columns);
Shape : constant Tensor_Shape :=
(if Result_Rows = 1 then
(1 => Result_Columns)
else
(1 => Result_Rows, 2 => Result_Columns));
Column_Start : constant Index_Type :=
(if 2 in Index'Range then Index (2).Start else 1);
Column_Stop : constant Index_Type :=
(if 2 in Index'Range then Index (2).Stop else Columns);
begin
if Row_Stop > Rows then
raise Constraint_Error with
"Stop index (" & Trim (Row_Stop) & ") out of bounds (1 .. " &
Trim (Rows) & ")";
end if;
if Column_Stop > Columns then
raise Constraint_Error with
"Stop index (" & Trim (Column_Stop) & ") out of bounds (1 .. " &
Trim (Columns) & ")";
end if;
return Result : CPU_Tensor := Without_Data (Shape, Object.Kind) do
declare
Result_Data : Element_Array (1 .. Result.Elements)
with Import, Convention => Ada, Address => Result.Data'Address;
Object_Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
begin
for I in 1 .. Result_Rows loop
declare
Result_Index : constant Natural := (I - 1) * Result_Columns;
Current_Row : constant Natural := Row_Start - 1 + I;
Base_Index : constant Natural := (Current_Row - 1) * Columns;
begin
Result_Data (Result_Index + 1 .. Result_Index + Result_Columns) :=
Object_Data (Base_Index + Column_Start .. Base_Index + Column_Stop);
end;
end loop;
end;
end return;
end;
when others =>
raise Not_Implemented_Yet; -- FIXME
end case;
end Get;
overriding function Get (Object : CPU_Tensor; Index : CPU_Tensor) return CPU_Tensor is
type Integer_Vector_Array is array (Index_Type range <>) of Integer_Vector_Type;
One_Vector : constant Integer_Vector_Type := (others => 1);
Indices : Integer_Vector_Array (1 .. Index.Size);
Offset : Integer_Vector_Type := (others => 0);
begin
for Index_Vector in Index.Data'Range loop
declare
-- 1. Create Integer_Vector of 1s and 0s
Mask : constant Integer_Vector_Type := Convert (Index.Data (Index_Vector));
PS : Integer_Vector_Type := Mask and One_Vector;
Sum : Integer_Vector_Type := Offset + PS;
begin
-- 2. Compute prefix sum
for I in 2 .. Vector_Type'Length loop
PS := Shift_Elements_Left (PS);
Sum := Sum + PS;
end loop;
-- Index is > 0 if valid according to mask
Indices (Index_Vector) := Mask and Sum;
-- The last number (sum of all the elements in the vector)
-- is the offset for the next vector
Offset := (others => Sum (Sum'Last));
end;
end loop;
-- 3. Last number of last vector is number of elements in Result tensor
return Result : CPU_Tensor :=
Without_Data (Tensor_Shape'(1 => Natural (Offset (Offset'Last))))
do
if Result.Elements > 0 then
declare
Result_Data : Element_Array (1 .. Result.Elements)
with Import, Convention => Ada, Address => Result.Data'Address;
begin
-- 4. Iterate over the prefix sum and assign the value from Object.Data
-- to Result.Data at the index found in the prefix sum
for Index_Vector in Index.Data'Range loop
declare
Indices_Vector : Integer_Vector_Type renames Indices (Index_Vector);
begin
for I in Indices_Vector'Range loop
if Indices_Vector (I) > 0 then
Result_Data (Natural (Indices_Vector (I))) :=
Object.Data (Index_Vector) (I);
end if;
end loop;
end;
end loop;
end;
end if;
end return;
end Get;
----------------------------------------------------------------------------
overriding
function Image (Object : CPU_Tensor) return String is
package L1 renames Ada.Characters.Latin_1;
package SU renames Ada.Strings.Unbounded;
Row_Count : constant := 5;
Count : constant Natural := Object.Elements;
Result : SU.Unbounded_String;
begin
SU.Append (Result, "tensor([");
case Object.Axes is
when 1 =>
for I in 1 .. Count loop
declare
First_Element_Of_Row : constant Boolean := (I - 1) mod Row_Count = 0;
Last_Element_Of_Row : constant Boolean := (I - 0) mod Row_Count = 0;
Value : Element_Type renames Object.Data (Data_Vectors (I)) (Data_Offset (I));
begin
if First_Element_Of_Row then
SU.Append (Result, (if I = 1 then "" else " "));
end if;
case Object.Kind is
when Float_Type | Int_Type =>
SU.Append (Result, (if Value'Valid then Value'Image else " invalid"));
when Bool_Type =>
SU.Append (Result, " " &
(if not Value'Valid or else Value /= 0.0 then " True" else "False"));
end case;
if I < Count then
SU.Append (Result, ",");
if Last_Element_Of_Row then
SU.Append (Result, L1.LF);
end if;
end if;
end;
end loop;
when 2 =>
declare
Rows : constant Natural := Object.Rows;
Columns : constant Natural := Object.Columns;
Object_Data : Element_Array (1 .. Count)
with Import, Convention => Ada, Address => Object.Data'Address;
begin
for I in 1 .. Rows loop
SU.Append (Result, (if I = 1 then "" else " "));
SU.Append (Result, "[");
for J in 1 .. Columns loop
declare
Value : Element_Type renames Object_Data ((I - 1) * Columns + J);
begin
case Object.Kind is
when Float_Type | Int_Type =>
SU.Append (Result,
(if Value'Valid then Value'Image else " invalid"));
when Bool_Type =>
SU.Append (Result, " " &
(if not Value'Valid or else Value /= 0.0 then
" True"
else
"False"));
end case;
end;
if J < Columns then
SU.Append (Result, ",");
end if;
end loop;
SU.Append (Result, "]");
if I < Rows then
SU.Append (Result, ",");
SU.Append (Result, L1.LF);
end if;
end loop;
end;
when others =>
raise Not_Implemented_Yet; -- FIXME
end case;
SU.Append (Result, "])");
return SU.To_String (Result);
end Image;
overriding
function Shape (Object : CPU_Tensor) return Tensor_Shape is (Object.Shape);
overriding
function Elements (Object : CPU_Tensor) return Natural is (Elements (Object.Shape));
overriding
function Axes (Object : CPU_Tensor) return Tensor_Axis is (Object.Axes);
overriding
function Empty (Shape : Tensor_Shape) return CPU_Tensor is (Without_Data (Shape));
overriding
function Fill (Shape : Tensor_Shape; Value : Element) return CPU_Tensor is
Vector : constant Vector_Type := (others => Value);
begin
return Result : CPU_Tensor := Without_Data (Shape) do
Result.Data := (others => Vector);
end return;
end Fill;
overriding function Zeros (Shape : Tensor_Shape) return CPU_Tensor renames Operations.Zeros;
overriding function Zeros (Elements : Positive) return CPU_Tensor renames Operations.Zeros;
overriding function Ones (Shape : Tensor_Shape) return CPU_Tensor renames Operations.Ones;
overriding function Ones (Elements : Positive) return CPU_Tensor renames Operations.Ones;
overriding
function To_Tensor (Elements : Element_Array; Shape : Tensor_Shape) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Shape) do
declare
Result_Data : Element_Array (1 .. Result.Elements)
with Import, Convention => Ada, Address => Result.Data'Address;
begin
Result_Data := Elements;
end;
end return;
end To_Tensor;
overriding
function To_Tensor (Elements : Element_Array) return CPU_Tensor renames Operations.To_Tensor;
overriding
function To_Boolean_Tensor
(Booleans : Boolean_Array;
Shape : Tensor_Shape) return CPU_Tensor
is
Elements : Element_Array (Booleans'Range);
begin
for Index in Elements'Range loop
Elements (Index) := (if Booleans (Index) then 1.0 else 0.0);
end loop;
return To_Tensor (Elements, Shape) > 0.0;
end To_Boolean_Tensor;
overriding
function To_Boolean_Tensor (Booleans : Boolean_Array) return CPU_Tensor
renames Operations.To_Boolean_Tensor;
overriding
function Linear_Space
(Start, Stop : Element;
Count : Positive;
Interval : Interval_Kind := Closed) return CPU_Tensor
is
Shape : constant Tensor_Shape := (1 => Count);
Step : constant Element :=
(if Count > 1 then (Stop - Start) / Element (Count - (case Interval is
when Closed => 1,
when Half_Open => 0))
else 0.0);
begin
return Result : CPU_Tensor := Without_Data (Shape) do
declare
Result_Data : Element_Array (1 .. Elements (Shape))
with Import, Convention => Ada, Address => Result.Data'Address;
begin
for Index in 1 .. Count loop
Result_Data (Index) := Start + Step * Element (Index - 1);
end loop;
end;
end return;
end Linear_Space;
overriding
function Log_Space
(Start, Stop : Element;
Count : Positive;
Interval : Interval_Kind := Closed;
Base : Element := 10.0) return CPU_Tensor
is
Shape : constant Tensor_Shape := (1 => Count);
Step : constant Element :=
(if Count > 1 then (Stop - Start) / Element (Count - (case Interval is
when Closed => 1,
when Half_Open => 0))
else 0.0);
begin
return Result : CPU_Tensor := Without_Data (Shape) do
declare
Result_Data : Element_Array (1 .. Elements (Shape))
with Import, Convention => Ada, Address => Result.Data'Address;
use EF;
begin
for Index in 1 .. Count loop
Result_Data (Index) := Base ** (Start + Step * Element (Index - 1));
end loop;
end;
end return;
end Log_Space;
overriding
function Geometric_Space
(Start, Stop : Element;
Count : Positive;
Interval : Interval_Kind := Closed;
Base : Element := 10.0) return CPU_Tensor renames Operations.Geometric_Space;
overriding
function Array_Range (Start, Stop : Element; Step : Element := 1.0) return CPU_Tensor
renames Operations.Array_Range;
overriding
function Array_Range (Stop : Element) return CPU_Tensor renames Operations.Array_Range;
overriding
function Identity (Size : Positive; Offset : Integer := 0) return CPU_Tensor
renames Operations.Identity;
overriding
function Identity (Rows, Columns : Positive; Offset : Integer := 0) return CPU_Tensor is
Shape : constant Tensor_Shape := (1 => Rows, 2 => Columns);
Max_Size : constant Positive := Positive'Max (Rows, Columns);
Zero_Vector : constant Vector_Type := (others => 0.0);
begin
return Result : CPU_Tensor :=
(Axes => Shape'Length,
Size => Data_Vectors (Shape),
Kind => Float_Type,
Shape => Shape,
Data => (others => Zero_Vector))
do
if Offset in -(Max_Size - 1) .. Max_Size - 1 then
declare
Result_Data : Element_Array (1 .. Elements (Shape))
with Import, Convention => Ada, Address => Result.Data'Address;
Index : Integer := Offset + 1;
begin
for I in 1 .. Rows loop
if Index in Result_Data'Range then
Result_Data (Index) := 1.0;
end if;
Index := Index + Columns + 1;
end loop;
end;
end if;
end return;
end Identity;
overriding
function Upper_Triangular (Object : CPU_Tensor; Offset : Integer := 0) return CPU_Tensor
renames Operations.Upper_Triangular;
overriding
function Main_Diagonal (Object : CPU_Tensor; Offset : Integer := 0) return CPU_Tensor is
Rows : constant Positive := Object.Rows;
Columns : constant Positive := Object.Columns;
Shape : constant Tensor_Shape := (1 => Positive'Min (Rows, Columns));
begin
return Result : CPU_Tensor := Without_Data (Shape) do
declare
Result_Data : Element_Array (1 .. Elements (Shape))
with Import, Convention => Ada, Address => Result.Data'Address;
Object_Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
Index : Integer := Offset + 1;
begin
for I in Result_Data'Range loop
if Index in Object_Data'Range then
Result_Data (I) := Object_Data (Index);
else
Result_Data (I) := 0.0;
end if;
Index := Index + Columns + 1;
end loop;
end;
end return;
end Main_Diagonal;
overriding
function Diagonal (Elements : Element_Array; Offset : Integer := 0) return CPU_Tensor is
Size : constant Positive := Elements'Length;
Shape : constant Tensor_Shape := (1 .. 2 => Size);
Zero_Vector : constant Vector_Type := (others => 0.0);
begin
return Result : CPU_Tensor :=
(Axes => Shape'Length,
Size => Data_Vectors (Shape),
Kind => Float_Type,
Shape => Shape,
Data => (others => Zero_Vector))
do
if Offset in -(Size - 1) .. Size - 1 then
declare
Result_Data : Element_Array (1 .. Size * Size)
with Import, Convention => Ada, Address => Result.Data'Address;
Index : Integer := Offset + 1;
begin
for I in Elements'Range loop
if Index in Result_Data'Range then
Result_Data (Index) := Elements (I);
end if;
Index := Index + Size + 1;
end loop;
end;
end if;
end return;
end Diagonal;
overriding
function Diagonal (Elements : CPU_Tensor; Offset : Integer := 0) return CPU_Tensor is
Object_Data : Element_Array (1 .. Elements.Elements)
with Import, Convention => Ada, Address => Elements.Data'Address;
begin
return Diagonal (Object_Data, Offset);
end Diagonal;
overriding
function Trace (Object : CPU_Tensor; Offset : Integer := 0) return Element
renames Operations.Trace;
overriding
function Reshape (Object : CPU_Tensor; Shape : Tensor_Shape) return CPU_Tensor is
(Axes => Shape'Length,
Size => Object.Size,
Kind => Object.Kind,
Shape => Shape,
Data => Object.Data);
overriding
function Reshape (Object : CPU_Tensor; Elements : Positive) return CPU_Tensor
renames Operations.Reshape;
overriding
function Flatten (Object : CPU_Tensor) return CPU_Tensor renames Operations.Flatten;
overriding
function Concatenate
(Left, Right : CPU_Tensor;
Axis : Tensor_Axis) return CPU_Tensor
is
Shape : constant Tensor_Shape := Add (Left.Shape, Right.Shape, Axis);
pragma Assert (Elements (Shape) = Left.Elements + Right.Elements);
begin
return Result : CPU_Tensor := Without_Data (Shape, Left.Kind) do
declare
Result_Data : Element_Array (1 .. Result.Elements)
with Import, Convention => Ada, Address => Result.Data'Address;
Left_Data : Element_Array (1 .. Left.Elements)
with Import, Convention => Ada, Address => Left.Data'Address;
Right_Data : Element_Array (1 .. Right.Elements)
with Import, Convention => Ada, Address => Right.Data'Address;
begin
case Axis is
when 1 =>
Result_Data (1 .. Left.Elements) := Left_Data;
Result_Data (Left.Elements + 1 .. Result_Data'Last) := Right_Data;
when 2 =>
declare
Rows : constant Positive := Left.Rows;
Columns_Left : constant Positive := Left.Columns;
Columns_Right : constant Positive := Right.Columns;
begin
for Index in 1 .. Rows loop
declare
Base_Left_Index : constant Natural :=
(Index - 1) * (Columns_Left + Columns_Right);
Base_Right_Index : constant Natural := Base_Left_Index + Columns_Left;
Left_Index : constant Natural := (Index - 1) * Columns_Left;
Right_Index : constant Natural := (Index - 1) * Columns_Right;
begin
Result_Data (Base_Left_Index + 1 .. Base_Left_Index + Columns_Left)
:= Left_Data (Left_Index + 1 .. Left_Index + Columns_Left);
Result_Data (Base_Right_Index + 1 .. Base_Right_Index + Columns_Right)
:= Right_Data (Right_Index + 1 .. Right_Index + Columns_Right);
end;
end loop;
end;
when others =>
raise Not_Implemented_Yet; -- FIXME
end case;
end;
end return;
end Concatenate;
overriding
function "&" (Left, Right : CPU_Tensor) return CPU_Tensor renames Operations."&";
----------------------------------------------------------------------------
-- Matrix operations --
----------------------------------------------------------------------------
procedure Multiply_Add
(Result : in out Element_Array;
Left : Element;
Right : Element_Array)
is
Left_Vector : constant Vector_Type := (others => Left);
subtype Vector_Elements is Element_Array (1 .. Vector_Type'Length);
function Convert is new Ada.Unchecked_Conversion (Vector_Elements, Vector_Type);
function Convert is new Ada.Unchecked_Conversion (Vector_Type, Vector_Elements);
Last_Vector_Index : constant Positive := Data_Vectors (Right'Length);
Padding : constant Natural :=
Data_Padding (Last_Vector_Index, Right'Length);
begin
for Index in 1 .. Last_Vector_Index - (if Padding > 0 then 1 else 0) loop
declare
Vector_Index : constant Integer := (Index - 1) * Vector_Type'Length - 1;
Result_Index : constant Natural := Vector_Index + Result'First;
Right_Index : constant Natural := Vector_Index + Right'First;
Result_Vector : constant Vector_Type :=
Convert (Result (Result_Index + 1 .. Result_Index + Vector_Type'Length));
Right_Vector : constant Vector_Type :=
Convert (Right (Right_Index + 1 .. Right_Index + Vector_Type'Length));
begin
Result (Result_Index + 1 .. Result_Index + Vector_Type'Length) :=
Convert (Result_Vector + Left_Vector * Right_Vector);
end;
end loop;
if Padding > 0 then
declare
Vector_Index : constant Integer := (Last_Vector_Index - 1) * Vector_Type'Length - 1;
Result_Index : constant Natural := Vector_Index + Result'First;
Right_Index : constant Natural := Vector_Index + Right'First;
Last_Count : constant Positive := Vector_Type'Length - Padding;
begin
for I in 1 .. Last_Count loop
Result (Result_Index + I) :=
Result (Result_Index + I) + Left * Right (Right_Index + I);
end loop;
end;
end if;
end Multiply_Add;
overriding
function "*" (Left, Right : CPU_Tensor) return CPU_Tensor is
-- m x n * n x p
-- ^ ^
-- |___|
-- (Count)
Left_Rows : constant Natural := (if Left.Axes = 2 then Left.Rows else 1);
Count : constant Natural := Right.Rows;
Right_Columns : constant Natural := (if Right.Axes = 2 then Right.Columns else 1);
Shape : constant Tensor_Shape :=
(case Right.Axes is
when 1 => (1 => Left_Rows),
when 2 => (1 => Left_Rows, 2 => Right_Columns),
when others => raise Not_Implemented_Yet); -- FIXME
begin
-- Matrix-matrix or matrix-vector or vector-matrix multiplication
return Result : CPU_Tensor := Zeros (Shape) do
declare
Result_Data : Element_Array (1 .. Result.Elements)
with Import, Convention => Ada, Address => Result.Data'Address;
Left_Data : Element_Array (1 .. Left.Elements)
with Import, Convention => Ada, Address => Left.Data'Address;
Right_Data : Element_Array (1 .. Right.Elements)
with Import, Convention => Ada, Address => Right.Data'Address;
begin
for Row_Index in 1 .. Left_Rows loop
-- Result (Row_Index) := Left (Row_Index) * Right;
declare
Result_Index : constant Natural := To_Index ((Row_Index, 1), Right_Columns) - 1;
begin
for Column_Index in 1 .. Count loop
declare
Right_Index : constant Natural :=
To_Index ((Column_Index, 1), Right_Columns) - 1;
begin
-- Left_Value := Left (Row_Index, Column_Index)
-- Result (Row_Index) := @ + Left_Value * Right (Row_Index)
Multiply_Add
(Result_Data (Result_Index + 1 .. Result_Index + Right_Columns),
Left_Data (To_Index ((Row_Index, Column_Index), Count)),
Right_Data (Right_Index + 1 .. Right_Index + Right_Columns));
end;
end loop;
end;
end loop;
end;
end return;
end "*";
overriding
function "*" (Left, Right : CPU_Tensor) return Element is
Result : Element_Type := 0.0;
Padding : constant Natural :=
Data_Padding (Size => Left.Size, Count => Left.Elements);
Last_Left : constant Vector_Type := Reset_Padding (Left, Padding, 0.0);
Last_Right : constant Vector_Type := Reset_Padding (Right, Padding, 0.0);
type Sum_Index_Type is mod 8;
Sums : array (Sum_Index_Type) of Vector_Type := (others => (others => 0.0));
-- TODO Do pairwise summation recursively
begin
for Index in Left.Data'First .. Left.Data'Last - 1 loop
declare
Sum_Index : constant Sum_Index_Type := Sum_Index_Type (Index mod Sums'Length);
begin
Sums (Sum_Index) := Sums (Sum_Index) + Left.Data (Index) * Right.Data (Index);
end;
end loop;
declare
Sum_Index : constant Sum_Index_Type := Sum_Index_Type (Left.Data'Last mod Sums'Length);
begin
Sums (Sum_Index) := Sums (Sum_Index) + Last_Left * Last_Right;
end;
for Value of Sums loop
Result := Result + Sum (Value);
end loop;
return Element (Result);
end "*";
overriding function "**" (Left : CPU_Tensor; Right : Integer) return CPU_Tensor
renames Operations."**";
overriding
function Outer (Left, Right : CPU_Tensor) return CPU_Tensor is
Shape : constant Tensor_Shape := (1 => Left.Elements, 2 => Right.Elements);
begin
return Result : CPU_Tensor := Without_Data (Shape) do
declare
Result_Data : Element_Array (1 .. Result.Elements)
with Import, Convention => Ada, Address => Result.Data'Address;
Left_Data : Element_Array (1 .. Left.Elements)
with Import, Convention => Ada, Address => Left.Data'Address;
Columns : constant Positive := Right.Elements;
begin
for Index in 1 .. Left.Elements loop
declare
Row : constant CPU_Tensor := Left_Data (Index) * Right;
Row_Data : Element_Array (1 .. Columns)
with Import, Convention => Ada, Address => Row.Data'Address;
Base_Index : constant Natural := (Index - 1) * Columns;
begin
Result_Data (Base_Index + 1 .. Base_Index + Columns) := Row_Data;
end;
end loop;
end;
end return;
end Outer;
overriding
function Inverse (Object : CPU_Tensor) return CPU_Tensor renames Operations.Inverse;
overriding
function Transpose (Object : CPU_Tensor) return CPU_Tensor is
Shape : constant Tensor_Shape :=
(1 => Object.Columns,
2 => Object.Rows);
begin
return Result : CPU_Tensor := Without_Data (Shape) do
declare
Result_Data : Element_Array (1 .. Result.Elements)
with Import, Convention => Ada, Address => Result.Data'Address;
Object_Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
Rows : constant Natural := Object.Rows;
Columns : constant Natural := Object.Columns;
Result_Columns : Natural renames Rows;
begin
for Row_Index in 1 .. Rows loop
for Column_Index in 1 .. Columns loop
Result_Data (To_Index ((Column_Index, Row_Index), Result_Columns)) :=
Object_Data (To_Index ((Row_Index, Column_Index), Columns));
end loop;
end loop;
end;
end return;
end Transpose;
----------------------------------------------------------------------------
overriding
function Solve (A, B : CPU_Tensor; Solution : out Solution_Kind) return CPU_Tensor
renames Operations.Solve;
overriding
function Solve (A, B : CPU_Tensor; Form : Triangular_Form) return CPU_Tensor
renames Operations.Solve;
overriding
function Divide_By (B, A : CPU_Tensor) return CPU_Tensor
renames Operations.Divide_By;
overriding
function Divide_By (B, A : CPU_Tensor; Form : Triangular_Form) return CPU_Tensor
renames Operations.Divide_By;
overriding
function QR (Object : CPU_Tensor) return CPU_Tensor
renames Operations.QR;
overriding
function QR (Object : CPU_Tensor; Mode : QR_Mode := Reduced) return QR_Factorization'Class
renames Operations.QR;
overriding
function QR_For_Least_Squares (Object : CPU_Tensor) return QR_Factorization'Class
renames Operations.QR_For_Least_Squares;
overriding
function Least_Squares (Object : QR_Factorization'Class; B : CPU_Tensor) return CPU_Tensor
renames Operations.Least_Squares;
overriding
function Least_Squares (A, B : CPU_Tensor) return CPU_Tensor
renames Operations.Least_Squares;
overriding
function Constrained_Least_Squares (A, B, C, D : CPU_Tensor) return CPU_Tensor
renames Operations.Constrained_Least_Squares;
overriding
function Cholesky (Object : CPU_Tensor; Form : Triangular_Form := Lower) return CPU_Tensor
renames Operations.Cholesky;
overriding
function Cholesky_Update
(R, V : CPU_Tensor;
Mode : Update_Mode) return CPU_Tensor renames Operations.Cholesky_Update;
----------------------------------------------------------------------------
-- Vector operations --
----------------------------------------------------------------------------
overriding
function Norm (Object : CPU_Tensor) return Element renames Operations.Norm;
overriding
function Normalize (Object : CPU_Tensor) return CPU_Tensor renames Operations.Normalize;
overriding
function Standardize (Object : CPU_Tensor) return CPU_Tensor renames Operations.Standardize;
overriding
function Correlation_Coefficient (Left, Right : CPU_Tensor) return Correlation_Element
renames Operations.Correlation_Coefficient;
----------------------------------------------------------------------------
-- Element-wise operations --
----------------------------------------------------------------------------
overriding function "+" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) + Right.Data (Index);
end loop;
end return;
end "+";
overriding function "-" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) - Right.Data (Index);
end loop;
end return;
end "-";
overriding function "/" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) / Right.Data (Index);
end loop;
end return;
end "/";
overriding function Divide_Or_Zero (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Divide_Or_Zero (Left.Data (Index), Right.Data (Index));
end loop;
end return;
end Divide_Or_Zero;
function Power (Left, Right : Element) return Element is
(if Left = 0.0 and Right = 0.0 then 1.0 else EF."**" (Left, Right));
-- 0.0 ** X = 1.0 if X = 0.0 (EF."**" raises Argument_Error instead of returning 1.0)
-- 0.0 ** X = 0.0 if X > 0.0
overriding function "**" (Left, Right : CPU_Tensor) return CPU_Tensor is
-- (Exp (Multiply (Right, Log (Left))));
Padding : constant Natural :=
Data_Padding (Size => Left.Size, Count => Elements (Left.Shape));
Last_Left : constant Vector_Type := Reset_Padding (Left, Padding, 0.0);
Last_Right : constant Vector_Type := Reset_Padding (Right, Padding, 1.0);
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'First .. Result.Data'Last - 1 loop
for Offset in Vector_Type'Range loop
declare
Left_Element : Element renames Left.Data (Index) (Offset);
Right_Element : Element renames Right.Data (Index) (Offset);
begin
Result.Data (Index) (Offset) := Power (Left_Element, Right_Element);
end;
end loop;
end loop;
for Offset in Vector_Type'Range loop
Result.Data (Result.Data'Last) (Offset) :=
Power (Last_Left (Offset), Last_Right (Offset));
end loop;
end return;
end "**";
overriding function "**" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
-- (Exp (Right * Log (Left)));
use EF;
begin
if Right = 0.0 then
return Ones (Left.Shape);
elsif Right = 1.0 then
return Left;
else
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := Left.Data (Index) (Offset) ** Right;
end loop;
end loop;
end return;
end if;
end "**";
overriding function "**" (Left : Element; Right : CPU_Tensor) return CPU_Tensor is
-- (Exp (Right * EF.Log (Left)));
Padding : constant Natural :=
Data_Padding (Size => Right.Size, Count => Elements (Right.Shape));
-- EF."**" raises Constraint_Error if Left = 0.0 and element
-- in the padding happens to be < 0.0
Last_Right : constant Vector_Type := Reset_Padding (Right, Padding, 1.0);
begin
if Left = 1.0 then
return Ones (Right.Shape);
else
return Result : CPU_Tensor := Without_Data (Right) do
for Index in Result.Data'First .. Result.Data'Last - 1 loop
for Offset in Vector_Type'Range loop
declare
Right_Element : Element renames Right.Data (Index) (Offset);
begin
Result.Data (Index) (Offset) := Power (Left, Right_Element);
end;
end loop;
end loop;
for Offset in Vector_Type'Range loop
Result.Data (Result.Data'Last) (Offset) := Power (Left, Last_Right (Offset));
end loop;
end return;
end if;
end "**";
overriding function "*" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) * Right_Vector;
end loop;
end return;
end "*";
overriding function "/" (Left : Element; Right : CPU_Tensor) return CPU_Tensor is
Left_Vector : constant Vector_Type := (others => Left);
begin
return Result : CPU_Tensor := Without_Data (Right) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left_Vector / Right.Data (Index);
end loop;
end return;
end "/";
overriding function "/" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) / Right_Vector;
end loop;
end return;
end "/";
overriding function "+" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) + Right_Vector;
end loop;
end return;
end "+";
overriding function "-" (Left : Element; Right : CPU_Tensor) return CPU_Tensor is
Left_Vector : constant Vector_Type := (others => Left);
begin
return Result : CPU_Tensor := Without_Data (Right) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left_Vector - Right.Data (Index);
end loop;
end return;
end "-";
overriding function "-" (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
Result.Data (Index) := -Object.Data (Index);
end loop;
end return;
end "-";
overriding
function "*" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations."*";
overriding
function "+" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations."+";
overriding
function "-" (Left : CPU_Tensor; Right : Element) return CPU_Tensor renames Operations."-";
overriding
function "mod" (Left, Right : CPU_Tensor) return CPU_Tensor renames Operations."mod";
overriding
function "rem" (Left, Right : CPU_Tensor) return CPU_Tensor renames Operations."rem";
overriding
function "mod" (Left : CPU_Tensor; Right : Element) return CPU_Tensor renames Operations."mod";
overriding
function "rem" (Left : CPU_Tensor; Right : Element) return CPU_Tensor renames Operations."rem";
overriding function "abs" (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
Result.Data (Index) := abs Object.Data (Index);
end loop;
end return;
end "abs";
overriding function Multiply (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) * Right.Data (Index);
end loop;
end return;
end Multiply;
overriding
function Power (Left : CPU_Tensor; Right : Integer) return CPU_Tensor renames Operations.Power;
overriding
function Min (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations.Min;
overriding
function Max (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations.Max;
overriding function Min (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Min (Left.Data (Index), Right_Vector);
end loop;
end return;
end Min;
overriding function Max (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Max (Left.Data (Index), Right_Vector);
end loop;
end return;
end Max;
overriding function Sqrt (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
Result.Data (Index) := Sqrt (Object.Data (Index));
end loop;
end return;
end Sqrt;
overriding function Ceil (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
Result.Data (Index) := Ceil (Object.Data (Index));
end loop;
end return;
end Ceil;
overriding function Floor (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
Result.Data (Index) := Floor (Object.Data (Index));
end loop;
end return;
end Floor;
overriding function Round (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
Result.Data (Index) := Round (Object.Data (Index));
end loop;
end return;
end Round;
overriding function Truncate (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
Result.Data (Index) := Truncate (Object.Data (Index));
end loop;
end return;
end Truncate;
overriding function Exp (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := EF.Exp (Object.Data (Index) (Offset));
end loop;
end loop;
end return;
end Exp;
overriding function Log (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := EF.Log (Object.Data (Index) (Offset));
end loop;
end loop;
end return;
end Log;
overriding function Log10 (Object : CPU_Tensor) return CPU_Tensor renames Operations.Log10;
overriding function Log2 (Object : CPU_Tensor) return CPU_Tensor renames Operations.Log2;
----------------------------------------------------------------------------
-- Trigonometry --
----------------------------------------------------------------------------
overriding function Sin (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := EF.Sin (Object.Data (Index) (Offset));
end loop;
end loop;
end return;
end Sin;
overriding function Cos (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := EF.Cos (Object.Data (Index) (Offset));
end loop;
end loop;
end return;
end Cos;
overriding function Tan (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := EF.Tan (Object.Data (Index) (Offset));
end loop;
end loop;
end return;
end Tan;
overriding function Arcsin (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := EF.Arcsin (Object.Data (Index) (Offset));
end loop;
end loop;
end return;
end Arcsin;
overriding function Arccos (Object : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Object) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) := EF.Arccos (Object.Data (Index) (Offset));
end loop;
end loop;
end return;
end Arccos;
overriding function Arctan (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
for Offset in Vector_Type'Range loop
Result.Data (Index) (Offset) :=
EF.Arctan (Left.Data (Index) (Offset), Right.Data (Index) (Offset));
end loop;
end loop;
end return;
end Arctan;
overriding function Degrees (Object : CPU_Tensor) return CPU_Tensor renames Operations.Degrees;
overriding function Radians (Object : CPU_Tensor) return CPU_Tensor renames Operations.Radians;
----------------------------------------------------------------------------
-- Reductions --
----------------------------------------------------------------------------
overriding
function Reduce_Associative
(Object : CPU_Tensor;
Subject : Expression'Class;
Initial : Element) return Element
is
CPU_Subject : constant Expression_Type := Expression_Type (Subject);
Max_Length_Sequential : constant Positive := 128 / Vector_Type'Length;
function Pairwise (Lower, Upper : Positive) return Vector_Type is
Length : constant Positive := Upper - Lower + 1;
begin
if Length <= Max_Length_Sequential then
declare
Result : Vector_Type := Object.Data (Lower);
begin
for Index in Lower + 1 .. Upper loop
Result := Apply (CPU_Subject, Result, Object.Data (Index));
end loop;
return Result;
end;
else
declare
Half_Index : constant Positive := Lower + Length / 2;
begin
return Apply
(CPU_Subject,
Pairwise (Lower, Half_Index - 1),
Pairwise (Half_Index, Upper));
end;
end if;
end Pairwise;
Padding : constant Natural :=
Data_Padding (Size => Object.Size, Count => Object.Elements);
Result : Element_Type := Initial;
begin
if Object.Data'Last = 0 then
return Result;
end if;
if Object.Elements > Vector_Type'Length then
for Element of Pairwise (Object.Data'First, Object.Data'Last - 1) loop
Result := Apply (CPU_Subject, Result, Element);
end loop;
else
-- Do not perform pairwise applying of expression because Object.Data has only 1 vector,
-- which is added to Result below
null;
end if;
for Index in Vector_Index_Type'First .. From_Last (Padding) loop
Result := Apply (CPU_Subject, Result, Object.Data (Object.Data'Last) (Index));
end loop;
return Result;
end Reduce_Associative;
overriding
function Reduce_Associative
(Object : CPU_Tensor;
Subject : Expression'Class;
Initial : Element;
Axis : Tensor_Axis) return CPU_Tensor is
begin
raise Program_Error;
return Zeros ((1 => 1)); -- FIXME
end Reduce_Associative;
overriding
function Reduce
(Object : CPU_Tensor;
Subject : Expression'Class;
Initial : Element) return Element
is
CPU_Subject : constant Expression_Type := Expression_Type (Subject);
Data : Element_Array (1 .. Object.Elements)
with Import, Convention => Ada, Address => Object.Data'Address;
Result : Element_Type := Initial;
begin
for Value of Data loop
Result := Apply (CPU_Subject, Result, Value);
end loop;
return Result;
end Reduce;
overriding
function Reduce
(Object : CPU_Tensor;
Subject : Expression'Class;
Initial : Element;
Axis : Tensor_Axis) return CPU_Tensor is
begin
raise Program_Error;
return Zeros ((1 => 1)); -- FIXME
end Reduce;
overriding function Sum (Object : CPU_Tensor) return Element renames Operations.Sum;
overriding function Product (Object : CPU_Tensor) return Element renames Operations.Product;
overriding
function Sum (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor
renames Operations.Sum;
overriding
function Product (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor
renames Operations.Product;
----------------------------------------------------------------------------
-- Statistics --
----------------------------------------------------------------------------
overriding function Min (Object : CPU_Tensor) return Element renames Operations.Min;
overriding function Max (Object : CPU_Tensor) return Element renames Operations.Max;
overriding function Quantile (Object : CPU_Tensor; P : Probability) return Element
renames Operations.Quantile;
overriding function Median (Object : CPU_Tensor) return Element
renames Operations.Median;
overriding function Mean (Object : CPU_Tensor) return Element
renames Operations.Mean;
overriding
function Variance (Object : CPU_Tensor; Offset : Natural := 0) return Element
renames Operations.Variance;
overriding
function Standard_Deviation (Object : CPU_Tensor; Offset : Natural := 0) return Element
renames Operations.Standard_Deviation;
overriding
function Min (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Min (Left.Data (Index), Right.Data (Index));
end loop;
end return;
end Min;
overriding
function Max (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left) do
for Index in Result.Data'Range loop
Result.Data (Index) := Max (Left.Data (Index), Right.Data (Index));
end loop;
end return;
end Max;
overriding
function Min (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor
renames Operations.Min;
overriding
function Max (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor
renames Operations.Max;
overriding
function Quantile
(Object : CPU_Tensor;
P : Probability;
Axis : Tensor_Axis) return CPU_Tensor is
begin
raise Program_Error;
return Zeros ((1 => 1)); -- FIXME
end Quantile;
overriding
function Mean (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor
renames Operations.Mean;
overriding
function Variance
(Object : CPU_Tensor;
Axis : Tensor_Axis;
Offset : Natural := 0) return CPU_Tensor
renames Operations.Variance;
overriding
function Median (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor
renames Operations.Median;
overriding
function Standard_Deviation
(Object : CPU_Tensor;
Axis : Tensor_Axis;
Offset : Natural := 0) return CPU_Tensor
renames Operations.Standard_Deviation;
----------------------------------------------------------------------------
-- Logical --
----------------------------------------------------------------------------
overriding function And_Not (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := And_Not (Left.Data (Index), Right.Data (Index));
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end And_Not;
overriding function "and" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Left.Kind) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) and Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "and";
overriding function "and" (Left : Element; Right : CPU_Tensor) return CPU_Tensor is
Left_Vector : constant Vector_Type := (others => Left);
begin
return Result : CPU_Tensor := Without_Data (Right, Kind => Float_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left_Vector and Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "and";
overriding function "or" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) or Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "or";
overriding function "xor" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) xor Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "xor";
overriding function "not" (Object : CPU_Tensor) return CPU_Tensor is
Zero_Vector : constant Vector_Type := (others => 0.0);
Mask : constant Vector_Type := Zero_Vector = Zero_Vector;
begin
return Result : CPU_Tensor := Without_Data (Object, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := And_Not (Object.Data (Index), Mask);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "not";
----------------------------------------------------------------------------
-- Comparisons --
----------------------------------------------------------------------------
overriding
function "=" (Left : CPU_Tensor; Right : Element) return CPU_Tensor renames Operations."=";
overriding
function "/=" (Left : CPU_Tensor; Right : Element) return CPU_Tensor renames Operations."/=";
overriding function ">" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) > Right_Vector;
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end ">";
overriding function "<" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) < Right_Vector;
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "<";
overriding function ">=" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) >= Right_Vector;
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end ">=";
overriding function "<=" (Left : CPU_Tensor; Right : Element) return CPU_Tensor is
Right_Vector : constant Vector_Type := (others => Right);
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) <= Right_Vector;
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "<=";
----------------------------------------------------------------------------
overriding
function "=" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations."=";
overriding
function "/=" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations."/=";
overriding
function ">" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations.">";
overriding
function "<" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations."<";
overriding
function ">=" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations.">=";
overriding
function "<=" (Left : Element; Right : CPU_Tensor) return CPU_Tensor renames Operations."<=";
----------------------------------------------------------------------------
overriding function "=" (Left, Right : CPU_Tensor) return Boolean renames Operations."=";
overriding function "=" (Left, Right : CPU_Tensor) return CPU_Tensor is
Zero_Vector : constant Vector_Type := (others => 0.0);
Mask : constant Vector_Type := Zero_Vector = Zero_Vector;
begin
case Left.Kind is
when Float_Type =>
return (abs (Left - Right) <= Element_Type'Model_Epsilon);
when Int_Type | Bool_Type =>
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) :=
And_Not (Left.Data (Index) xor Right.Data (Index), Mask);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end case;
end "=";
overriding function "/=" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
case Left.Kind is
when Float_Type =>
return (abs (Left - Right) > Element_Type'Model_Epsilon);
when Int_Type | Bool_Type =>
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) xor Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end case;
end "/=";
overriding function ">" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) > Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end ">";
overriding function "<" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) < Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "<";
overriding function ">=" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) >= Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end ">=";
overriding function "<=" (Left, Right : CPU_Tensor) return CPU_Tensor is
begin
return Result : CPU_Tensor := Without_Data (Left, Kind => Bool_Type) do
for Index in Result.Data'Range loop
Result.Data (Index) := Left.Data (Index) <= Right.Data (Index);
end loop;
Result.Data (Result.Data'Last) := Disable_Padding (Result);
end return;
end "<=";
----------------------------------------------------------------------------
overriding
function All_Close
(Left, Right : CPU_Tensor;
Relative_Tolerance : Element := 1.0e-05;
Absolute_Tolerance : Element := Element_Type'Model_Epsilon) return Boolean
renames Operations.All_Close;
overriding
function Any_True (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor is
begin
raise Program_Error;
return Zeros ((1 => 1)); -- FIXME
end Any_True;
overriding
function Any_True (Object : CPU_Tensor) return Boolean is
Padding : constant Natural :=
Data_Padding (Size => Object.Size, Count => Object.Elements);
function All_Zeros (Vector : Vector_Type) return Boolean is
(All_Zeros (Convert (Vector), Convert (Vector)));
Zero_Vector : constant Vector_Type := (others => 0.0);
Mask : Integer_Vector_Type := Convert (Zero_Vector = Zero_Vector);
begin
for Index in 1 .. Padding loop
Mask := Shift_Elements_Right (Mask);
end loop;
return (for some Index in Object.Data'First .. Object.Data'Last - 1 =>
not All_Zeros (Object.Data (Index)))
or not All_Zeros (Object.Data (Object.Data'Last) and Convert (Mask));
end Any_True;
overriding
function All_True (Object : CPU_Tensor; Axis : Tensor_Axis) return CPU_Tensor is
begin
raise Program_Error;
return Zeros ((1 => 1)); -- FIXME
end All_True;
overriding
function All_True (Object : CPU_Tensor) return Boolean is
Padding : constant Natural :=
Data_Padding (Size => Object.Size, Count => Object.Elements);
function All_Ones (Vector : Vector_Type) return Boolean is
(All_Ones (Convert (Vector), Convert (Vector = Vector)));
Zero_Vector : constant Vector_Type := (others => 0.0);
Mask : Integer_Vector_Type := Convert (Zero_Vector = Zero_Vector);
begin
for Index in 1 .. Vector_Type'Length - Padding loop
Mask := Shift_Elements_Left (Mask);
end loop;
return (for all Index in Object.Data'First .. Object.Data'Last - 1 =>
All_Ones (Object.Data (Index)))
and All_Ones (Object.Data (Object.Data'Last) or Convert (Mask));
end All_True;
procedure Reset_Random (Seed : Duration) is
begin
Reset (Random_State, Seed);
end Reset_Random;
overriding function Random_Uniform (Shape : Tensor_Shape) return CPU_Tensor is
Value : Vector_Type;
begin
return Result : CPU_Tensor := Without_Data (Shape) do
for I in Result.Data'Range loop
Next (Random_State, Value);
Result.Data (I) := Value;
end loop;
end return;
end Random_Uniform;
end Orka.Numerics.Tensors.SIMD_CPU;
|