1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287 | -- part of OpenGLAda, (c) 2017 Felix Krause
-- released under the terms of the MIT license, see the file "COPYING"
with Ada.Containers.Indefinite_Hashed_Maps;
with Ada.Unchecked_Conversion;
with GL.API;
with GL.Enums.Getter;
package body GL.Objects.Framebuffers is
------------
function Status (Target : Framebuffer_Target) return Framebuffer_Status is
begin
return API.Check_Framebuffer_Status (Target.Kind);
end Status;
procedure Attach_Renderbuffer (Target : Framebuffer_Target;
Attachment : Attachment_Point;
Object : Renderbuffers.Renderbuffer'Class) is
begin
API.Framebuffer_Renderbuffer (Target.Kind, Attachment,
Low_Level.Enums.Renderbuffer,
Object.Raw_Id);
Raise_Exception_On_OpenGL_Error;
end Attach_Renderbuffer;
procedure Attach_Texture (Target : Framebuffer_Target;
Attachment : Attachment_Point;
Object : Textures.Texture'Class;
Level : Textures.Mipmap_Level) is
begin
API.Framebuffer_Texture (Target.Kind, Attachment, Object.Raw_Id, Level);
Raise_Exception_On_OpenGL_Error;
end Attach_Texture;
procedure Attach_Texture_Layer (Target : Framebuffer_Target;
Attachment : Attachment_Point;
Object : Textures.Texture'Class;
Level : Textures.Mipmap_Level;
Layer : Int) is
begin
API.Framebuffer_Texture_Layer (Target.Kind, Attachment, Object.Raw_Id,
Level, Layer);
Raise_Exception_On_OpenGL_Error;
end Attach_Texture_Layer;
procedure Invalidate (Target : in out Framebuffer_Target;
Attachments : Attachment_List) is
begin
API.Invalidate_Framebuffer (Target.Kind, Attachments'Length, Attachments);
Raise_Exception_On_OpenGL_Error;
end Invalidate;
procedure Invalidate_Sub (Target : in out Framebuffer_Target;
Attachments : Attachment_List;
X, Y : Int;
Width, Height : Size) is
begin
API.Invalidate_Sub_Framebuffer (Target.Kind, Attachments'Length,
Attachments, X, Y, Width, Height);
Raise_Exception_On_OpenGL_Error;
end Invalidate_Sub;
procedure Blit (Src_X0, Src_Y0, Src_X1, Src_Y1,
Dst_X0, Dst_Y0, Dst_X1, Dst_Y1 : Int;
Mask : Buffers.Buffer_Bits;
Filter : Textures.Magnifying_Function) is
use type Low_Level.Bitfield;
function Convert is new Ada.Unchecked_Conversion
(Buffers.Buffer_Bits, Low_Level.Bitfield);
Raw_Bits : constant Low_Level.Bitfield
:= Convert (Mask) and 2#0100010100000000#;
begin
API.Blit_Framebuffer (Src_X0, Src_Y0, Src_X1, Src_Y1,
Dst_X0, Dst_Y0, Dst_X1, Dst_Y1, Raw_Bits, Filter);
Raise_Exception_On_OpenGL_Error;
end Blit;
procedure Set_Default_Width (Target : in out Framebuffer_Target;
Value : Size) is
begin
API.Framebuffer_Parameter_Size (Target.Kind, Enums.Default_Width, Value);
Raise_Exception_On_OpenGL_Error;
end Set_Default_Width;
function Default_Width (Target : Framebuffer_Target) return Size is
Ret : Size;
begin
API.Get_Framebuffer_Parameter_Size
(Target.Kind, Enums.Default_Width, Ret);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Default_Width;
function Max_Framebuffer_Width return Size is
Ret : aliased Size;
begin
API.Get_Size (Enums.Getter.Max_Framebuffer_Width, Ret'Access);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Max_Framebuffer_Width;
procedure Set_Default_Height (Target : in out Framebuffer_Target;
Value : Size) is
begin
API.Framebuffer_Parameter_Size (Target.Kind, Enums.Default_Height,
Value);
Raise_Exception_On_OpenGL_Error;
end Set_Default_Height;
function Default_Height (Target : Framebuffer_Target) return Size is
Ret : Size;
begin
API.Get_Framebuffer_Parameter_Size (Target.Kind, Enums.Default_Height,
Ret);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Default_Height;
function Max_Framebuffer_Height return Size is
Ret : aliased Size;
begin
API.Get_Size (Enums.Getter.Max_Framebuffer_Height, Ret'Unchecked_Access);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Max_Framebuffer_Height;
procedure Set_Default_Layers (Target : in out Framebuffer_Target;
Value : Size) is
begin
API.Framebuffer_Parameter_Size (Target.Kind, Enums.Default_Layers, Value);
Raise_Exception_On_OpenGL_Error;
end Set_Default_Layers;
function Default_Layers (Target : Framebuffer_Target) return Size is
Ret : Size;
begin
API.Get_Framebuffer_Parameter_Size (Target.Kind, Enums.Default_Layers,
Ret);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Default_Layers;
function Max_Framebuffer_Layers return Size is
Ret : aliased Size;
begin
API.Get_Size (Enums.Getter.Max_Framebuffer_Layers, Ret'Unchecked_Access);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Max_Framebuffer_Layers;
procedure Set_Default_Samples (Target : in out Framebuffer_Target;
Value : Size) is
begin
API.Framebuffer_Parameter_Size (Target.Kind, Enums.Default_Samples,
Value);
Raise_Exception_On_OpenGL_Error;
end Set_Default_Samples;
function Default_Samples
(Target : Framebuffer_Target) return Size is
Ret : Size;
begin
API.Get_Framebuffer_Parameter_Size (Target.Kind, Enums.Default_Samples,
Ret);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Default_Samples;
function Max_Framebuffer_Samples return Size is
Ret : aliased Size;
begin
API.Get_Size (Enums.Getter.Max_Framebuffer_Samples, Ret'Unchecked_Access);
Raise_Exception_On_OpenGL_Error;
return Ret;
end Max_Framebuffer_Samples;
procedure Set_Default_Fixed_Sample_Locactions
(Target : in out Framebuffer_Target; Value : Boolean) is
begin
API.Framebuffer_Parameter_Bool
(Target.Kind, Enums.Default_Fixed_Sample_Locations,
Low_Level.Bool (Value));
Raise_Exception_On_OpenGL_Error;
end Set_Default_Fixed_Sample_Locactions;
function Default_Fixed_Sample_Locations (Target : Framebuffer_Target)
return Boolean is
Ret : Low_Level.Bool;
begin
API.Get_Framebuffer_Parameter_Bool
(Target.Kind, Enums.Default_Fixed_Sample_Locations, Ret);
Raise_Exception_On_OpenGL_Error;
return Boolean (Ret);
end Default_Fixed_Sample_Locations;
overriding
procedure Internal_Create_Id (Object : Framebuffer; Id : out UInt) is
pragma Unreferenced (Object);
begin
API.Gen_Framebuffers (1, Id);
Raise_Exception_On_OpenGL_Error;
end Internal_Create_Id;
overriding
procedure Internal_Release_Id (Object : Framebuffer; Id : UInt) is
pragma Unreferenced (Object);
begin
API.Delete_Framebuffers (1, (1 => Id));
Raise_Exception_On_OpenGL_Error;
end Internal_Release_Id;
function Hash (Key : Low_Level.Enums.Framebuffer_Kind)
return Ada.Containers.Hash_Type is
function Value is new Ada.Unchecked_Conversion
(Source => Low_Level.Enums.Framebuffer_Kind, Target => Low_Level.Enum);
begin
return Ada.Containers.Hash_Type (Value (Key));
end Hash;
package Framebuffer_Maps is new Ada.Containers.Indefinite_Hashed_Maps
(Key_Type => Low_Level.Enums.Framebuffer_Kind,
Element_Type => Framebuffer'Class,
Hash => Hash,
Equivalent_Keys => Low_Level.Enums."=");
use type Framebuffer_Maps.Cursor;
Current_Framebuffers : Framebuffer_Maps.Map;
type Framebuffer_Kind_Array is array (Positive range <>) of
Low_Level.Enums.Framebuffer_Kind;
function Backend_Framebuffer_Targets
(Kind : Low_Level.Enums.Framebuffer_Kind) return Framebuffer_Kind_Array is
begin
case Kind is
when Low_Level.Enums.Read => return (1 => Low_Level.Enums.Read);
when Low_Level.Enums.Draw => return (1 => Low_Level.Enums.Draw);
when Low_Level.Enums.Read_Draw =>
return (1 => Low_Level.Enums.Draw, 2 => Low_Level.Enums.Read);
end case;
end Backend_Framebuffer_Targets;
pragma Inline (Backend_Framebuffer_Targets);
procedure Bind (Target : Framebuffer_Target;
Object : Framebuffer'Class) is
-- Read_Draw bind to both read and draw framebuffer, we need to set
-- the current framebuffer objects accordingly.
Targets : constant Framebuffer_Kind_Array
:= Backend_Framebuffer_Targets (Target.Kind);
Cursor : Framebuffer_Maps.Cursor;
begin
API.Bind_Framebuffer (Target.Kind, Object.Reference.GL_Id);
Raise_Exception_On_OpenGL_Error;
for Index in Targets'Range loop
Cursor := Current_Framebuffers.Find (Targets (Index));
if Cursor = Framebuffer_Maps.No_Element then
Current_Framebuffers.Insert (Targets (Index), Object);
elsif Framebuffer_Maps.Element (Cursor).Reference.GL_Id
/= Object.Reference.GL_Id then
Current_Framebuffers.Replace_Element (Cursor, Object);
end if;
end loop;
end Bind;
function Current (Target : Framebuffer_Target) return Framebuffer'Class is
Targets : constant Framebuffer_Kind_Array
:= Backend_Framebuffer_Targets (Target.Kind);
-- If target is Read_Draw, return the draw framebuffer
-- (Note: this is necessary because distinct read/draw framebuffers
-- were added later to the API and therefore might not be available
-- in the context. So everything needs to work with just Read_Draw).
Cursor : constant Framebuffer_Maps.Cursor
:= Current_Framebuffers.Find (Targets (1));
begin
if Cursor = Framebuffer_Maps.No_Element then
raise No_Object_Bound_Exception with Target.Kind'Img;
else
return Framebuffer_Maps.Element (Cursor);
end if;
end Current;
end GL.Objects.Framebuffers;
|