1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173 | -- part of OpenGLAda, (c) 2017 Felix Krause
-- released under the terms of the MIT license, see the file "COPYING"
with Ada.Strings.Fixed;
with Interfaces.C.Strings;
with GL.API;
with GL.Enums.Getter;
with GL.Errors;
package body GL.Context is
function Major_Version return Int is
Result : aliased Int;
begin
API.Get_Integer (Enums.Getter.Major_Version, Result'Access);
Raise_Exception_On_OpenGL_Error;
return Result;
end Major_Version;
function Minor_Version return Int is
Result : aliased Int;
begin
API.Get_Integer (Enums.Getter.Minor_Version, Result'Access);
Raise_Exception_On_OpenGL_Error;
return Result;
end Minor_Version;
function Version_String return String is
begin
return C.Strings.Value (API.Get_String (Enums.Getter.Version));
end Version_String;
function Vendor return String is
begin
return C.Strings.Value (API.Get_String (Enums.Getter.Vendor));
end Vendor;
function Renderer return String is
begin
return C.Strings.Value (API.Get_String (Enums.Getter.Renderer));
end Renderer;
function Extensions return String_List is
use Ada.Strings.Unbounded;
use type Errors.Error_Code;
Count : aliased Int;
begin
API.Get_Integer (Enums.Getter.Num_Extensions, Count'Access);
if API.Get_Error = Errors.No_Error then
-- we are on OpenGL 3
return List : String_List (1 .. Positive (Count)) do
for I in List'Range loop
List (I) := To_Unbounded_String
(C.Strings.Value (API.Get_String_I
(Enums.Getter.Extensions, UInt (I - 1))));
end loop;
end return;
else
-- OpenGL 2 fallback
declare
Raw : constant String := C.Strings.Value
(API.Get_String (Enums.Getter.Extensions));
Cur_Pos : Positive := Raw'First;
Next_Space : Natural;
begin
if Raw'Length = 0 then
return Null_String_List;
end if;
return List : String_List
(1 .. Ada.Strings.Fixed.Count (Raw, " ") + 1) do
for I in List'Range loop
Next_Space := Ada.Strings.Fixed.Index (Raw, " ", Cur_Pos);
if Next_Space = 0 then
-- this is the last token, there is no space behind it.
Next_Space := Raw'Last + 1;
end if;
List (I) := To_Unbounded_String
(Raw (Cur_Pos .. Next_Space - 1));
Cur_Pos := Next_Space + 1;
end loop;
end return;
end;
end if;
end Extensions;
function Has_Extension (Name : String) return Boolean is
use type Errors.Error_Code;
Count : aliased Int;
begin
API.Get_Integer (Enums.Getter.Num_Extensions, Count'Access);
if API.Get_Error = Errors.No_Error then
-- we are on OpenGL 3
for I in 1 .. Count loop
declare
Extension : constant String := C.Strings.Value
(API.Get_String_I (Enums.Getter.Extensions, UInt (I - 1)));
begin
if Extension = Name then
return True;
end if;
end;
end loop;
else
-- OpenGL 2 fallback
declare
Raw : constant String := C.Strings.Value
(API.Get_String (Enums.Getter.Extensions));
Cur_Pos : Positive := Raw'First;
Next_Space : Natural;
begin
if Raw'Length = 0 then
return False;
end if;
for I in 1 .. Ada.Strings.Fixed.Count (Raw, " ") + 1 loop
Next_Space := Ada.Strings.Fixed.Index (Raw, " ", Cur_Pos);
if Next_Space = 0 then
Next_Space := Raw'Last + 1;
end if;
if Raw (Cur_Pos .. Next_Space - 1) = Name then
return True;
end if;
Cur_Pos := Next_Space + 1;
end loop;
end;
end if;
return False;
end Has_Extension;
function Primary_Shading_Language_Version return String is
Result : constant String := C.Strings.Value
(API.Get_String (Enums.Getter.Shading_Language_Version));
begin
Raise_Exception_On_OpenGL_Error;
return Result;
end Primary_Shading_Language_Version;
function Supported_Shading_Language_Versions return String_List is
use Ada.Strings.Unbounded;
use type Errors.Error_Code;
Count : aliased Int;
begin
API.Get_Integer (Enums.Getter.Num_Shading_Language_Versions, Count'Access);
if API.Get_Error = Errors.Invalid_Enum then
raise Feature_Not_Supported_Exception;
end if;
return List : String_List (1 .. Positive (Count)) do
for I in List'Range loop
List (I) := To_Unbounded_String
(C.Strings.Value (API.Get_String_I (
Enums.Getter.Shading_Language_Version, UInt (I - 1))));
end loop;
end return;
end Supported_Shading_Language_Versions;
function Supports_Shading_Language_Version (Name : String) return Boolean is
Count : aliased Int;
begin
API.Get_Integer (Enums.Getter.Num_Shading_Language_Versions, Count'Access);
Raise_Exception_On_OpenGL_Error;
for I in 1 .. Count loop
if C.Strings.Value
(API.Get_String_I (Enums.Getter.Shading_Language_Version,
UInt (I - 1))) = Name then
return True;
end if;
end loop;
return False;
end Supports_Shading_Language_Version;
end GL.Context;
|