1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273 | ------------------------------------------------------------------------------
-- --
-- GNAT2XML COMPONENTS --
-- --
-- V E C T O R S --
-- --
-- S p e c --
-- --
-- Copyright (C) 2013-2017, AdaCore --
-- --
-- Gnat2xml is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 2, or (at your option) any later --
-- version. Gnat2xml is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MER- --
-- CHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General --
-- Public License for more details. You should have received a copy of the --
-- GNU General Public License distributed with GNAT; see file COPYING. If --
-- not, write to the Free Software Foundation, 59 Temple Place Suite 330, --
-- Boston, MA 02111-1307, USA. --
-- The gnat2xml tool was derived from the Avatox sources. --
------------------------------------------------------------------------------
with Ada.Containers; use Ada.Containers;
with Ada.Iterator_Interfaces;
private with Ada.Finalization;
generic
type Index_Type is range <>;
type Element_Type is private;
type Elements_Array is array (Index_Type range <>) of Element_Type;
with function "=" (Left, Right : Element_Type) return Boolean is <>;
package Utils.Fast_Vectors is
-- This is a more efficient version of Ada.Containers.Vectors.
pragma Suppress (All_Checks);
pragma Assert (Index_Type'First = 1);
pragma Assert (Index_Type'Last >= 2**24 - 1);
-- These assumptions allow us to avoid a lot of horsing around. But we
-- still inherit some such horsing from Ada.Containers.Vectors.
subtype Extended_Index is
Index_Type'
Base range Index_Type'First - 1 ..
Index_Type'Min (Index_Type'Base'Last - 1, Index_Type'Last) + 1;
No_Index : constant Extended_Index := Extended_Index'First;
type Vector is tagged private with
Constant_Indexing => Constant_Reference,
Variable_Indexing => Reference,
Default_Iterator => Iterate,
Iterator_Element => Element_Type;
type Cursor is private;
No_Element : constant Cursor;
function Has_Element (Position : Cursor) return Boolean;
package Vector_Iterator_Interfaces is new Ada.Iterator_Interfaces (Cursor,
Has_Element);
Empty_Vector : constant Vector;
overriding function "=" (Left, Right : Vector) return Boolean;
function Length (Container : Vector) return Count_Type;
procedure Set_Length (Container : in out Vector; Length : Count_Type);
function Is_Empty (Container : Vector) return Boolean;
procedure Clear (Container : in out Vector);
procedure Free (Container : in out Vector);
-- Same as Clear, but also frees storage
function To_Cursor
(Container : Vector; Index : Extended_Index) return Cursor;
function To_Index (Position : Cursor) return Extended_Index;
function Element
(Container : Vector; Index : Index_Type) return Element_Type;
function Element (Position : Cursor) return Element_Type;
type Constant_Reference_Type
(Element : not null access constant Element_Type) is
private with
Implicit_Dereference => Element;
type Reference_Type (Element : not null access Element_Type) is private with
Implicit_Dereference => Element;
function Constant_Reference
(Container : aliased Vector; Position : Cursor)
return Constant_Reference_Type;
function Reference
(Container : aliased in out Vector; Position : Cursor)
return Reference_Type;
function Constant_Reference
(Container : aliased Vector; Index : Index_Type)
return Constant_Reference_Type;
function Reference
(Container : aliased in out Vector; Index : Index_Type)
return Reference_Type;
procedure Move (Target : in out Vector; Source : in out Vector);
procedure Append (Container : in out Vector; New_Item : Element_Type);
procedure Push (Container : in out Vector; New_Item : Element_Type) renames
Append;
type Element_Access is access all Element_Type;
function Last_Ptr (Container : in out Vector) return Element_Access;
function Append (Container : in out Vector) return Element_Access;
procedure Delete_Last (Container : in out Vector);
procedure Pop (Container : in out Vector) renames Delete_Last;
function First (Container : Vector) return Cursor;
function Last_Index (Container : Vector) return Extended_Index;
function Last (Container : Vector) return Cursor;
function Last_Element (Container : Vector) return Element_Type;
function Next (Position : Cursor) return Cursor;
procedure Next (Position : in out Cursor);
function Previous (Position : Cursor) return Cursor;
procedure Previous (Position : in out Cursor);
procedure Iterate
(Container : Vector;
Process : not null access procedure (Position : Cursor));
procedure Reverse_Iterate
(Container : Vector;
Process : not null access procedure (Position : Cursor));
function Iterate
(Container : Vector)
return Vector_Iterator_Interfaces.Reversible_Iterator'Class;
function Iterate
(Container : Vector; Start : Cursor)
return Vector_Iterator_Interfaces.Reversible_Iterator'Class;
generic
with function "<" (Left, Right : Element_Type) return Boolean is <>;
package Generic_Sorting is
function Is_Sorted (Container : Vector) return Boolean;
procedure Sort (Container : in out Vector);
procedure Merge (Target : in out Vector; Source : in out Vector);
end Generic_Sorting;
-- Extra operations not in Ada.Containers.Vectors:
subtype Big_Elements_Array is Elements_Array (Index_Type);
type Big_Ptr is access constant Big_Elements_Array;
pragma No_Strict_Aliasing (Big_Ptr);
type Big_Ptr_Var is access all Big_Elements_Array;
pragma No_Strict_Aliasing (Big_Ptr_Var);
function Elems (Container : Vector) return Big_Ptr; -- with
-- Post => Elems'Result'First = Index_Type'First;
function Elems_Var (Container : Vector) return Big_Ptr_Var; -- with
-- Post => Elems_Var'Result'First = Index_Type'First;
-- ???Above postconditions cause warnings These return a pointer to the
-- underlying data structure. This is of course dangerous. The idea is
-- that you can do:
--
-- X : Elems_Array renames Elems (V) (1 .. Last_Index (V));
--
-- But don't do Append (etc) while X still exists. Do not call these
-- without the slicing.
type Subrange is record
First : Index_Type;
Last : Extended_Index;
end record;
function Full_Range (Container : Vector) return Subrange is
(1, Last_Index (Container));
function Slice
(Container : Vector; First : Index_Type; Last : Extended_Index)
return Elements_Array with
Post => Slice'Result'First = Index_Type'First;
function Slice (Container : Vector; R : Subrange) return Elements_Array is
(Slice (Container, R.First, R.Last));
function To_Array (Container : Vector) return Elements_Array with
Post => To_Array'Result'First = Index_Type'First;
procedure Append (Container : in out Vector; New_Items : Elements_Array);
procedure Put
(Container : Vector;
Put : not null access procedure (Item : Element_Type);
Put_Between : not null access procedure);
-- Prints out the Container for debugging. We don't want to depend on any
-- output packages here, so you must pass in Put (to print out an element)
-- and Put_Between (to print out a separator between elements).
private
pragma Inline (Append);
pragma Inline (Constant_Reference);
pragma Inline (Clear);
pragma Inline (Reference);
pragma Inline (Last_Index);
pragma Inline (Element);
pragma Inline (Last_Element);
pragma Inline (Is_Empty);
function "=" (L, R : Elements_Array) return Boolean is abstract;
type Elements_Type (Last : Extended_Index) is limited record
EA : aliased Elements_Array (Index_Type'First .. Last);
end record;
Empty_Elements : aliased Elements_Type := (Last => 0, EA => (others => <>));
type Elements_Access is access all Elements_Type;
use Ada.Finalization;
type Vector is new Controlled with record
Elements : Elements_Access := Empty_Elements'Access;
Last : Extended_Index := No_Index;
end record;
overriding procedure Adjust (Container : in out Vector);
overriding procedure Finalize (Container : in out Vector);
type Vector_Access is access all Vector;
type Cursor is record
Container : Vector_Access;
Index : Index_Type := Index_Type'First;
end record;
type Constant_Reference_Type
(Element : not null access constant Element_Type) is null record;
type Reference_Type (Element : not null access Element_Type) is null record;
No_Element : constant Cursor := Cursor'(null, Index_Type'First);
Empty_Vector : constant Vector := (Controlled with others => <>);
end Utils.Fast_Vectors;
|