1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184 | -- --
-- package Copyright (c) Dmitry A. Kazakov --
-- Synchronization.Interprocess. Luebeck --
-- Mutexes Spring, 2018 --
-- Interface --
-- Last revision : 01:09 01 May 2018 --
-- --
-- This library is free software; you can redistribute it and/or --
-- modify it under the terms of the GNU General Public License as --
-- published by the Free Software Foundation; either version 2 of --
-- the License, or (at your option) any later version. This library --
-- is distributed in the hope that it will be useful, but WITHOUT --
-- ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. You should have --
-- received a copy of the GNU General Public License along with --
-- this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
-- As a special exception, if other files instantiate generics from --
-- this unit, or you link this unit with other files to produce an --
-- executable, this unit does not by itself cause the resulting --
-- executable to be covered by the GNU General Public License. This --
-- exception does not however invalidate any other reasons why the --
-- executable file might be covered by the GNU Public License. --
--____________________________________________________________________--
with Ada.Task_Identification; use Ada.Task_Identification;
package Synchronization.Interprocess.Mutexes is
--
-- Mutex -- A mutex object. The mutex must be a component of an
-- environment object. The mutex can be seized and released.
-- Only one task can hold the mutex. The same task can take it
-- several times without deadlocking. If taken multiple times
-- the mutex must be released for each take.
--
type Mutex is new Abstract_Shared_Object with private;
--
-- Get_Timeout -- The mutex seize timeout
--
-- Object - The mutex object
--
-- Returns :
--
-- The timeout used in the the Seize
--
function Get_Timeout (Object : Mutex) return Duration;
--
-- Grab -- The mutex if not owned
--
-- Object - The mutex object
--
-- This procedure seizes the mutex if it is not owned or else is owned
-- by the caller. Is_Mine can be used after Grab in order to verify if
-- the mutex was seized. For example:
--
-- Grab (Resource); -- Try to seize it without blocking
-- if Is_Mine (Resource) then
-- ... -- Use the resource
-- Release (Resource); -- Note, it has to be released
-- end if;
--
-- Exceptions :
--
-- Data_Error - System errors
-- Status_Error - The mutex is not initialized
--
procedure Grab (Object : in out Mutex);
--
-- Is_Mine -- Check if the mutex is owned by the caller
--
-- Object - The mutex object
--
-- Returns :
--
-- True if owned by the caller
--
-- Exceptions :
--
-- Data_Error - System errors
-- Status_Error - The mutex is not initialized
--
function Is_Mine (Object : Mutex) return Boolean;
--
-- Is_Owned -- Check if the mutex is owned
--
-- Object - The mutex object
--
-- Returns :
--
-- True if owned
--
-- Exceptions :
--
-- Data_Error - System errors
-- Status_Error - The mutex is not initialized
--
function Is_Owned (Object : Mutex) return Boolean;
--
-- Release -- The mutex
--
-- Object - The mutex object
--
-- Exceptions :
--
-- Data_Error - System errors
-- Ownership_Error - The mutex is not owned by the caller
-- Status_Error - The mutex is not initialized
--
procedure Release (Object : in out Mutex);
--
-- Seize -- The mutex
--
-- Object - The mutex object
-- [ Timeout ] - Time before Timeout_Error is propagated
--
-- Seize does not block when the task already owns the mutex. Each call
-- to Seize shall be matched by a call to Release.
--
-- Exceptions :
--
-- Data_Error - System errors
-- Status_Error - The mutex is not initialized
-- Timeout_Error - Timed out
--
procedure Seize (Object : in out Mutex);
procedure Seize (Object : in out Mutex; Timeout : Duration);
--
-- Set_Timeout -- The mutex seize timeout
--
-- Object - The mutex object
-- Timeout - The timeout to be used in the the Seize
--
procedure Set_Timeout
( Object : in out Mutex;
Timeout : Duration
);
--
-- Holder -- A mutex holder object. This is a helper which ensures
-- releasing of a mutex even upon exception propagation.
--
-- Resource - A pointer to the mutex to seize
--
type Holder (Resource : access Mutex) is
new Ada.Finalization.Limited_Controlled with private;
--
-- Finalize -- Destruction
--
-- This procedure releases the mutex. It shall be called by the derived
-- type if overridden.
--
procedure Finalize (Object : in out Holder);
--
-- Initialize -- Construction
--
-- This procedure seizes the mutex. It shall be called by the derived
-- type if overridden.
--
procedure Initialize (Object : in out Holder);
private
type Holder (Resource : access Mutex) is
new Ada.Finalization.Limited_Controlled with null record;
type Mutex_Data is record
Futex : aliased int := 0;
Count : Natural := 0;
end record;
type Mutex_Data_Ptr is access all Mutex_Data;
type Mutex is new Abstract_Shared_Object with record
Data : Mutex_Data_Ptr;
Timeout : Duration := 10.0;
end record;
procedure Finalize (Object : in out Mutex);
function Get_Size (Object : Mutex) return Storage_Count;
procedure Map
( Object : in out Mutex;
Shared : in out Abstract_Shared_Environment'Class;
Location : System.Address;
Size : Storage_Count;
Owner : Boolean
);
end Synchronization.Interprocess.Mutexes;
|