1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191 | ------------------------------------------------------------------------------
-- G N A T C O L L --
-- --
-- Copyright (C) 2005-2020, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify it --
-- under terms of the GNU General Public License as published by the Free --
-- Software Foundation; either version 3, or (at your option) any later --
-- version. This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception, --
-- version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
-- This package declares various types and subprograms that must be overridden
-- by anyone wishing to add new backends to GNATCOLL.SQL.Exec.
-- Most users can ignore the contents of this package altogether, since none
-- of these types is intended to be visible in the user's code. They are
-- wrapped up in other types in GNATCOLL.SQL.Exec, which is the actual user
-- API.
with Ada.Strings.Fixed; use Ada.Strings.Fixed;
with GNATCOLL.Utils; use GNATCOLL.Utils;
package body GNATCOLL.SQL.Exec_Private is
function Class_Value
(Self : DBMS_Forward_Cursor'Class; Field : Field_Index) return String
is (Value (Self, Field)) with Inline_Always;
generic
type Base_Type is digits <>;
function Any_Float_Value (S : String) return Base_Type;
-----------
-- Value --
-----------
function Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return String is
begin
return Value (C_Value (DBMS_Forward_Cursor'Class (Self), Field));
end Value;
---------------------
-- Unbounded_Value --
---------------------
function Unbounded_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return Unbounded_String is
begin
return To_Unbounded_String (Self.Class_Value (Field));
end Unbounded_Value;
-------------------
-- XString_Value --
-------------------
function XString_Value
(Self : DBMS_Forward_Cursor; Field : Field_Index) return XString is
begin
return To_XString (Self.Class_Value (Field));
end XString_Value;
-------------------
-- Boolean_Value --
-------------------
function Boolean_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return Boolean is
begin
return Boolean'Value (Self.Class_Value (Field));
end Boolean_Value;
-------------------
-- Integer_Value --
-------------------
function Integer_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return Integer is
begin
return Integer'Value (Self.Class_Value (Field));
end Integer_Value;
------------------
-- Bigint_Value --
------------------
function Bigint_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return Long_Long_Integer is
begin
return Long_Long_Integer'Value (Self.Class_Value (Field));
end Bigint_Value;
---------------------
-- Any_Float_Value --
---------------------
function Any_Float_Value (S : String) return Base_Type is
pragma Warnings (Off, "*is not modified, could be declared constant");
Zero : Base_Type := 0.0;
pragma Warnings (On, "*is not modified, could be declared constant");
begin
if S = "NaN" then
return 0.0 / Zero;
elsif S = "-Infinity" then
return -1.0 / Zero;
elsif S = "Infinity" then
return 1.0 / Zero;
else
return Base_Type'Value (S);
end if;
end Any_Float_Value;
-----------------
-- Float_Value --
-----------------
function Float_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return Float
is
function To_Float is new Any_Float_Value (Float);
begin
return To_Float (Self.Class_Value (Field));
end Float_Value;
----------------------
-- Long_Float_Value --
----------------------
function Long_Float_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return Long_Float
is
function To_Float is new Any_Float_Value (Long_Float);
begin
return To_Float (Self.Class_Value (Field));
end Long_Float_Value;
-----------------
-- Money_Value --
-----------------
function Money_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return T_Money
is
begin
return T_Money'Value (Self.Class_Value (Field));
end Money_Value;
----------------
-- Time_Value --
----------------
function Time_Value
(Self : DBMS_Forward_Cursor;
Field : Field_Index) return Ada.Calendar.Time
is
Val : constant String := Self.Class_Value (Field);
begin
if Val = "" then
return No_Time;
else
-- Workaround bug(?) in GNAT.Calendar.Time_IO: if there is no time,
-- set one to avoid daylight saving time issues
if Ada.Strings.Fixed.Index (Val, ":") < Val'First then
return GNATCOLL.Utils.Time_Value (Val & " 12:00:00");
else
return GNATCOLL.Utils.Time_Value (Val);
end if;
end if;
end Time_Value;
end GNATCOLL.SQL.Exec_Private;
|