1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159 | ------------------------------------------------------------------------------
-- --
-- GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS --
-- --
-- S Y S T E M . M U L T I P R O C E S S O R S . F A I R _ L O C K S --
-- --
-- B o d y --
-- --
-- Copyright (C) 2010-2023, AdaCore --
-- --
-- GNARL is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 3, or (at your option) any later ver- --
-- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
-- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
-- or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception, --
-- version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
------------------------------------------------------------------------------
with System.OS_Interface;
package body System.Multiprocessors.Fair_Locks is
use System.Multiprocessors.Spin_Locks;
Multiprocessor : constant Boolean := CPU'Range_Length /= 1;
-- Set true if on multiprocessor (more than one CPU)
function Next_Spinning (Flock : Fair_Lock) return CPU;
pragma Inline (Next_Spinning);
-- Search for the next spinning CPU. If no one is spinning return the
-- current CPU.
----------------
-- Initialize --
----------------
procedure Initialize (Flock : in out Fair_Lock) is
begin
Unlock (Flock.Lock);
Flock.Spinning := (others => False);
end Initialize;
----------
-- Lock --
----------
procedure Lock (Flock : in out Fair_Lock) is
CPU_Id : constant CPU := System.OS_Interface.Current_CPU;
Succeeded : Boolean;
begin
-- Notify we are waiting for the lock
Flock.Spinning (CPU_Id) := True;
loop
Try_Lock (Flock.Lock, Succeeded);
if Succeeded then
-- We have the lock
Flock.Spinning (CPU_Id) := False;
return;
else
loop
if not Flock.Spinning (CPU_Id) then
-- Lock's owner gives us the lock
return;
end if;
-- Lock's owner left but didn't wake us up, retry to get lock
exit when not Locked (Flock.Lock);
end loop;
end if;
end loop;
end Lock;
------------
-- Locked --
------------
function Locked (Flock : Fair_Lock) return Boolean is
begin
return Locked (Flock.Lock);
end Locked;
-------------------
-- Next_Spinning --
-------------------
function Next_Spinning (Flock : Fair_Lock) return CPU is
Current : constant CPU := System.OS_Interface.Current_CPU;
CPU_Id : CPU := Current;
begin
if Multiprocessor then
-- Only for multiprocessor
loop
if CPU_Id = CPU'Last then
CPU_Id := CPU'First;
else
CPU_Id := CPU_Id + 1;
end if;
exit when Flock.Spinning (CPU_Id) or else CPU_Id = Current;
end loop;
end if;
return CPU_Id;
end Next_Spinning;
--------------
-- Try_Lock --
--------------
procedure Try_Lock (Flock : in out Fair_Lock; Succeeded : out Boolean) is
begin
Try_Lock (Flock.Lock, Succeeded);
end Try_Lock;
------------
-- Unlock --
------------
procedure Unlock (Flock : in out Fair_Lock) is
CPU_Id : constant CPU := Next_Spinning (Flock);
begin
if CPU_Id /= System.OS_Interface.Current_CPU then
-- Wake up the next spinning CPU
Flock.Spinning (CPU_Id) := False;
else
-- Nobody is waiting for the Lock
Unlock (Flock.Lock);
end if;
end Unlock;
end System.Multiprocessors.Fair_Locks;
|