1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443 | ------------------------------------------------------------------------------
-- --
-- GLADE TOOLS --
-- --
-- G L A D E . U T I L S --
-- --
-- B o d y --
-- --
-- Copyright (C) 1996-2020 Free Software Foundation, Inc. --
-- --
-- GLADE is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 2, or (at your option) any later ver- --
-- sion. GLADE is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABI- --
-- LITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public --
-- License for more details. You should have received a copy of the GNU --
-- General Public License distributed with GLADE; see file COPYING. If --
-- not, write to the Free Software Foundation, 59 Temple Place - Suite 330, --
-- Boston, MA 02111-1307, USA. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
-- --
------------------------------------------------------------------------------
with Ada.Exceptions;
with Ada.Unchecked_Deallocation;
with System.Tasking_Soft_Links; use System.Tasking_Soft_Links;
package body GLADE.Utils is
use Ada.Task_Identification;
protected type Barrier_PO is
entry Wait;
procedure Signal (How_Many : Positive := 1);
procedure Signal_All (Permanent : Boolean);
private
Free : Natural := 0;
Perm : Boolean := False;
end Barrier_PO;
-- Any number of task may be waiting on Wait. Signal unblocks How_Many
-- tasks (the order depends on the queuing policy) and Signal_All
-- unblocks all the tasks and Wait will no longer be blocking. If
-- How_Many is more than the number of tasks waiting, new tasks will be
-- awakened as well.
protected type Mutex_PO is
entry Enter;
procedure Leave;
private
Locked : Boolean := False;
end Mutex_PO;
protected type Watcher_PO is
function Lookup return Version_Id;
procedure Update;
entry Differ (V : in Version_Id);
private
entry Await (V : in Version_Id);
Current : Version_Id := Version_Id'First;
Passing : Boolean := True;
end Watcher_PO;
type Adv_Mutex_PO is limited record
Mutex : Mutex_Type;
Current : Ada.Task_Identification.Task_Id;
pragma Atomic (Current);
Level : Natural;
pragma Atomic (Level);
end record;
-- This is a classical critical section except that when a task try to
-- Enter a critical section several times without leaving it first it
-- is not blocked and can continue. Leave keeps track of the number of
-- times Enter has been successful.
procedure Free is
new Ada.Unchecked_Deallocation (Mutex_PO, Mutex_Type);
procedure Free is
new Ada.Unchecked_Deallocation (Adv_Mutex_PO, Adv_Mutex_Type);
procedure Free is
new Ada.Unchecked_Deallocation (Watcher_PO, Watcher_Type);
procedure Free is
new Ada.Unchecked_Deallocation (Barrier_PO, Barrier_Type);
----------------------
-- Access_To_String --
----------------------
function Access_To_String (S : String_Access) return String is
begin
return S.all;
end Access_To_String;
------------------
-- Barrier_PO --
------------------
protected body Barrier_PO is
------------
-- Signal --
------------
procedure Signal (How_Many : Positive := 1) is
begin
if not Perm then
Free := Free + How_Many;
end if;
end Signal;
----------------
-- Signal_All --
----------------
procedure Signal_All (Permanent : Boolean) is
begin
if not Perm then
if Permanent then
Perm := True;
else
Free := Free + Wait'Count;
end if;
end if;
end Signal_All;
----------
-- Wait --
----------
entry Wait when Perm or else Free > 0 is
begin
if not Perm then
Free := Free - 1;
end if;
end Wait;
end Barrier_PO;
------------
-- Lookup --
------------
procedure Lookup (W : in Watcher_Type; V : out Version_Id) is
begin
pragma Assert (W /= null);
V := W.Lookup;
end Lookup;
------------
-- Create --
------------
procedure Create (B : out Barrier_Type) is
begin
B := new Barrier_PO;
end Create;
------------
-- Create --
------------
procedure Create (W : out Watcher_Type) is
begin
W := new Watcher_PO;
end Create;
------------
-- Create --
------------
procedure Create (M : out Adv_Mutex_Type) is
begin
M := new Adv_Mutex_PO;
Create (M.Mutex);
M.Current := Null_Task_Id;
M.Level := 0;
end Create;
------------
-- Create --
------------
procedure Create (M : out Mutex_Type) is
begin
M := new Mutex_PO;
end Create;
-------------
-- Destroy --
-------------
procedure Destroy (B : in out Barrier_Type) is
begin
Free (B);
end Destroy;
-------------
-- Destroy --
-------------
procedure Destroy (W : in out Watcher_Type) is
begin
Free (W);
end Destroy;
-------------
-- Destroy --
-------------
procedure Destroy (M : in out Adv_Mutex_Type) is
begin
pragma Assert (M /= null);
Destroy (M.Mutex);
Free (M);
end Destroy;
-------------
-- Destroy --
-------------
procedure Destroy (M : in out Mutex_Type) is
begin
Free (M);
end Destroy;
------------
-- Differ --
------------
procedure Differ (W : in Watcher_Type; V : in Version_Id) is
begin
pragma Assert (W /= null);
W.Differ (V);
end Differ;
-----------
-- Enter --
-----------
procedure Enter (M : Mutex_Type) is
begin
pragma Assert (M /= null);
Abort_Defer.all;
M.Enter;
end Enter;
-----------
-- Enter --
-----------
procedure Enter (M : Adv_Mutex_Type) is
Self : constant Task_Id := Current_Task;
begin
pragma Assert (M /= null);
if M.Current /= Self then
Enter (M.Mutex);
pragma Assert (M.Current = Null_Task_Id);
pragma Assert (M.Level = 0);
M.Current := Self;
end if;
M.Level := M.Level + 1;
end Enter;
-----------
-- Leave --
-----------
procedure Leave (M : in Adv_Mutex_Type) is
begin
pragma Assert (M /= null
and then M.Current = Current_Task
and then M.Level > 0);
M.Level := M.Level - 1;
if M.Level = 0 then
M.Current := Null_Task_Id;
Leave (M.Mutex);
end if;
end Leave;
-----------
-- Leave --
-----------
procedure Leave (M : in Mutex_Type) is
begin
pragma Assert (M /= null);
Abort_Undefer.all;
M.Leave;
end Leave;
--------------
-- Mutex_PO --
--------------
protected body Mutex_PO is
-----------
-- Enter --
-----------
entry Enter when not Locked is
begin
Locked := True;
end Enter;
------------
-- Leave --
------------
procedure Leave is
begin
Locked := False;
end Leave;
end Mutex_PO;
----------------------
-- String_To_Access --
----------------------
function String_To_Access (S : String) return String_Access is
begin
return new String'(S);
end String_To_Access;
------------
-- Signal --
------------
procedure Signal (B : in Barrier_Type; N : in Positive := 1) is
begin
pragma Assert (B /= null);
B.Signal (N);
end Signal;
----------------
-- Signal_All --
----------------
procedure Signal_All (B : in Barrier_Type; P : in Boolean := True) is
begin
pragma Assert (B /= null);
B.Signal_All (P);
end Signal_All;
--------------
-- To_Lower --
--------------
procedure To_Lower (Item : in out String) is
begin
for I in Item'Range loop
if Item (I) in 'A' .. 'Z' then
Item (I) :=
Character'Val (Character'Pos (Item (I)) -
Character'Pos ('A') +
Character'Pos ('a'));
end if;
end loop;
end To_Lower;
------------
-- Update --
------------
procedure Update (W : in Watcher_Type) is
begin
pragma Assert (W /= null);
W.Update;
end Update;
----------
-- Wait --
----------
procedure Wait (B : in Barrier_Type) is
begin
pragma Assert (B /= null);
B.Wait;
end Wait;
----------------
-- Watcher_PO --
----------------
protected body Watcher_PO is
-----------
-- Await --
-----------
entry Await (V : in Version_Id) when not Passing is
begin
if Await'Count = 0 then
Passing := True;
end if;
requeue Differ with abort;
end Await;
------------
-- Lookup --
------------
function Lookup return Version_Id is
begin
return Current;
end Lookup;
------------
-- Differ --
------------
entry Differ (V : in Version_Id) when Passing is
begin
if Current = V then
requeue Await with abort;
end if;
end Differ;
------------
-- Update --
------------
procedure Update is
begin
Current := Current + 1;
if Current = No_Version then
Current := Current + 1;
end if;
if Await'Count /= 0 then
Passing := False;
end if;
end Update;
end Watcher_PO;
end GLADE.Utils;
|