1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2002-2012, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under terms of the GNU General Public License as published by the --
-- Free Software Foundation; either version 3, or (at your option) any --
-- later version. This library is distributed in the hope that it will be --
-- useful, but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are --
-- granted additional permissions described in the GCC Runtime Library --
-- Exception, version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
------------------------------------------------------------------------------
with Ada.Containers.Indefinite_Hashed_Maps;
with Ada.Strings.Hash;
with AWS.Resources.Streams.ZLib;
with ZLib;
package body AWS.Resources.Embedded is
type Node is record
File_Buffer : Buffer_Access;
File_Time : Calendar.Time;
end record;
package Res_Files is new Ada.Containers.Indefinite_Hashed_Maps
(String, Node, Ada.Strings.Hash, "=", "=");
Files_Table : Res_Files.Map;
procedure Append
(Stream : Streams.Stream_Access;
Data : Buffer_Access);
------------
-- Append --
------------
procedure Append
(Stream : Streams.Stream_Access;
Data : Buffer_Access) is
begin
Streams.Memory.Append
(Streams.Memory.Stream_Type (Stream.all), Data);
end Append;
------------
-- Create --
------------
procedure Create
(File : out File_Type;
Buffer : Buffer_Access)
is
Stream : Streams.Stream_Access;
begin
Stream := new Streams.Memory.Stream_Type;
Append (Stream, Buffer);
Streams.Create (File, Stream);
end Create;
-----------
-- Exist --
-----------
function Exist (Name : String) return File_Instance is
VP, VG : Boolean := False;
begin
if Is_GZip (Name) then
VG := Res_Files.Contains (Files_Table, Name);
VP := Res_Files.Contains
(Files_Table,
(Name (Name'First .. Name'Last - GZip_Ext'Length)));
else
VP := Res_Files.Contains (Files_Table, Name);
VG := Res_Files.Contains (Files_Table, Name & GZip_Ext);
end if;
if VG and then VP then
return Both;
elsif VG then
return GZip;
elsif VP then
return Plain;
else
return None;
end if;
end Exist;
---------------
-- File_Size --
---------------
function File_Size (Name : String) return Utils.File_Size_Type is
Cursor : Res_Files.Cursor;
begin
Cursor := Res_Files.Find (Files_Table, Name);
if Res_Files.Has_Element (Cursor) then
return Res_Files.Element (Cursor).File_Buffer'Length;
elsif Is_GZip (Name) then
-- Don't look for resource Name & ".gz.gz"
raise Resource_Error;
end if;
Cursor := Res_Files.Find (Files_Table, Name & GZip_Ext);
if Res_Files.Has_Element (Cursor) then
return Res_Files.Element (Cursor).File_Buffer'Length;
else
raise Resource_Error;
end if;
end File_Size;
--------------------
-- File_Timestamp --
--------------------
function File_Timestamp (Name : String) return Ada.Calendar.Time is
Cursor : Res_Files.Cursor;
begin
Cursor := Res_Files.Find (Files_Table, Name);
if Res_Files.Has_Element (Cursor) then
return Res_Files.Element (Cursor).File_Time;
elsif Is_GZip (Name) then
-- Don't look for resource Name & ".gz.gz";
raise Resource_Error;
end if;
Cursor := Res_Files.Find (Files_Table, Name & GZip_Ext);
if Res_Files.Has_Element (Cursor) then
return Res_Files.Element (Cursor).File_Time;
else
raise Resource_Error;
end if;
end File_Timestamp;
----------------
-- Get_Buffer --
----------------
function Get_Buffer
(Name : String; GZip : in out Boolean) return Buffer_Access
is
function Has_Embedded (Name : String) return Boolean with Inline;
-- Returns True and set Cursor to resource with Name in
-- Files_Table if found.
Cursor : Res_Files.Cursor;
------------------
-- Has_Embedded --
------------------
function Has_Embedded (Name : String) return Boolean is
begin
Cursor := Files_Table.Find (Name);
return Res_Files.Has_Element (Cursor);
end Has_Embedded;
begin
if Check_Name (Name, Has_Embedded'Access, GZip) = "" then
return null;
else
return Res_Files.Element (Cursor).File_Buffer;
end if;
end Get_Buffer;
---------------------
-- Is_Regular_File --
---------------------
function Is_Regular_File (Name : String) return Boolean is
begin
return Res_Files.Contains (Files_Table, Name)
or else (not Is_GZip (Name)
and then Res_Files.Contains (Files_Table, Name & GZip_Ext));
end Is_Regular_File;
----------
-- Open --
----------
procedure Open
(File : out File_Type;
Name : String;
Form : String := "";
GZip : in out Boolean)
is
use type Buffer_Access;
pragma Unreferenced (Form);
Stream : AWS.Resources.Streams.Stream_Access;
In_GZip : constant Boolean := GZip;
Buffer : constant Buffer_Access := Get_Buffer (Name, GZip);
begin
if Buffer = null then
File := null;
return;
end if;
Stream := new Streams.Memory.Stream_Type;
Streams.Memory.Stream_Type (Stream.all).Append (Buffer);
if GZip and not In_GZip then
Stream := Streams.ZLib.Inflate_Create (Stream, Header => ZLib.GZip);
end if;
Streams.Create (File, Stream);
end Open;
--------------
-- Register --
--------------
procedure Register
(Name : String;
Content : Buffer_Access;
File_Time : Calendar.Time)
is
N : constant Node := (Content, File_Time);
begin
Res_Files.Include (Files_Table, Name, N);
end Register;
end AWS.Resources.Embedded;
|