1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2012-2022, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under terms of the GNU General Public License as published by the --
-- Free Software Foundation; either version 3, or (at your option) any --
-- later version. This library is distributed in the hope that it will be --
-- useful, but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are --
-- granted additional permissions described in the GCC Runtime Library --
-- Exception, version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
------------------------------------------------------------------------------
pragma Ada_2012;
with Ada.Containers.Indefinite_Ordered_Maps;
with Ada.Containers.Indefinite_Vectors;
with Ada.Containers.Ordered_Maps;
with Ada.Containers.Ordered_Sets;
pragma Warnings (Off, "is an internal GNAT unit");
with Ada.Strings.Unbounded.Aux;
pragma Warnings (On, "is an internal GNAT unit");
with Ada.Unchecked_Deallocation;
with GNAT.Regpat;
with AWS.Config;
with AWS.Net.Generic_Sets;
with AWS.Net.Memory;
with AWS.Net.Poll_Events;
with AWS.Net.Std;
with AWS.Utils;
package body AWS.Net.WebSocket.Registry is
use GNAT;
use GNAT.Regpat;
use type Ada.Containers.Count_Type;
-- Container for URI based registered constructors
package Constructors is
new Ada.Containers.Indefinite_Ordered_Maps (String, Factory);
Factories : Constructors.Map;
-- Container for Pattern based registered constructors
type P_Data (Size : Regpat.Program_Size) is record
Pattern : Regpat.Pattern_Matcher (Size);
Factory : Registry.Factory;
end record;
package Pattern_Constructors is
new Ada.Containers.Indefinite_Vectors (Positive, P_Data);
Pattern_Factories : Pattern_Constructors.Vector;
-- A queue for WebSocket with pending messages to be read
package WebSocket_Queue is new Utils.Mailbox_G (Object_Class);
type Queue_Ref is access WebSocket_Queue.Mailbox;
-- A list of all WebSockets in the registry, this list is used to send or
-- broadcast messages.
function Same_WS (Left, Right : Object_Class) return Boolean is
(Left.Get.Id = Right.Get.Id);
-- Equality is based on the unique id
package WebSocket_Map is
new Ada.Containers.Ordered_Maps (UID, Object_Class, "=" => Same_WS);
package WebSocket_Set is new Ada.Containers.Ordered_Sets (UID);
package WebSocket_List is new Ada.Containers.Doubly_Linked_Lists (UID);
-- The socket set with all sockets to wait for data
package FD_Set is new Net.Generic_Sets (Object_Class);
use type FD_Set.Socket_Count;
task type Watcher with Priority => Config.WebSocket_Priority is
end Watcher;
task type Message_Sender with Priority => Config.WebSocket_Priority is
end Message_Sender;
type Message_Sender_Set is array (Positive range <>) of Message_Sender;
type Message_Sender_Set_Ref is access all Message_Sender_Set;
type Watcher_Ref is access all Watcher;
-- This task is in charge of watching the WebSocket for incoming messages.
-- It then places the WebSocket into a job queue to be processed by the
-- reader tasks.
task type Message_Reader with Priority => Config.WebSocket_Priority is
end Message_Reader;
-- Wait for WebSocket message to be ready, read them and call the Received
-- callback. The a message has been read, the WebSocket is added back into
-- the list of watched sockets.
type Message_Reader_Set is array (Positive range <>) of Message_Reader;
type Message_Reader_Set_Ref is access all Message_Reader_Set;
-- Task objects
Message_Queue : Queue_Ref;
Message_Watcher : Watcher_Ref;
Message_Readers : Message_Reader_Set_Ref;
Message_Senders : Message_Sender_Set_Ref;
Shutdown_Signal : Boolean := False with Atomic;
-- Concurrent access to Set above
protected DB is
procedure Initialize;
-- Initialize the socket set by inserting a signaling socket
procedure Finalize;
-- Close signaling socket
function Create_Set return FD_Set.Socket_Set_Type;
-- Returns the set of watched WebSockets
procedure Watch (WebSocket : Object'Class);
-- Add a new Websocket into the set, release the current FD_Set.Wait
-- call if any to ensure this new WebSocket will be watched too.
procedure Remove (WebSocket : Object'Class);
-- Remove WebSocket from the watched list
entry Get_Socket (WebSocket : out Object_Class);
-- Get a WebSocket having some data to be sent
procedure Release_Socket (WebSocket : Object_Class);
-- Release a socket retrieved with Get_Socket above, this socket will be
-- then available again.
entry Not_Empty;
-- Returns if the Set is not empty
procedure Send
(To : Recipient;
Message : String;
Except_Peer : String;
Timeout : Duration := Forever;
Asynchronous : Boolean := False;
Error : access procedure (Socket : Object'Class;
Action : out Action_Kind) := null);
-- Send the given message to all matching WebSockets
procedure Send
(Socket : in out Object'Class;
Message : String;
Is_Binary : Boolean := False;
Timeout : Duration := Forever;
Asynchronous : Boolean := False);
procedure Close
(To : Recipient;
Message : String;
Except_Peer : String;
Timeout : Duration := Forever;
Error : Error_Type := Normal_Closure);
-- Close all matching Webockets
procedure Close
(Socket : in out Object'Class;
Message : String;
Timeout : Duration := Forever;
Error : Error_Type := Normal_Closure);
procedure Register (WebSocket : Object_Class; Success : out Boolean) with
Pre => WebSocket /= No_Object;
-- Register a new WebSocket
procedure Unregister (WebSocket : Object'Class);
-- Unregister a WebSocket
function Is_Registered (Id : UID) return Boolean;
-- Returns True if the WebSocket Id is registered and False otherwise
procedure Signal_Socket;
-- Send a signal to the wait call
procedure Shutdown_Signal;
-- Signal when a shutdown is requested
procedure Receive
(WebSocket : Object'Class;
Data : out Stream_Element_Array;
Last : out Stream_Element_Offset);
-- Get data from WebSocket
private
Sig1, Sig2 : Net.Std.Socket_Type; -- Signaling sockets
Signal : Boolean := False; -- Transient signal, release Not_Emtpy
S_Signal : Boolean := False; -- Shutdown is in progress
New_Pending : Boolean := False; -- New pending socket
Count : Natural := 0; -- Not counting signaling socket
Registered : WebSocket_Map.Map; -- Contains all the WebSocket ref
Sending : WebSocket_Set.Set; -- Socket being handed to Sender task
Pending : WebSocket_List.List; -- Pending messages to be sent
Watched : WebSocket_Set.Set;
-- All WebSockets are registered into this set to check for incoming
-- messages. When a message is ready the WebSocket is placed into the
-- Message_Queue for being handled. When the message has been read
-- and handled the WebSocket is put back into this set.
end DB;
-------------
-- Watcher --
-------------
task body Watcher is
Count : FD_Set.Socket_Count;
WS : Object_Class;
begin
loop
DB.Not_Empty;
exit when Shutdown_Signal;
declare
Set : FD_Set.Socket_Set_Type := DB.Create_Set;
-- Note that the very first one is a signaling socket used to
-- release the wait call. This first entry is not a WebSocket and
-- should be ignored in most code below.
begin
-- Wait indefinitely, this call will be released either by an
-- incoming message in a WebSocket or because the signaling socket
-- has been used due to a new WebSocket registered. In this later
-- case no message will be read, but on the next iteration the new
-- WebSockets will be watched.
FD_Set.Wait (Set, Duration'Last, Count);
-- Queue all WebSocket having some data to read, skip the
-- signaling socket.
declare
-- Skip first entry as it is not a websocket
K : FD_Set.Socket_Count := 2;
begin
while K <= FD_Set.Count (Set) loop
if FD_Set.Is_Read_Ready (Set, K) then
WS := FD_Set.Get_Data (Set, K);
DB.Remove (WS.Get);
Message_Queue.Add (WS);
end if;
K := K + 1;
end loop;
end;
exception
when E : others =>
-- Send a On_Error message to all registered clients
for K in 2 .. FD_Set.Count (Set) loop
WS := FD_Set.Get_Data (Set, K);
WS.Get.State.Errno := Error_Code (Internal_Server_Error);
WS.Get.On_Error
("WebSocket Watcher server error, "
& Exception_Message (E));
end loop;
end;
end loop;
end Watcher;
--------------------
-- Message_Reader --
--------------------
task body Message_Reader is
procedure Do_Receive
(WebSocket : Object'Class;
Data : out Stream_Element_Array;
Last : out Stream_Element_Offset);
procedure Do_Register (WebSocket : Object'Class);
procedure Do_Unregister (WebSocket : Object'Class);
----------------
-- Do_Receive --
----------------
procedure Do_Receive
(WebSocket : Object'Class;
Data : out Stream_Element_Array;
Last : out Stream_Element_Offset) is
begin
DB.Receive (WebSocket, Data, Last);
end Do_Receive;
-----------------
-- Do_Register --
-----------------
procedure Do_Register (WebSocket : Object'Class) is
begin
DB.Watch (WebSocket);
end Do_Register;
-------------------
-- Do_Unregister --
-------------------
procedure Do_Unregister (WebSocket : Object'Class) is
begin
DB.Unregister (WebSocket);
end Do_Unregister;
function Read_Message is new AWS.Net.WebSocket.Read_Message
(Receive => Do_Receive,
On_Success => Do_Register,
On_Error => Do_Unregister);
begin
Handle_Message : loop
declare
WebSocket : Object_Class;
Message : Unbounded_String;
begin
Message_Queue.Get (WebSocket);
-- A WebSocket is null when termination is requested
exit Handle_Message when WebSocket = No_Object;
-- A message can be sent in multiple chunks and/or multiple
-- frames with possibly some control frames in between text or
-- binary ones. This loop handles those cases.
loop
exit when Read_Message (WebSocket.Get, Message);
end loop;
exception
when E : others =>
declare
WS : constant Object_References.Reference_Type :=
WebSocket.Get;
begin
Do_Unregister (WS);
WebSocket_Exception
(WS, Exception_Message (E), Protocol_Error);
WS.Shutdown;
end;
end;
end loop Handle_Message;
end Message_Reader;
--------
-- DB --
--------
protected body DB is
----------
-- Close --
----------
procedure Close
(To : Recipient;
Message : String;
Except_Peer : String;
Timeout : Duration := Forever;
Error : Error_Type := Normal_Closure)
is
procedure Close_To (Position : WebSocket_Map.Cursor);
-------------
-- Close_To --
-------------
procedure Close_To (Position : WebSocket_Map.Cursor) is
WebSocket : constant Object_References.Reference_Type :=
WebSocket_Map.Element (Position).Get;
begin
if (Except_Peer = "" or else WebSocket.Peer_Addr /= Except_Peer)
and then
(not To.URI_Set
or else GNAT.Regexp.Match (WebSocket.URI, To.URI))
and then
(not To.Origin_Set
or else GNAT.Regexp.Match (WebSocket.Origin, To.Origin))
then
DB.Unregister (WebSocket);
WebSocket.State.Errno := Error_Code (Error);
-- If an error occurs, we don't want to fail, shutdown the
-- socket silently.
begin
WebSocket.Set_Timeout (Timeout);
WebSocket.Close (Message, Error);
WebSocket.On_Close (Message);
exception
when others =>
null;
end;
WebSocket.Shutdown;
end if;
end Close_To;
Registered_Before : constant WebSocket_Map.Map := Registered;
begin
case To.Kind is
when K_UID =>
if Registered.Contains (To.WS_Id) then
declare
WebSocket : constant Object_References.Reference_Type :=
Registered (To.WS_Id).Get;
begin
WebSocket.Set_Timeout (Timeout);
WebSocket.Close (Message, Error);
WebSocket.On_Close (Message);
exception
when others =>
null;
end;
else
-- This WebSocket is not registered anymore
raise Socket_Error
with "WebSocket " & Utils.Image (Natural (To.WS_Id))
& " is not registered";
end if;
when K_URI =>
Registered_Before.Iterate (Close_To'Access);
end case;
end Close;
procedure Close
(Socket : in out Object'Class;
Message : String;
Timeout : Duration := Forever;
Error : Error_Type := Normal_Closure)
is
W : Object_Class;
begin
-- Look for WebSocket into the registered set, unregisted it if
-- present.
if Registered.Contains (Socket.Id) then
W := Registered (Socket.Id);
Unregister (W.Get);
end if;
Socket.State.Errno := Error_Code (Error);
Socket.Set_Timeout (Timeout);
Socket.Close (Message, Error);
Socket.On_Close (Message);
Socket.Shutdown;
end Close;
----------------
-- Create_Set --
----------------
function Create_Set return FD_Set.Socket_Set_Type is
begin
return Result : FD_Set.Socket_Set_Type do
-- Add the signaling socket
FD_Set.Add (Result, Sig1, No_Object, FD_Set.Input);
-- Add watched sockets
for Id of Watched loop
declare
WS : constant Object_Class := Registered (Id);
begin
FD_Set.Add (Result, WS.Get.Socket.all, WS, FD_Set.Input);
end;
end loop;
end return;
end Create_Set;
--------------
-- Finalize --
--------------
procedure Finalize is
procedure On_Close (Position : WebSocket_Map.Cursor);
--------------
-- On_Close --
--------------
procedure On_Close (Position : WebSocket_Map.Cursor) is
WebSocket : constant Object_References.Reference_Type :=
WebSocket_Map.Element (Position).Get;
begin
WebSocket.State.Errno := Error_Code (Going_Away);
-- We do not want to block if the peer is not responding, just
-- allow 10 seconds for the close message to be accepted.
-- In any case, we do not want to raise an exception. If an
-- error occurs just close the socket silently.
begin
WebSocket.Set_Timeout (10.0);
WebSocket.On_Close ("AWS server going down");
exception
when others =>
null;
end;
WebSocket.Shutdown;
end On_Close;
begin
Net.Std.Shutdown (Sig1);
Net.Std.Shutdown (Sig2);
-- Finally send a On_Close message to all registered WebSocket
Registered.Iterate (On_Close'Access);
Registered.Clear;
end Finalize;
----------------
-- Get_Socket --
----------------
entry Get_Socket (WebSocket : out Object_Class)
when New_Pending or else S_Signal is
begin
WebSocket := No_Object;
-- Shutdown requested, just return now
if S_Signal then
return;
end if;
-- No pending message on the queue, this can happen because
-- New_Pending is set when giving back a WebSocket into the
-- registry. See Release_Socket.
if Pending.Length = 0 then
New_Pending := False;
requeue Get_Socket;
end if;
-- Look for a socket not yet being handled
declare
use type WebSocket_List.Cursor;
Pos : WebSocket_List.Cursor := Pending.First;
Id : UID;
WS : Object_Class;
begin
while Pos /= WebSocket_List.No_Element loop
Id := Pending (Pos);
-- Check if this socket is not yet being used by a sender task
if not Sending.Contains (Id) then
WS := Registered (Id);
-- Check that some messages are to be sent. This is needed
-- as some messages could have been dropped if the list was
-- too long to avoid congestion.
if WS.Get.Messages.Length > 0 then
Pending.Delete (Pos);
WebSocket := WS;
Sending.Insert (Id);
return;
end if;
end if;
Pos := WebSocket_List.Next (Pos);
end loop;
-- Finally no more socket found to be handled, wait for new to
-- arrive.
New_Pending := False;
requeue Get_Socket;
end;
end Get_Socket;
----------------
-- Initialize --
----------------
procedure Initialize is
begin
-- Create a signaling socket that will be used to exit from the
-- infinite wait when a new WebSocket arrives.
Net.Std.Socket_Pair (Sig1, Sig2);
end Initialize;
-------------------
-- Is_Registered --
-------------------
function Is_Registered (Id : UID) return Boolean is
begin
return Registered.Contains (Id);
end Is_Registered;
---------------
-- Not_Empty --
---------------
entry Not_Empty when Count > 0 or else Signal or else S_Signal is
begin
-- If shutdown is in process, return now
if S_Signal then
return;
end if;
-- It was a signal, consume the one by sent
if Signal then
Signal := False;
declare
Data : Stream_Element_Array (1 .. 1);
Last : Stream_Element_Offset;
begin
AWS.Net.Std.Receive (Sig1, Data, Last);
end;
end if;
end Not_Empty;
-------------
-- Receive --
-------------
procedure Receive
(WebSocket : Object'Class;
Data : out Stream_Element_Array;
Last : out Stream_Element_Offset) is
begin
WebSocket.Receive (Data, Last);
end Receive;
--------------
-- Register --
--------------
procedure Register (WebSocket : Object_Class; Success : out Boolean) is
begin
-- Check if maximum number of WebSocket has been reached
if Natural (Registered.Length) = Config.Max_WebSocket then
-- Let's try to close a WebSocket for which the activity has
-- timed out.
declare
use type Calendar.Time;
Timeout : constant Calendar.Time :=
Calendar.Clock - Config.WebSocket_Timeout;
W : Object_Class;
begin
for WS of Registered loop
if WS.Get.State.Last_Activity < Timeout then
W := WS;
exit;
end if;
end loop;
-- If no WebSocket can be closed
if W = No_Object then
Success := False;
return;
else
Close
(Socket => W.Get,
Message => "activity timeout reached",
Timeout => 1.0,
Error => Abnormal_Closure);
end if;
end;
end if;
Registered.Insert (WebSocket.Get.Id, WebSocket);
Success := True;
end Register;
--------------------
-- Release_Socket --
--------------------
procedure Release_Socket (WebSocket : Object_Class) is
begin
Sending.Exclude (WebSocket.Get.Id);
New_Pending := True;
end Release_Socket;
------------
-- Remove --
------------
procedure Remove (WebSocket : Object'Class) is
CID : WebSocket_Set.Cursor := Watched.Find (WebSocket.Id);
begin
if WebSocket_Set.Has_Element (CID) then
Watched.Delete (CID);
Count := Count - 1;
end if;
end Remove;
----------
-- Send --
----------
procedure Send
(To : Recipient;
Message : String;
Except_Peer : String;
Timeout : Duration := Forever;
Asynchronous : Boolean := False;
Error : access procedure (Socket : Object'Class;
Action : out Action_Kind) := null)
is
type Object_Set is array (Positive range <>) of Object_Class;
procedure Initialize_Recipients (Position : WebSocket_Map.Cursor);
-- Count recipients and initialize the message's raw data
procedure Send_To_Recipients (Recipients : Object_Set);
-- Send message to all recipients
Recipients : Object_Set (1 .. Natural (Registered.Length));
Last : Natural := 0;
---------------------------
-- Initialize_Recipients --
---------------------------
procedure Initialize_Recipients (Position : WebSocket_Map.Cursor) is
WebSocket : constant Object_Class :=
WebSocket_Map.Element (Position);
WS : constant Object_References.Reference_Type :=
WebSocket.Get;
begin
if (Except_Peer = "" or else WS.Peer_Addr /= Except_Peer)
and then
(not To.URI_Set
or else GNAT.Regexp.Match (WS.URI, To.URI))
and then
(not To.Origin_Set
or else GNAT.Regexp.Match (WS.Origin, To.Origin))
then
-- Send all data to a memory socket. This is a special
-- circuitry where all sent data are actually stored into
-- a buffer. This is necessary to be able to get raw data
-- depending on the protocol.
--
-- ??? for supporting a large set of WebSocket it would be
-- good to share the memory buffer. There is actually one
-- for each WebSocket format.
WS.Mem_Sock := new Memory.Socket_Type;
WS.In_Mem := True;
WS.Send (Message);
WS.In_Mem := False;
-- Not that it is not possible to honor the synchronous
-- sending if the socket is already being handled by a
-- send task (Asynchronously).
if Asynchronous or else Sending.Contains (WS.Id) then
declare
M : constant Message_Data := (WS.Mem_Sock, Timeout);
begin
WS.Messages.Append (M);
WS.Mem_Sock := null;
Pending.Append (WS.Id);
New_Pending := True;
end;
else
Last := Last + 1;
WS.Set_Timeout (Timeout);
Recipients (Last) := WebSocket;
end if;
end if;
end Initialize_Recipients;
------------------------
-- Send_To_Recipients --
------------------------
procedure Send_To_Recipients (Recipients : Object_Set) is
Wait_Events : constant Wait_Event_Set :=
(Input => False, Output => True);
Set : Poll_Events.Set (Recipients'Length);
Socks : Object_Set := Recipients;
Sock_Index : Positive;
Count : Natural;
Pending : Stream_Element_Count;
begin
-- Register the sockets to be handled
for S of Socks loop
Set.Add (S.Get.Get_FD, Wait_Events);
end loop;
-- Send actual data to the WebSocket depending on their status
Send_Message : loop
Set.Wait (Timeout, Count);
-- Timeout reached, some sockets are not responding
if Count = 0 then
for K in 1 .. Set.Length loop
declare
W : constant Object_References.Reference_Type :=
Socks (K).Get;
A : Action_Kind := None;
begin
if Error = null then
DB.Unregister (W);
else
Error (W, A);
case A is
when Close =>
DB.Unregister (W);
when None =>
null;
end case;
end if;
end;
end loop;
exit Send_Message;
end if;
Sock_Index := 1;
for K in 1 .. Count loop
Set.Next (Sock_Index);
declare
WS : constant Object_References.Reference_Type :=
Socks (Sock_Index).Get;
Chunk_Size : Stream_Element_Offset := WS.Output_Space;
begin
if Chunk_Size = -1 then
Chunk_Size := 100 * 1_024;
end if;
Pending := WS.Mem_Sock.Pending;
Chunk_Size := Stream_Element_Offset'Min
(Chunk_Size, Pending);
Read_Send : declare
-- ??? Might blow up if Chunk_Size > 2Mb
Data : Stream_Element_Array (1 .. Chunk_Size);
Last : Stream_Element_Offset;
begin
-- ??? Useless copy of the data in memory. Would be
-- nice to remove this.
WS.Mem_Sock.Receive (Data, Last);
pragma Assert (Last = Data'Last);
if Last /= 0 then
WS.Set_Timeout (Timeout);
WS.Send (Data, Last);
end if;
Pending := Pending - Last;
exception
when E : others =>
Unregister (WS);
WebSocket_Exception
(WS, Exception_Message (E), Protocol_Error);
WS.Close (Exception_Message (E), Going_Away);
-- No more data to send from this socket
Pending := 0;
Socks (Sock_Index) := No_Object;
end Read_Send;
end;
if Pending = 0 then
-- No more data for this socket, first free memory
if Socks (Sock_Index) /= No_Object then
Free (Socks (Sock_Index).Get.Mem_Sock);
end if;
-- Then the Set.Remove (on the socket set) move the last
-- socket in the set to the location of the removed
-- one. Do the same for the local data to keep data
-- consistency.
--
-- Note that in this case we do not want to increment the
-- socket index. The new loop will check the socket at
-- the same position which is now the previous last in
-- the set.
if Sock_Index /= Set.Length then
Socks (Sock_Index) := Socks (Set.Length);
end if;
Set.Remove (Sock_Index);
else
-- In this case, and only in this case we move to next
-- socket position for next iteration.
Sock_Index := Sock_Index + 1;
end if;
end loop;
exit Send_Message when Set.Length = 0;
end loop Send_Message;
end Send_To_Recipients;
begin
case To.Kind is
when K_UID =>
if Registered.Contains (To.WS_Id) then
declare
WebSocket : constant Object_References.Reference_Type :=
Registered (To.WS_Id).Get;
begin
WebSocket.Set_Timeout (Timeout);
WebSocket.Send (Message);
exception
when E : others =>
Unregister (WebSocket);
WebSocket_Exception
(WebSocket, Exception_Message (E), Protocol_Error);
WebSocket.Close (Exception_Message (E), Going_Away);
end;
else
-- This WebSocket is not registered anymore
raise Socket_Error
with "WebSocket " & Utils.Image (Natural (To.WS_Id))
& " is not registered";
end if;
when K_URI =>
Registered.Iterate (Initialize_Recipients'Access);
if Last > 0 then
Send_To_Recipients (Recipients (1 .. Last));
end if;
end case;
end Send;
procedure Send
(Socket : in out Object'Class;
Message : String;
Is_Binary : Boolean := False;
Timeout : Duration := Forever;
Asynchronous : Boolean := False) is
begin
if Asynchronous then
Socket.In_Mem := True;
Socket.Send (Message, Is_Binary);
Socket.In_Mem := False;
declare
M : constant Message_Data := (Socket.Mem_Sock, Timeout);
begin
Socket.Messages.Append (M);
Socket.Mem_Sock := null;
Pending.Append (Socket.Id);
New_Pending := True;
end;
else
Socket.Set_Timeout (Timeout);
Socket.Send (Message, Is_Binary);
end if;
end Send;
---------------------
-- Shutdown_Signal --
---------------------
procedure Shutdown_Signal is
begin
S_Signal := True;
Signal_Socket;
end Shutdown_Signal;
-------------------
-- Signal_Socket --
-------------------
procedure Signal_Socket is
begin
-- If a signal is pending no need to signal again the socket
if not Signal then
Net.Send (Sig2, Stream_Element_Array'(1 => 0));
-- Also activate the signal to release Not_Empty for proper
-- termination when there is no remaining socket.
Signal := True;
end if;
end Signal_Socket;
----------------
-- Unregister --
----------------
procedure Unregister (WebSocket : Object'Class) is
Id : constant UID := WebSocket.Id;
begin
Registered.Exclude (Id);
Sending.Exclude (Id);
Remove (WebSocket);
Signal_Socket;
end Unregister;
-----------
-- Watch --
-----------
procedure Watch (WebSocket : Object'Class) is
begin
if Is_Registered (WebSocket.Id)
and then not Watched.Contains (WebSocket.Id)
then
Watched.Insert (WebSocket.Id);
Count := Count + 1;
Signal_Socket;
end if;
exception
when others =>
Unregister (WebSocket);
raise;
end Watch;
end DB;
-----------
-- Close --
-----------
procedure Close
(To : Recipient;
Message : String;
Except_Peer : String := "";
Timeout : Duration := Forever;
Error : Error_Type := Normal_Closure) is
begin
DB.Close (To, Message, Except_Peer, Timeout, Error);
exception
when others =>
-- Should never fails even if the WebSocket is closed by peer
null;
end Close;
procedure Close
(Socket : in out Object'Class;
Message : String;
Timeout : Duration := Forever;
Error : Error_Type := Normal_Closure) is
begin
DB.Close (Socket, Message, Timeout, Error);
exception
when others =>
-- Should never fails even if the WebSocket is closed by peer
null;
end Close;
-----------------
-- Constructor --
-----------------
function Constructor (URI : String) return Registry.Factory is
Position : constant Constructors.Cursor := Factories.Find (URI);
begin
if Constructors.Has_Element (Position) then
return Constructors.Element (Position);
else
for Data of Pattern_Factories loop
declare
Count : constant Natural := Paren_Count (Data.Pattern);
Matches : Match_Array (0 .. Count);
begin
Match (Data.Pattern, URI, Matches);
if Matches (0) /= No_Match then
return Data.Factory;
end if;
end;
end loop;
end if;
return Create'Access;
end Constructor;
------------
-- Create --
------------
function Create (URI : String; Origin : String := "") return Recipient is
Result : Recipient (K_URI);
begin
if URI /= "" then
Result.URI_Set := True;
Result.URI := GNAT.Regexp.Compile (URI);
end if;
if Origin /= "" then
Result.Origin_Set := True;
Result.Origin := GNAT.Regexp.Compile (Origin);
end if;
return Result;
end Create;
function Create (Id : UID) return Recipient is
begin
return Result : Recipient (K_UID) do
Result.WS_Id := Id;
end return;
end Create;
-------------------
-- Is_Registered --
-------------------
function Is_Registered (Id : UID) return Boolean is
begin
return DB.Is_Registered (Id);
end Is_Registered;
--------------------
-- Message_Sender --
--------------------
task body Message_Sender is
WSR : Object_Class;
WS : Object_References.Element_Access;
procedure Send (Message : Message_Data);
----------
-- Send --
----------
procedure Send (Message : Message_Data) is
Chunk_Size : Stream_Element_Offset := WS.Output_Space;
Pending : Stream_Element_Count;
begin
if Chunk_Size = -1 then
Chunk_Size := 100 * 1_024;
end if;
loop
Pending := Message.Mem_Sock.Pending;
exit when Pending = 0;
Chunk_Size := Stream_Element_Offset'Min (Chunk_Size, Pending);
Read_Send : declare
Data : Stream_Element_Array (1 .. Chunk_Size);
Last : Stream_Element_Offset;
begin
Message.Mem_Sock.Receive (Data, Last);
pragma Assert (Last = Data'Last);
WS.Send (Data, Last);
Pending := Pending - Chunk_Size;
exception
when E : others =>
DB.Unregister (WS.all);
WebSocket_Exception
(WS.all, Exception_Message (E), Protocol_Error);
-- No more data to send from this socket
Pending := 0;
end Read_Send;
end loop;
end Send;
begin
loop
DB.Get_Socket (WSR);
WS := WSR.Get.Element;
exit when Shutdown_Signal;
-- This WebSocket has a message to be sent
-- First let's remove too old messages
while Positive (WS.Messages.Length) >
Config.WebSocket_Send_Message_Queue_Size
loop
WS.Messages.Delete_First;
end loop;
-- Then send the oldest message on the list
declare
Message : constant Message_Data := WS.Messages.First_Element;
begin
Send (Message);
WS.Messages.Delete_First;
DB.Release_Socket (WSR);
end;
end loop;
end Message_Sender;
--------------
-- Register --
--------------
procedure Register (URI : String; Factory : Registry.Factory) is
begin
Factories.Insert (URI, Factory);
end Register;
function Register (WebSocket : Object'Class) return Object_Class is
WS : Object_Class;
Success : Boolean;
begin
WS.Set (WebSocket);
DB.Register (WS, Success);
if not Success then
WS := No_Object;
end if;
return WS;
end Register;
----------------------
-- Register_Pattern --
----------------------
procedure Register_Pattern
(Pattern : String;
Factory : Registry.Factory)
is
M : constant Regpat.Pattern_Matcher :=
Regpat.Compile (Pattern, GNAT.Regpat.Case_Insensitive);
begin
Pattern_Factories.Append (P_Data'(M.Size, M, Factory));
end Register_Pattern;
----------
-- Send --
----------
procedure Send
(To : Recipient;
Message : Unbounded_String;
Except_Peer : String := "";
Timeout : Duration := Forever;
Asynchronous : Boolean := False;
Error : access procedure (Socket : Object'Class;
Action : out Action_Kind) := null)
is
use Ada.Strings.Unbounded.Aux;
S : Big_String_Access;
L : Natural;
begin
Get_String (Message, S, L);
DB.Send (To, S (1 .. L), Except_Peer, Timeout, Asynchronous, Error);
exception
when others =>
-- Should never fails even if the WebSocket is closed by peer
null;
end Send;
procedure Send
(To : Recipient;
Message : String;
Except_Peer : String := "";
Timeout : Duration := Forever;
Asynchronous : Boolean := False;
Error : access procedure (Socket : Object'Class;
Action : out Action_Kind) := null) is
begin
DB.Send (To, Message, Except_Peer, Timeout, Asynchronous, Error);
end Send;
procedure Send
(To : Recipient;
Message : Unbounded_String;
Request : AWS.Status.Data;
Timeout : Duration := Forever;
Asynchronous : Boolean := False;
Error : access procedure (Socket : Object'Class;
Action : out Action_Kind) := null)
is
use Ada.Strings.Unbounded.Aux;
S : Big_String_Access;
L : Natural;
begin
Get_String (Message, S, L);
Send (To, S (1 .. L), Request, Timeout, Asynchronous, Error);
end Send;
procedure Send
(To : Recipient;
Message : String;
Request : AWS.Status.Data;
Timeout : Duration := Forever;
Asynchronous : Boolean := False;
Error : access procedure (Socket : Object'Class;
Action : out Action_Kind) := null) is
begin
Send
(To, Message,
Except_Peer => AWS.Status.Socket (Request).Peer_Addr,
Timeout => Timeout,
Asynchronous => Asynchronous,
Error => Error);
end Send;
procedure Send
(Socket : in out Object'Class;
Message : String;
Is_Binary : Boolean := False;
Timeout : Duration := Forever;
Asynchronous : Boolean := False) is
begin
DB.Send (Socket, Message, Is_Binary, Timeout, Asynchronous);
end Send;
procedure Send
(Socket : in out Object'Class;
Message : Unbounded_String;
Is_Binary : Boolean := False;
Timeout : Duration := Forever;
Asynchronous : Boolean := False)
is
use Ada.Strings.Unbounded.Aux;
S : Big_String_Access;
L : Natural;
begin
Get_String (Message, S, L);
DB.Send (Socket, S (1 .. L), Is_Binary, Timeout, Asynchronous);
end Send;
procedure Send
(Socket : in out Object'Class;
Message : Stream_Element_Array;
Is_Binary : Boolean := True;
Timeout : Duration := Forever;
Asynchronous : Boolean := False)
is
A : String (1 .. Message'Length) with Import, Address => Message'Address;
pragma Compile_Time_Error
(Character'Size /= Stream_Element'Size,
"A character size is not the size of a byte");
begin
Send (Socket, A, Is_Binary, Timeout, Asynchronous);
end Send;
--------------
-- Shutdown --
--------------
procedure Shutdown is
procedure Unchecked_Free is new
Unchecked_Deallocation (Watcher, Watcher_Ref);
procedure Unchecked_Free is new
Unchecked_Deallocation (Message_Reader_Set, Message_Reader_Set_Ref);
procedure Unchecked_Free is new
Unchecked_Deallocation (Message_Sender_Set, Message_Sender_Set_Ref);
procedure Unchecked_Free is new
Unchecked_Deallocation (WebSocket_Queue.Mailbox, Queue_Ref);
begin
-- Check if a shutdown if not already in progress or if the servers have
-- not been initialized.
if Shutdown_Signal
or else (Message_Watcher = null and then Message_Readers = null)
then
return;
end if;
-- First shutdown the watcher
Shutdown_Signal := True;
DB.Shutdown_Signal;
-- Wait for proper termination to be able to free the task object
while not Message_Watcher'Terminated loop
delay 0.5;
end loop;
-- Now shutdown all the message readers
for K in Message_Readers'Range loop
Message_Queue.Add (No_Object);
end loop;
for K in Message_Readers'Range loop
while not Message_Readers (K)'Terminated loop
delay 0.5;
end loop;
end loop;
for K in Message_Senders'Range loop
while not Message_Senders (K)'Terminated loop
delay 0.5;
end loop;
end loop;
-- Now we can deallocate the task objects
Unchecked_Free (Message_Readers);
Unchecked_Free (Message_Senders);
Unchecked_Free (Message_Watcher);
Unchecked_Free (Message_Queue);
DB.Finalize;
end Shutdown;
-----------
-- Start --
-----------
procedure Start is
begin
DB.Initialize;
Message_Queue :=
new WebSocket_Queue.Mailbox (Config.WebSocket_Message_Queue_Size);
Message_Watcher := new Watcher;
Message_Readers :=
new Message_Reader_Set (1 .. Config.Max_WebSocket_Handler);
Message_Senders :=
new Message_Sender_Set (1 .. Config.Max_WebSocket_Handler);
end Start;
-----------
-- Watch --
-----------
procedure Watch (WebSocket : in out Object_Class) is
WS : constant Object_References.Reference_Type := WebSocket.Get;
begin
-- Send a Connection_Open message
WS.State.Kind := Connection_Open;
WS.On_Open ("AWS WebSocket connection open");
DB.Watch (WS);
end Watch;
end AWS.Net.WebSocket.Registry;
|