1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2006-2017, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under terms of the GNU General Public License as published by the --
-- Free Software Foundation; either version 3, or (at your option) any --
-- later version. This library is distributed in the hope that it will be --
-- useful, but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are --
-- granted additional permissions described in the GCC Runtime Library --
-- Exception, version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
------------------------------------------------------------------------------
pragma Ada_2012;
with Ada.Real_Time;
with Interfaces.C;
package body AWS.Net.Poll_Events is
procedure Set_Mode (Item : out Pollfd; Mode : Wait_Event_Set);
procedure Set_Event
(Item : out Pollfd; Event : Wait_Event_Type; Value : Boolean);
type Poll_Access is access all Set;
procedure Check_Range (FD_Set : Set; Index : Positive) with Inline;
procedure Wait
(Fds : in out Set; Timeout : Timeout_Type; Result : out Integer);
---------
-- Add --
---------
overriding procedure Add
(FD_Set : in out Set;
FD : FD_Type;
Event : Wait_Event_Set) is
begin
if FD_Set.Size = FD_Set.Length then
raise Constraint_Error;
end if;
if FD < 0 then
raise Socket_Error with
"Wrong socket descriptor " & FD_Type'Image (FD);
end if;
if FD_Type (FD_Set.Max_FD) < FD then
FD_Set.Max_FD := OS_Lib.FD_Type (FD);
end if;
FD_Set.Length := FD_Set.Length + 1;
FD_Set.Fds (FD_Set.Length).FD := AWS.OS_Lib.FD_Type (FD);
Set_Mode (FD_Set.Fds (FD_Set.Length), Event);
end Add;
-----------------
-- Check_Range --
-----------------
procedure Check_Range (FD_Set : Set; Index : Positive) is
begin
if Index > FD_Set.Length then
raise Constraint_Error;
end if;
end Check_Range;
----------
-- Copy --
----------
overriding function Copy
(FD_Set : not null access Set; Size : Natural) return FD_Set_Access
is
use type OS_Lib.FD_Type;
Result : Poll_Access;
begin
Result := new Set (Size);
if FD_Set.Size < Size then
-- New size is bigger
Result.Length := FD_Set.Length;
Result.Fds (1 .. FD_Set.Size) := FD_Set.Fds;
else
-- New size is smaller
Result.Length := Size;
Result.Fds := FD_Set.Fds (1 .. Size);
end if;
for J in 1 .. Result.Length loop
if Result.Max_FD < Result.Fds (J).FD then
Result.Max_FD := Result.Fds (J).FD;
end if;
end loop;
return Result.all'Access;
end Copy;
------------
-- Length --
------------
overriding function Length (FD_Set : Set) return Natural is
begin
return FD_Set.Length;
end Length;
----------
-- Next --
----------
overriding procedure Next (FD_Set : Set; Index : in out Positive) is
use type OS_Lib.Events_Type;
begin
loop
exit when Index > FD_Set.Length
or else FD_Set.Fds (Index).REvents /= 0;
Index := Index + 1;
end loop;
end Next;
------------
-- Remove --
------------
overriding procedure Remove (FD_Set : in out Set; Index : Positive) is
begin
Check_Range (FD_Set, Index);
if Index < FD_Set.Length then
FD_Set.Fds (Index) := FD_Set.Fds (FD_Set.Length);
elsif Index > FD_Set.Length then
raise Constraint_Error;
end if;
FD_Set.Length := FD_Set.Length - 1;
end Remove;
-------------
-- Replace --
-------------
overriding procedure Replace
(FD_Set : in out Set;
Index : Positive;
FD : FD_Type) is
begin
Check_Range (FD_Set, Index);
FD_Set.Fds (Index).FD := OS_Lib.FD_Type (FD);
if FD_Type (FD_Set.Max_FD) < FD then
FD_Set.Max_FD := OS_Lib.FD_Type (FD);
end if;
end Replace;
---------------
-- Set_Event --
---------------
overriding procedure Set_Event
(FD_Set : in out Set;
Index : Positive;
Event : Wait_Event_Type;
Value : Boolean) is
begin
Check_Range (FD_Set, Index);
Set_Event (FD_Set.Fds (Index), Event, Value);
end Set_Event;
procedure Set_Event
(Item : out Pollfd; Event : Wait_Event_Type; Value : Boolean)
is
use OS_Lib;
To_C : constant array (Wait_Event_Type) of Events_Type :=
(Input => POLLIN or POLLPRI, Output => POLLOUT);
begin
if Value then
Item.Events := Item.Events or To_C (Event);
else
Item.Events := Item.Events and not To_C (Event);
end if;
end Set_Event;
--------------
-- Set_Mode --
--------------
overriding procedure Set_Mode
(FD_Set : in out Set; Index : Positive; Mode : Wait_Event_Set) is
begin
Check_Range (FD_Set, Index);
Set_Mode (FD_Set.Fds (Index), Mode);
end Set_Mode;
procedure Set_Mode (Item : out Pollfd; Mode : Wait_Event_Set) is
begin
for J in Mode'Range loop
Set_Event (Item, J, Mode (J));
end loop;
end Set_Mode;
------------
-- Status --
------------
overriding function Status
(FD_Set : Set; Index : Positive) return Event_Set
is
use AWS.OS_Lib;
begin
Check_Range (FD_Set, Index);
return
(Input => (FD_Set.Fds (Index).REvents and (POLLIN or POLLPRI))
/= 0,
Error => (FD_Set.Fds (Index).REvents
and (POLLERR or POLLHUP or POLLNVAL)) /= 0,
Output => (FD_Set.Fds (Index).REvents and POLLOUT) /= 0);
end Status;
----------
-- Wait --
----------
procedure Wait
(Fds : in out Set; Timeout : Timeout_Type; Result : out Integer)
is separate;
overriding procedure Wait
(FD_Set : in out Set; Timeout : Duration; Count : out Natural)
is
use Ada.Real_Time;
use type Timeout_Type;
Result : Integer;
Poll_Timeout : Duration := Timeout;
C_Timeout : Timeout_Type;
Errno : Integer;
Stamp : constant Time := Clock;
begin
if FD_Set.Length = 0 then
Count := 0;
return;
end if;
loop
if Poll_Timeout >= Duration (Timeout_Type'Last - 8) / 1_000 then
-- Minus 8 is to workaround Linux kernel 2.6.24 bug with close to
-- Integer'Last poll timeout values.
-- syscall (SYS_poll, &ufds, 1, 2147483644); // is waiting
-- syscall (SYS_poll, &ufds, 1, 2147483645); // is not waiting
-- Timeout values close to maximum could be not safe because of
-- possible time conversion boundary errors in the kernel.
-- Use unlimited timeout instead of maximum 24 days timeout for
-- safety reasons.
C_Timeout := -1;
else
C_Timeout := Timeout_Type (Poll_Timeout * 1_000);
end if;
Wait (FD_Set, C_Timeout, Result);
exit when Result >= 0;
Errno := AWS.OS_Lib.Socket_Errno;
-- In case of EINTR error we have to continue waiting for network
-- events.
if Errno = OS_Lib.EINTR then
if C_Timeout >= 0 then
Poll_Timeout := Timeout - To_Duration (Clock - Stamp);
if Poll_Timeout < 0.0 then
Poll_Timeout := 0.0;
end if;
end if;
else
-- Call Raise_Socket_Error with dummy created socket and
-- error code, to raise exception and log error message.
Raise_Socket_Error
(AWS.Net.Socket (False),
"Poll (Size => " & Utils.Image (FD_Set.Length)
& ") error code" & Integer'Image (Errno));
end if;
end loop;
Count := Result;
end Wait;
end AWS.Net.Poll_Events;
|