1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264 | -----------------------------------------------------------------------
-- awa-tags-beans -- Beans for the tags module
-- Copyright (C) 2013, 2018 Stephane Carrez
-- Written by Stephane Carrez (Stephane.Carrez@gmail.com)
--
-- Licensed under the Apache License, Version 2.0 (the "License");
-- you may not use this file except in compliance with the License.
-- You may obtain a copy of the License at
--
-- http://www.apache.org/licenses/LICENSE-2.0
--
-- Unless required by applicable law or agreed to in writing, software
-- distributed under the License is distributed on an "AS IS" BASIS,
-- WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
-- See the License for the specific language governing permissions and
-- limitations under the License.
-----------------------------------------------------------------------
with Ada.Strings.Unbounded;
with Ada.Containers.Hashed_Maps;
with Ada.Containers.Ordered_Sets;
with Ada.Finalization;
with Util.Beans.Basic;
with Util.Beans.Objects.Lists;
with Util.Beans.Lists.Strings;
with Util.Strings.Vectors;
with ADO;
with ADO.Utils;
with ADO.Schemas;
with ADO.Sessions;
with AWA.Tags.Models;
with AWA.Tags.Modules;
-- == Ada Beans ==
-- Several bean types are provided to represent and manage a list of tags.
-- The tag module registers the bean constructors when it is initialized.
-- To use them, one must declare a bean definition in the application XML configuration.
--
-- === Tag_List_Bean ===
-- The `Tag_List_Bean` holds a list of tags and provides operations used by the
-- `awa:tagList` component to add or remove tags within a `h:form` component.
-- A bean can be declared and configured as follows in the XML application configuration file:
--
-- <managed-bean>
-- <managed-bean-name>questionTags</managed-bean-name>
-- <managed-bean-class>AWA.Tags.Beans.Tag_List_Bean</managed-bean-class>
-- <managed-bean-scope>request</managed-bean-scope>
-- <managed-property>
-- <property-name>entity_type</property-name>
-- <property-class>String</property-class>
-- <value>awa_question</value>
-- </managed-property>
-- <managed-property>
-- <property-name>permission</property-name>
-- <property-class>String</property-class>
-- <value>question-edit</value>
-- </managed-property>
-- </managed-bean>
--
-- The `entity_type` property defines the name of the database table to which the tags
-- are assigned. The `permission` property defines the permission name that must be used
-- to verify that the user has the permission do add or remove the tag. Such permission is
-- verified only when the `awa:tagList` component is used within a form.
--
-- === Tag_Search_Bean ===
-- The `Tag_Search_Bean` is dedicated to searching for tags that start with a given
-- pattern. The auto complete feature of the `awa:tagList` component can use this
-- bean type to look in the database for tags matching a start pattern. The declaration of the
-- bean should define the database table to search for tags associated with a given database
-- table. This is done in the XML configuration with the `entity_type` property.
--
-- <managed-bean>
-- <managed-bean-name>questionTagSearch</managed-bean-name>
-- <managed-bean-class>AWA.Tags.Beans.Tag_Search_Bean</managed-bean-class>
-- <managed-bean-scope>request</managed-bean-scope>
-- <managed-property>
-- <property-name>entity_type</property-name>
-- <property-class>String</property-class>
-- <value>awa_question</value>
-- </managed-property>
-- </managed-bean>
--
-- === Tag_Info_List_Bean ===
-- The <tt>Tag_Info_List_Bean</tt> holds a collection of tags with their weight. It is used
-- by the <tt>awa:tagCloud</tt> component.
--
-- <managed-bean>
-- <managed-bean-name>questionTagList</managed-bean-name>
-- <managed-bean-class>AWA.Tags.Beans.Tag_Info_List_Bean</managed-bean-class>
-- <managed-bean-scope>request</managed-bean-scope>
-- <managed-property>
-- <property-name>entity_type</property-name>
-- <property-class>String</property-class>
-- <value>awa_question</value>
-- </managed-property>
-- </managed-bean>
--
-- @include-bean tag-queries.xml
package AWA.Tags.Beans is
-- Compare two tags on their count and name.
function "<" (Left, Right : in AWA.Tags.Models.Tag_Info) return Boolean;
package Tag_Ordered_Sets is
new Ada.Containers.Ordered_Sets (Element_Type => AWA.Tags.Models.Tag_Info,
"=" => AWA.Tags.Models."=");
type Tag_List_Bean is
new Util.Beans.Objects.Lists.List_Bean and Util.Beans.Basic.Bean with private;
type Tag_List_Bean_Access is access all Tag_List_Bean'Class;
-- Set the value identified by the name.
-- If the name cannot be found, the method should raise the No_Value
-- exception.
overriding
procedure Set_Value (From : in out Tag_List_Bean;
Name : in String;
Value : in Util.Beans.Objects.Object);
-- Set the entity type (database table) onto which the tags are associated.
procedure Set_Entity_Type (Into : in out Tag_List_Bean;
Table : in ADO.Schemas.Class_Mapping_Access);
-- Set the permission to check before removing or adding a tag on the entity.
procedure Set_Permission (Into : in out Tag_List_Bean;
Permission : in String);
-- Load the tags associated with the given database identifier.
procedure Load_Tags (Into : in out Tag_List_Bean;
Session : in ADO.Sessions.Session;
For_Entity_Id : in ADO.Identifier);
-- Set the list of tags to add.
procedure Set_Added (Into : in out Tag_List_Bean;
Tags : in Util.Strings.Vectors.Vector);
-- Set the list of tags to remove.
procedure Set_Deleted (Into : in out Tag_List_Bean;
Tags : in Util.Strings.Vectors.Vector);
-- Update the tags associated with the tag entity represented by <tt>For_Entity_Id</tt>.
-- The list of tags defined by <tt>Set_Deleted</tt> are removed first and the list of
-- tags defined by <tt>Set_Added</tt> are associated with the database entity.
procedure Update_Tags (From : in Tag_List_Bean;
For_Entity_Id : in ADO.Identifier);
-- Create the tag list bean instance.
function Create_Tag_List_Bean (Module : in AWA.Tags.Modules.Tag_Module_Access)
return Util.Beans.Basic.Readonly_Bean_Access;
type Tag_Search_Bean is
new Util.Beans.Objects.Lists.List_Bean and Util.Beans.Basic.Bean with private;
type Tag_Search_Bean_Access is access all Tag_Search_Bean'Class;
-- Set the value identified by the name.
-- If the name cannot be found, the method should raise the No_Value
-- exception.
overriding
procedure Set_Value (From : in out Tag_Search_Bean;
Name : in String;
Value : in Util.Beans.Objects.Object);
-- Search the tags that match the search string.
procedure Search_Tags (Into : in out Tag_Search_Bean;
Session : in ADO.Sessions.Session;
Search : in String);
-- Set the entity type (database table) onto which the tags are associated.
procedure Set_Entity_Type (Into : in out Tag_Search_Bean;
Table : in ADO.Schemas.Class_Mapping_Access);
-- Create the tag search bean instance.
function Create_Tag_Search_Bean (Module : in AWA.Tags.Modules.Tag_Module_Access)
return Util.Beans.Basic.Readonly_Bean_Access;
type Tag_Info_List_Bean is
new AWA.Tags.Models.Tag_Info_List_Bean and Util.Beans.Basic.Bean with private;
type Tag_Info_List_Bean_Access is access all Tag_Info_List_Bean'Class;
-- Set the value identified by the name.
-- If the name cannot be found, the method should raise the No_Value
-- exception.
overriding
procedure Set_Value (From : in out Tag_Info_List_Bean;
Name : in String;
Value : in Util.Beans.Objects.Object);
-- Load the list of tags.
procedure Load_Tags (Into : in out Tag_Info_List_Bean;
Session : in out ADO.Sessions.Session);
-- Create the tag info list bean instance.
function Create_Tag_Info_List_Bean (Module : in AWA.Tags.Modules.Tag_Module_Access)
return Util.Beans.Basic.Readonly_Bean_Access;
-- The <tt>Entity_Tag_Map</tt> contains a list of tags associated with some entities.
-- It allows to retrieve from the database all the tags associated with several entities
-- and get the list of tags for a given entity.
type Entity_Tag_Map is new Ada.Finalization.Limited_Controlled with private;
-- Get the list of tags associated with the given entity.
-- Returns null if the entity does not have any tag.
function Get_Tags (From : in Entity_Tag_Map;
For_Entity : in ADO.Identifier)
return Util.Beans.Lists.Strings.List_Bean_Access;
-- Get the list of tags associated with the given entity.
-- Returns a null object if the entity does not have any tag.
function Get_Tags (From : in Entity_Tag_Map;
For_Entity : in ADO.Identifier)
return Util.Beans.Objects.Object;
-- Release the list of tags.
procedure Clear (List : in out Entity_Tag_Map);
-- Load the list of tags associated with a list of entities.
procedure Load_Tags (Into : in out Entity_Tag_Map;
Session : in out ADO.Sessions.Session'Class;
Entity_Type : in String;
List : in ADO.Utils.Identifier_Vector);
-- Release the list of tags.
overriding
procedure Finalize (List : in out Entity_Tag_Map);
private
type Tag_List_Bean is
new Util.Beans.Objects.Lists.List_Bean and Util.Beans.Basic.Bean with record
Module : AWA.Tags.Modules.Tag_Module_Access;
Entity_Type : Ada.Strings.Unbounded.Unbounded_String;
Permission : Ada.Strings.Unbounded.Unbounded_String;
Current : Natural := 0;
Added : Util.Strings.Vectors.Vector;
Deleted : Util.Strings.Vectors.Vector;
end record;
type Tag_Search_Bean is
new Util.Beans.Objects.Lists.List_Bean and Util.Beans.Basic.Bean with record
Module : AWA.Tags.Modules.Tag_Module_Access;
Entity_Type : Ada.Strings.Unbounded.Unbounded_String;
end record;
type Tag_Info_List_Bean is
new AWA.Tags.Models.Tag_Info_List_Bean and Util.Beans.Basic.Bean with record
Module : AWA.Tags.Modules.Tag_Module_Access;
Entity_Type : Ada.Strings.Unbounded.Unbounded_String;
end record;
package Entity_Tag_Maps is
new Ada.Containers.Hashed_Maps (Key_Type => ADO.Identifier,
Element_Type => Util.Beans.Lists.Strings.List_Bean_Access,
Hash => ADO.Utils.Hash,
Equivalent_Keys => ADO."=",
"=" => Util.Beans.Lists.Strings."=");
type Entity_Tag_Map is new Ada.Finalization.Limited_Controlled with record
Tags : Entity_Tag_Maps.Map;
end record;
end AWA.Tags.Beans;
|