1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2000-2003 --
-- ACT-Europe --
-- --
-- Authors: Dmitriy Anisimkov - Pascal Obry --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
------------------------------------------------------------------------------
-- $Id: aws-config-ini.adb,v 1.1 2003/10/05 19:59:52 Jano Exp $
with Ada.Command_Line;
with Ada.Strings.Fixed;
with Ada.Strings.Maps;
with Ada.Strings.Unbounded;
with Ada.Text_IO;
with AWS.Utils;
package body AWS.Config.Ini is
use Ada;
use Ada.Strings.Unbounded;
function Program_Ini_File return String;
-- Returns initialization filename for current server (using the
-- executable name and adding .ini)
procedure Read_If_Present
(Config : in out Object;
Filename : in String);
-- Read and parse Filename, does not raise an exception if the file does
-- not exists.
----------------------
-- Program_Ini_File --
----------------------
function Program_Ini_File return String is
Exec_Name : constant String := Ada.Command_Line.Command_Name;
Last : Natural;
First : Natural;
begin
First := Strings.Fixed.Index
(Exec_Name, Strings.Maps.To_Set ("/\"), Going => Strings.Backward);
if First = 0 then
First := Exec_Name'First;
end if;
Last := Strings.Fixed.Index
(Exec_Name (First .. Exec_Name'Last), ".", Strings.Backward);
if Last = 0 then
return Exec_Name & ".ini";
else
return Exec_Name (Exec_Name'First .. Last) & "ini";
end if;
end Program_Ini_File;
----------
-- Read --
----------
procedure Read
(Config : in out Object;
Filename : in String)
is
procedure Error_Message (Filename : in String; Message : in String);
-- Output error message with filename and line number.
procedure Set_Value
(Filename : in String;
Key : in String;
Value : in String);
Line : Natural;
-- current line number parsed
Process_Mode : Boolean := True;
-- Set to True when parsing a file that can support per process
-- options.
-------------------
-- Error_Message --
-------------------
procedure Error_Message (Filename : in String; Message : in String) is
begin
Text_IO.Put (Text_IO.Current_Error, '(' & Filename & ':');
Text_IO.Put (Text_IO.Current_Error, AWS.Utils.Image (Line));
Text_IO.Put_Line (Text_IO.Current_Error, ") " & Message & '.');
end Error_Message;
---------------
-- Set_Value --
---------------
procedure Set_Value
(Filename : in String;
Key : in String;
Value : in String)
is
use Ada.Strings.Unbounded;
function "+" (S : in String)
return Unbounded_String
renames To_Unbounded_String;
Expected_Type : Unbounded_String;
P : Parameter_Name;
begin
begin
P := Parameter_Name'Value (Key);
exception
when others =>
Error_Message (Filename, "unrecognized option " & Key);
return;
end;
if P in Server_Parameter_Name then
case Config.P (P).Kind is
when Str =>
Expected_Type := +"string";
Config.P (P).Str_Value := +Value;
when Dir =>
Expected_Type := +"string";
if Value (Value'Last) = '/'
or else Value (Value'Last) = '\'
then
Config.P (P).Dir_Value := +Value;
else
Config.P (P).Dir_Value := +(Value & '/');
end if;
when Pos =>
Expected_Type := +"positive";
Config.P (P).Pos_Value := Positive'Value (Value);
when Dur =>
Expected_Type := +"duration";
Config.P (P).Dur_Value := Duration'Value (Value);
when Bool =>
Expected_Type := +"boolean";
Config.P (P).Bool_Value := Boolean'Value (Value);
end case;
else
if not Process_Mode then
Error_Message
(Filename,
"Per process option (" & Key
& ") not supported for this file");
end if;
case Process_Options (P).Kind is
when Str =>
Expected_Type := +"string";
Process_Options (P).Str_Value := +Value;
when Dir =>
Expected_Type := +"string";
if Value (Value'Last) = '/'
or else Value (Value'Last) = '\'
then
Process_Options (P).Dir_Value := +Value;
else
Process_Options (P).Dir_Value := +(Value & '/');
end if;
when Pos =>
Expected_Type := +"positive";
Process_Options (P).Pos_Value := Positive'Value (Value);
when Dur =>
Expected_Type := +"duration";
Process_Options (P).Dur_Value := Duration'Value (Value);
when Bool =>
Expected_Type := +"boolean";
Process_Options (P).Bool_Value := Boolean'Value (Value);
end case;
end if;
exception
when others =>
Error_Message
(Filename,
"wrong value for " & Key
& " " & To_String (Expected_Type) & " expected");
end Set_Value;
Separators : constant Strings.Maps.Character_Set
:= Strings.Maps.To_Set (' ' & ASCII.HT);
File : Text_IO.File_Type;
Buffer : String (1 .. 1024);
Last : Natural;
K_First : Natural;
K_Last : Natural;
begin
Text_IO.Open (Name => Filename,
File => File,
Mode => Text_IO.In_File);
Line := 0;
while not Text_IO.End_Of_File (File) loop
Text_IO.Get_Line (File, Buffer, Last);
Line := Line + 1;
-- Remove comments
for I in 1 .. Last loop
if Buffer (I) = '#' then
Last := I - 1;
exit;
end if;
end loop;
if Last /= 0 then
-- Looks for Key token
Strings.Fixed.Find_Token
(Buffer (1 .. Last), Separators, Strings.Outside,
K_First, K_Last);
if K_Last /= 0 then
declare
Key : constant String := Buffer (K_First .. K_Last);
Value : constant String := Strings.Fixed.Trim
(Buffer (K_Last + 1 .. Last), Separators, Separators);
begin
if Value = "" then
Error_Message (Filename, "No value for " & Key);
else
Set_Value (Filename, Key, Value);
end if;
end;
else
Error_Message (Filename, "wrong format");
end if;
end if;
end loop;
Text_IO.Close (File);
end Read;
---------------------
-- Read_If_Present --
---------------------
procedure Read_If_Present
(Config : in out Object;
Filename : in String) is
begin
Read (Config, Filename);
exception
when Text_IO.Name_Error =>
null;
end Read_If_Present;
begin
Read_If_Present (Server_Config, "aws.ini");
Read_If_Present (Server_Config, Program_Ini_File);
end AWS.Config.Ini;
|