1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167 | -- --
-- package Copyright (c) Dmitry A. Kazakov --
-- Synchronization.Interprocess. Luebeck --
-- Events Spring, 2018 --
-- Implementation --
-- Last revision : 01:09 01 May 2018 --
-- --
-- This library is free software; you can redistribute it and/or --
-- modify it under the terms of the GNU General Public License as --
-- published by the Free Software Foundation; either version 2 of --
-- the License, or (at your option) any later version. This library --
-- is distributed in the hope that it will be useful, but WITHOUT --
-- ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. You should have --
-- received a copy of the GNU General Public License along with --
-- this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
-- As a special exception, if other files instantiate generics from --
-- this unit, or you link this unit with other files to produce an --
-- executable, this unit does not by itself cause the resulting --
-- executable to be covered by the GNU General Public License. This --
-- exception does not however invalidate any other reasons why the --
-- executable file might be covered by the GNU Public License. --
--____________________________________________________________________--
with Ada.Exceptions; use Ada.Exceptions;
with Ada.IO_Exceptions; use Ada.IO_Exceptions;
with System.Address_To_Access_Conversions;
package body Synchronization.Interprocess.Events is
procedure Check (Message : String) is
Code : constant DWORD := GetLastError;
begin
if Code = ERROR_INVALID_HANDLE then
Raise_Exception
( Status_Error'Identity,
Message & "Event is not initialized or already finalized"
);
else
Raise_From_LastError (Data_Error'Identity, Message, Code);
end if;
end Check;
procedure Finalize (Object : in out Event) is
Result : BOOL;
begin
if Object.External /= INVALID_HANDLE_VALUE then
Result := CloseHandle (Object.External);
Object.External := INVALID_HANDLE_VALUE;
end if;
Synchronization.Interprocess.Finalize
( Abstract_Shared_Object (Object)
);
end Finalize;
function Get_Size (Object : Event) return Storage_Count is
begin
return Round (HANDLE'Max_Size_In_Storage_Elements);
end Get_Size;
function Is_Signaled (Object : Event) return Boolean is
begin
case WaitForSingleObject (Object.External, 0) is
when WAIT_OBJECT_0 =>
return True;
when others =>
return False;
end case;
end Is_Signaled;
procedure Map
( Object : in out Event;
Shared : in out Abstract_Shared_Environment'Class;
Location : System.Address;
Size : Storage_Count;
Owner : Boolean
) is
package Conversions is
new System.Address_To_Access_Conversions (HANDLE);
This : HANDLE renames Conversions.To_Pointer (Location).all;
begin
if Owner then
Object.External := CreateEvent (ManualReset => 1);
if Object.External = 0 then
Object.External := INVALID_HANDLE_VALUE;
Raise_From_LastError
( Data_Error'Identity,
"Event creation fault: ",
GetLastError
);
end if;
This := Object.External;
else
if ( 0
= DuplicateHandle
( SourceProcessHandle => Shared.Server,
SourceHandle => This,
TargetProcessHandle => GetCurrentProcess,
TargetHandle =>
Object.External'Unchecked_Access
) )
then
Raise_From_LastError
( Data_Error'Identity,
"Cannot duplicate a handle to the event: ",
GetLastError
);
end if;
end if;
end Map;
procedure Reset (Object : in out Event) is
begin
if 0 = ResetEvent (Object.External) then
Check ("Reset event fault: ");
end if;
end Reset;
procedure Signal (Object : in out Event) is
begin
if 0 = SetEvent (Object.External) then
Check ("Set event fault: ");
end if;
end Signal;
procedure Wait
( Object : in out Event;
Timeout : Duration := Duration'Last
) is
begin
case WaitForSingleObject
( Object.External,
Milliseconds (Timeout)
) is
when WAIT_OBJECT_0 =>
return;
when WAIT_TIMEOUT =>
Raise_Exception (Timeout_Error'Identity, "Timed out");
when others =>
Check ("Event wait fault: ");
end case;
end Wait;
procedure Wait
( Object : in out Event;
Timeout : Duration;
Signaled : out Boolean
) is
begin
case WaitForSingleObject
( Object.External,
Milliseconds (Timeout)
) is
when WAIT_OBJECT_0 =>
Signaled := True;
when WAIT_TIMEOUT =>
Signaled := False;
when others =>
Check ("Event wait fault: ");
end case;
end Wait;
end Synchronization.Interprocess.Events;
|