mcp2221_1.20220.1_af01ab34/src/objects/hid/hid-hidapi.ads

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
-- 64-byte message services using the raw HID services from libhidapi

-- Copyright (C)2018-2020, Philip Munts, President, Munts AM Corp.
--
-- Redistribution and use in source and binary forms, with or without
-- modification, are permitted provided that the following conditions are met:
--
-- * Redistributions of source code must retain the above copyright notice,
--   this list of conditions and the following disclaimer.
--
-- THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
-- AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
-- IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
-- ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
-- LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
-- CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
-- SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
-- INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
-- CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
-- ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
-- POSSIBILITY OF SUCH DAMAGE.

-- Allowed values for the timeout parameter:
--
-- -1 => Receive operation blocks forever, until a report is received
--  0 => Receive operation never blocks at all
-- >0 => Receive operation blocks for the indicated number of milliseconds

WITH Message64;

PRIVATE WITH Interfaces.C;
PRIVATE WITH System;

PACKAGE HID.hidapi IS

  -- Type definitions

  TYPE MessengerSubclass IS NEW Message64.MessengerInterface WITH PRIVATE;

  Destroyed : CONSTANT MessengerSubclass;

  -- Constructor

  FUNCTION Create
   (vid       : HID.Vendor;
    pid       : HID.Product;
    serial    : String  := "";
    timeoutms : Integer := 1000) RETURN Message64.Messenger;

  -- Initializer

  PROCEDURE Initialize
   (Self      : IN OUT MessengerSubclass;
    vid       : HID.Vendor;
    pid       : HID.Product;
    serial    : String  := "";
    timeoutms : Integer := 1000);

  -- Destroyer

  PROCEDURE Destroy(Self : IN OUT MessengerSubclass);

  -- Send a message

  PROCEDURE Send
   (Self : MessengerSubclass;
    msg  : Message64.Message);

  -- Receive a message

  PROCEDURE Receive
   (Self : MessengerSubclass;
    msg  : OUT Message64.Message);

  -- Get HID device name string

  FUNCTION Name(Self : MessengerSubclass) RETURN String;

  -- Get HID device manufacturer string

  FUNCTION Manufacturer
   (Self : MessengerSubclass) RETURN String;

  -- Get HID device product string

  FUNCTION Product
   (Self : MessengerSubclass) RETURN String;

  -- Get HID device serial number string

  FUNCTION SerialNumber
   (Self : MessengerSubclass) RETURN String;

PRIVATE

  -- Check whether the HID device has been destroyed

  PROCEDURE CheckDestroyed(Self : MessengerSubclass);

  TYPE MessengerSubclass IS NEW Message64.MessengerInterface WITH RECORD
    handle  : System.Address := System.Null_Address;
    timeout : Integer        := Integer'First;
  END RECORD;

  Destroyed : CONSTANT MessengerSubclass :=
    MessengerSubclass'(System.Null_Address, Integer'First);

  -- Minimal Ada thin binding to hidapi

  FUNCTION hid_init RETURN Integer;

  FUNCTION hid_open
   (vid     : Interfaces.C.unsigned_short;
    pid     : Interfaces.C.unsigned_short;
    serial  : System.Address) RETURN System.Address;

  PROCEDURE hid_close
   (handle  : System.Address);

  FUNCTION hid_read_timeout
   (handle  : System.Address;
    buf     : System.Address;
    len     : Interfaces.C.size_t;
    timeout : Integer) RETURN Integer;

  FUNCTION hid_write
   (handle  : System.Address;
    buf     : System.Address;
    len     : Interfaces.C.size_t) RETURN Integer;

  FUNCTION hid_get_manufacturer_string
   (handle  : System.Address;
    buf     : OUT Interfaces.C.wchar_array;
    len     : Interfaces.C.size_t) RETURN Integer;

  FUNCTION hid_get_product_string
   (handle  : System.Address;
    buf     : OUT Interfaces.C.wchar_array;
    len     : Interfaces.C.size_t) RETURN Integer;

  FUNCTION hid_get_serial_number_string
   (handle  : System.Address;
    buf     : OUT Interfaces.C.wchar_array;
    len     : Interfaces.C.size_t) RETURN Integer;

  PRAGMA Import(C, hid_init);
  PRAGMA Import(C, hid_open);
  PRAGMA Import(C, hid_close);
  PRAGMA Import(C, hid_read_timeout);
  PRAGMA Import(C, hid_write);
  PRAGMA Import(C, hid_get_manufacturer_string);
  PRAGMA Import(C, hid_get_product_string);
  PRAGMA Import(C, hid_get_serial_number_string);

  PRAGMA Link_With("-lhidapi");

END HID.hidapi;