lace_0.1.0_347e4627/source/environ/lace-environ-paths.adb

   1
   2
   3
   4
   5
   6
   7
   8
   9
  10
  11
  12
  13
  14
  15
  16
  17
  18
  19
  20
  21
  22
  23
  24
  25
  26
  27
  28
  29
  30
  31
  32
  33
  34
  35
  36
  37
  38
  39
  40
  41
  42
  43
  44
  45
  46
  47
  48
  49
  50
  51
  52
  53
  54
  55
  56
  57
  58
  59
  60
  61
  62
  63
  64
  65
  66
  67
  68
  69
  70
  71
  72
  73
  74
  75
  76
  77
  78
  79
  80
  81
  82
  83
  84
  85
  86
  87
  88
  89
  90
  91
  92
  93
  94
  95
  96
  97
  98
  99
 100
 101
 102
 103
 104
 105
 106
 107
 108
 109
 110
 111
 112
 113
 114
 115
 116
 117
 118
 119
 120
 121
 122
 123
 124
 125
 126
 127
 128
 129
 130
 131
 132
 133
 134
 135
 136
 137
 138
 139
 140
 141
 142
 143
 144
 145
 146
 147
 148
 149
 150
 151
 152
 153
 154
 155
 156
 157
 158
 159
 160
 161
 162
 163
 164
 165
 166
 167
 168
 169
 170
 171
 172
 173
 174
 175
 176
 177
 178
 179
 180
 181
 182
 183
 184
 185
 186
 187
 188
 189
 190
 191
 192
 193
 194
 195
 196
 197
 198
 199
 200
 201
 202
 203
 204
 205
 206
 207
 208
 209
 210
 211
 212
 213
 214
 215
 216
 217
 218
 219
 220
 221
 222
 223
 224
 225
 226
 227
 228
 229
 230
 231
 232
 233
 234
 235
 236
 237
 238
 239
 240
 241
 242
 243
 244
 245
 246
 247
 248
 249
 250
 251
 252
 253
 254
 255
 256
 257
 258
 259
 260
 261
 262
 263
 264
 265
 266
 267
 268
 269
 270
 271
 272
 273
 274
 275
 276
 277
 278
 279
 280
 281
 282
 283
 284
 285
 286
 287
 288
 289
 290
 291
 292
 293
 294
 295
 296
 297
 298
 299
 300
 301
 302
 303
 304
 305
 306
 307
 308
 309
 310
 311
 312
 313
 314
 315
 316
 317
 318
 319
 320
 321
 322
 323
 324
 325
 326
 327
 328
 329
 330
 331
 332
 333
 334
 335
 336
 337
 338
 339
 340
 341
 342
 343
 344
 345
 346
 347
 348
 349
 350
 351
 352
 353
 354
 355
 356
 357
 358
 359
 360
 361
 362
 363
 364
 365
 366
 367
 368
 369
 370
 371
 372
 373
 374
 375
 376
 377
 378
 379
 380
 381
 382
 383
 384
 385
 386
 387
 388
 389
 390
 391
 392
 393
 394
 395
 396
 397
 398
 399
 400
 401
 402
 403
 404
 405
 406
 407
 408
 409
 410
 411
 412
 413
 414
 415
 416
 417
 418
 419
 420
 421
 422
 423
 424
 425
 426
 427
 428
 429
 430
 431
 432
 433
 434
 435
 436
 437
 438
 439
 440
 441
 442
 443
 444
 445
 446
 447
 448
 449
 450
 451
 452
 453
 454
 455
 456
 457
 458
 459
 460
 461
 462
 463
 464
 465
 466
 467
 468
 469
 470
 471
 472
 473
 474
 475
 476
 477
 478
 479
 480
 481
 482
 483
 484
 485
 486
 487
 488
 489
 490
 491
 492
 493
 494
 495
 496
 497
 498
 499
 500
 501
 502
 503
 504
 505
 506
 507
 508
 509
 510
 511
 512
 513
 514
 515
 516
 517
 518
 519
 520
 521
 522
 523
 524
 525
 526
 527
 528
 529
 530
 531
 532
 533
 534
 535
 536
 537
 538
 539
 540
 541
 542
 543
 544
 545
 546
 547
 548
 549
 550
 551
 552
 553
 554
 555
 556
 557
 558
 559
 560
 561
 562
 563
 564
 565
 566
 567
 568
 569
 570
 571
 572
 573
 574
 575
 576
 577
 578
 579
 580
 581
 582
 583
 584
 585
 586
 587
 588
 589
 590
 591
 592
 593
 594
 595
 596
 597
 598
 599
 600
 601
 602
 603
 604
 605
 606
 607
 608
 609
 610
 611
 612
 613
 614
 615
 616
 617
 618
 619
 620
 621
 622
 623
 624
 625
 626
 627
 628
 629
 630
 631
 632
 633
 634
 635
 636
 637
 638
 639
 640
 641
 642
 643
 644
 645
 646
 647
 648
 649
 650
 651
 652
 653
 654
 655
 656
 657
 658
 659
 660
 661
 662
 663
 664
 665
 666
 667
 668
 669
 670
 671
 672
 673
 674
 675
 676
 677
 678
 679
 680
 681
 682
 683
 684
 685
 686
 687
 688
 689
 690
 691
 692
 693
 694
 695
 696
 697
 698
 699
 700
 701
 702
 703
 704
 705
 706
 707
 708
 709
 710
 711
 712
 713
 714
 715
 716
 717
 718
 719
 720
 721
 722
 723
 724
 725
 726
 727
 728
 729
 730
 731
 732
 733
 734
 735
 736
 737
 738
 739
 740
 741
 742
 743
 744
 745
 746
 747
 748
 749
 750
 751
 752
 753
 754
 755
 756
 757
 758
 759
 760
 761
 762
 763
 764
 765
 766
 767
 768
 769
 770
 771
 772
 773
 774
 775
 776
 777
 778
 779
 780
 781
 782
 783
 784
 785
 786
 787
 788
 789
 790
 791
 792
 793
 794
 795
 796
 797
 798
 799
 800
 801
 802
 803
 804
 805
 806
 807
 808
 809
 810
 811
 812
 813
 814
 815
 816
 817
 818
 819
 820
 821
 822
 823
 824
 825
 826
 827
 828
 829
 830
 831
 832
 833
 834
 835
 836
 837
 838
 839
 840
 841
 842
 843
 844
 845
 846
 847
 848
 849
 850
 851
 852
 853
 854
 855
 856
 857
 858
 859
 860
 861
 862
 863
 864
 865
 866
 867
 868
 869
 870
 871
 872
 873
 874
 875
 876
 877
 878
 879
 880
 881
 882
 883
 884
 885
 886
 887
 888
 889
 890
 891
 892
 893
 894
 895
 896
 897
 898
 899
 900
 901
 902
 903
 904
 905
 906
 907
 908
 909
 910
 911
 912
 913
 914
 915
 916
 917
 918
 919
 920
 921
 922
 923
 924
 925
 926
 927
 928
 929
 930
 931
 932
 933
 934
 935
 936
 937
 938
 939
 940
 941
 942
 943
 944
 945
 946
 947
 948
 949
 950
 951
 952
 953
 954
 955
 956
 957
 958
 959
 960
 961
 962
 963
 964
 965
 966
 967
 968
 969
 970
 971
 972
 973
 974
 975
 976
 977
 978
 979
 980
 981
 982
 983
 984
 985
 986
 987
 988
 989
 990
 991
 992
 993
 994
 995
 996
 997
 998
 999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
with
     lace.Environ.OS_Commands,
     lace.Text.utility,
     posix.file_Status,
     posix.Calendar,

     shell.Directory_Iteration,

     lace.Text.all_Tokens,

     ada.Strings.fixed,
     ada.Characters.handling,
     ada.Directories,
     ada.Direct_IO,
     ada.Tags,
     ada.Text_IO,
     ada.IO_Exceptions;

package body lace.Environ.Paths
is
   -----------
   --- General
   --

   function "+" (Source : in unbounded_String) return String
                 renames to_String;


   function expand_GLOB (GLOB : in String) return String
   is
      use ada.Text_IO;

      FileName : constant File     := +"/tmp/lace_environ_temporary_shell.sh";
      File     :          File_Type;
   begin
      create   (File, out_File, +Filename);
      put_Line (File, "echo " & GLOB);
      close    (File);

      change_Mode (Path (Filename), to => "a+rwx");

      declare
         use lace.Environ.OS_Commands;
         Output : constant String := run_OS ("bash " & (+Filename));
      begin
         rid_File (Filename);
         return Output;
      end;
   end expand_GLOB;



   ---------
   --- Paths
   --

   function to_String (Self : in Path'Class) return String
   is
   begin
      return to_String (Self.Name);
   end to_String;


   procedure check (Self : in Path'Class)
   is
      use ada.Tags,
          ada.Strings.fixed,
          ada.Characters.handling;

      Tag_full_Name : constant String := to_Lower (ada.Tags.expanded_Name (Self'Tag));
      Tag_Name      : constant String := (if Self'Tag = Folder'Tag then Tail (Tag_full_Name, 6)
                                                                   else Tail (Tag_full_Name, 4));
   begin
      if Self.Name = ""
      then
         raise Error with "No " & Tag_Name & " specified.";
      end if;

      if not Exists (Self)
      then
         raise Error with Tag_Name & " '" & (+Self) & "' does not exist.";
      end if;
   end check;


   procedure link (Self, To : in Path)
   is
   begin
      check (Self);

      declare
         use lace.Environ.OS_Commands;
         Output : constant String := run_OS (  "ln -s "
                                             & (+Self)
                                             & " "
                                             & (+To));
      begin

         if Output /= ""
         then
            raise Error with Output;
         end if;
      end;
   end link;


   procedure change_Mode (Self : in Path;
                          To   : in String)
   is
   begin
      check (Self);

      declare
         use lace.Environ.OS_Commands;
         Output : constant String := run_OS ("chmod -R " & To & " " & (+Self));
      begin
         if Output /= ""
         then
            raise Error with Output;
         end if;
      end;
   end change_Mode;


   procedure change_Owner (Self : in Path;
                           To   : in String)
   is
   begin
      check (Self);

      declare
         use lace.Environ.OS_Commands;
         Output : constant String := run_OS ("chown -R " & To & " " & (+Self));
      begin
         if Output /= ""
         then
            raise Error with Output;
         end if;
      end;
   end change_Owner;


   function Exists (Self : in Path) return Boolean
   is
   begin
      if +Self = ""
      then
         raise Error with "No path specified.";
      end if;

      return ada.Directories.Exists (+Self);
   end Exists;


   function is_Folder (Self : in Path) return Boolean
   is
      use ada.Directories;
   begin
      check (Self);
      return Kind (+Self) = Directory;
   end is_Folder;


   function is_File (Self : in Path) return Boolean
   is
      use ada.Directories;
   begin
      check (Self);
      return Kind (+Self) = Ordinary_File;
   end is_File;


   function is_Special (Self : in Path) return Boolean
   is
      use ada.Directories;
   begin
      check (Self);
      return Kind (+Self) = Special_File;
   end is_Special;


   function is_Absolute (Self : in Path) return Boolean
   is
   begin
      if Length (Self.Name) = 0
      then
         return False;
      end if;

      return Element (Self.Name, 1) = '/';
   end is_Absolute;


   function is_Relative (Self : in Path) return Boolean
   is
   begin
      return not is_Absolute (Self);
   end is_Relative;


   function modify_Time (Self : in Path) return ada.Calendar.Time
   is
   begin
      check (Self);

      declare
         use POSIX,
             POSIX.Calendar,
             POSIX.File_Status;

         the_Status : constant Status     := get_File_Status (pathname => to_POSIX_String (+Self));
         Time       : constant POSIX_Time := last_modification_Time_of (the_Status);
      begin
         return to_Time (Time);
      end;
   end modify_Time;


   function Parent (Self : in Path'Class) return Folder
   is
   begin
      declare
         use ada.Strings;
         Index : constant Natural := fixed.Index (+Self, "/", going => Backward);
      begin
         if    Index = 0
         then
            return no_Folder;

         elsif Index = 1
         then
            return +"/";
         end if;

         declare
            Result : Folder;
         begin
            Result.Name := Head (Self.Name,
                                 Count => Index - 1);
            return Result;
         end;
      end;
   end Parent;



   function Name (Self : in Path) return String
   is
   begin
   return +Self.Name;
   end Name;


   function Simple (Self : in Path) return String
   is
   begin
      check (Self);

      declare
         use ada.Strings;
         Idx  : constant Natural := Index  (Self.Name, "/", going => Backward);
         Last : constant Natural := Length (Self.Name);
      begin
         if Idx = 0
         then
            return +Self;
         else
            return Slice (Self.Name, Low  => Idx + 1,
                                     High => Last);
         end if;
      end;
   end Simple;


   -----------
   --- Folders
   --

   function to_Folder (Name : in String) return Folder
   is
   begin
      return (Name => To_Unbounded_String (Name));
   end to_Folder;


   function "+" (Left : in Folder;   Right : in Folder) return Folder
   is
      R_Folder : constant String := (if Right.is_Absolute then  Right.Simple
                                                          else +Right);
      Result   : Folder;
   begin
      Result.Name := Left.Name;
      append (Result.Name, "/" & R_Folder);

      return Result;
   end "+";


   function "+" (Left  : in Folder'Class;
                 Right : in File  'Class) return File
   is
      R_File : constant String := (if Right.is_Absolute then  Right.Simple
                                                        else +Right);
      Result : File;
   begin
      Result.Name := Left.Name;
      append (Result.Name, "/" & R_File);

      return Result;
   end "+";


   function current_Folder return Folder
   is
   begin
      return +ada.Directories.current_Directory;
   end current_Folder;


   protected folder_Lock
   is
      entry change (To : in Folder);
      procedure clear;
   private
      Locked : Boolean := False;
   end folder_Lock;


   protected body folder_Lock
   is
      entry change (To : in Folder)
      when not Locked
      is
      begin
         check (To);
         ada.Directories.set_Directory (+To);
         Locked := True;
      end change;

      procedure clear
      is
      begin
         Locked := False;
      end clear;
   end folder_Lock;


   procedure go_to_Folder (Self  : in Folder;
                           Lock   : in Boolean := False)
   is
   begin
      check (Self);

      if Lock
      then
         folder_Lock.change (Self);
      else
         ada.Directories.set_Directory (+Self);
      end if;
   end go_to_Folder;


   procedure unlock_Folder
   is
   begin
      folder_Lock.clear;
   end unlock_Folder;


   function contents_Count (Self  : in Folder;
                            Recurse : in Boolean := False) return Natural
   is
      use Shell.Directory_Iteration,
          Ada.Directories;

      Count : Natural := 0;
   begin
      check (Self);

      for Each of To_Directory (+Self, Recurse)
      loop
         declare
            Name : constant String := Simple_Name (Each);
         begin
            if not (Name = "." or Name = "..")
            then
               Count := Count + 1;
            end if;
         end;
      end loop;

      return Count;
   end contents_Count;


   function is_Empty (Self : in Folder) return Boolean
   is
   begin
      check (Self);
      return contents_Count (Self) = 0;
   end is_Empty;


   procedure rid_Folder (Self : in Folder)
   is
   begin
      check (Self);
      ada.Directories.delete_Tree (+Self);
   exception
      when ada.IO_Exceptions.name_Error =>
         null;
   end rid_Folder;


   procedure copy_Folder (Self : in Folder;   To : in Folder)
   is
      use lace.Environ.OS_Commands;
   begin
      check (Self);
      check (To);

      run_OS ("cp -fr " & (+Self) & " " & (+To));
   end copy_Folder;


   procedure move_Folder (Self : in Folder;   To : in Folder)
   is
      use lace.Environ.OS_Commands;
   begin
      check (Self);
      check (To);

      run_OS ("mv " & (+Self) & " " & (+To));
   end move_Folder;


   procedure rename_Folder (Self  : in Folder;   To : in Folder)
   is
   begin
      check (Self);

      ada.Directories.rename (+Self, +To);
   end rename_Folder;


   procedure ensure_Folder (Self  : in Folder)
   is
   begin
      if Self.Name = ""
      then
         raise Error with "No folder specified.";
      end if;

      ada.Directories.create_Path (+Self);
   end ensure_Folder;


   function Relative (Self : in Folder;   To : in Folder'Class) return Folder
   is
      use lace.Text,
          lace.Text.utility;
      Filename        : constant lace.Text.item := to_Text (+Self);
      relative_Folder : constant lace.Text.item := replace (Filename, pattern => +To & "/",
                                                                      by      => "");
   begin
      return to_Folder (+relative_Folder);
   end Relative;


   -------------------
   --- Folder Contexts
   --

   procedure push_Folder (Context     : in out folder_Context;
                          goto_Folder : in     Folder'Class)
   is
   begin
      check (goto_Folder);

      Context.folder_Stack.append (current_Folder);
      go_to_Folder (goto_Folder);
   end push_Folder;


   procedure pop_Folder (Context : in out folder_Context)
   is
   begin
      if Context.folder_Stack.is_Empty
      then
         raise Error with "'pop_Folder': No prior folder exists.";
      end if;

      declare
         prior_Folder : constant Folder := Context.folder_Stack.last_Element;
      begin
         Context.folder_Stack.delete_Last;
         go_to_Folder (prior_Folder);
      end;
   end pop_Folder;


   procedure pop_All (Context : in out folder_Context)
   is
   begin
      if Context.folder_Stack.is_Empty
      then
         raise Error with "'pop_All': No initial folder exists.";
      end if;

      go_to_Folder (Context.folder_Stack.Element (1));
      Context.folder_Stack.clear;
   end pop_All;


   ---------
   --- Files
   --

   function to_File (Name : in String) return File
   is
      Self : File;
   begin
      set_unbounded_String (Self.Name, Name);
      return Self;
   end to_File;


   function "+" (Left  : in File'Class;
                 Right : in File_Extension) return File
   is
   begin
      return to_File (+Left & "." & String (Right));
   end "+";


   function Extension (Self : in File) return File_Extension
   is
      use ada.Directories;
   begin
      return File_Extension (Extension (+Self.Name));
   end Extension;


   procedure save (Self   : in File;
                   Text   : in String;
                   Binary : in Boolean := False)
   is
   begin
      if Binary
      then
         declare
            type binary_String is new String (Text'Range);
            package Binary_IO  is new ada.Direct_IO (binary_String);
            use     Binary_IO;
            File :  File_Type;
         begin
            create (File, out_File, +Self);
            write  (File, binary_String (Text));
            close  (File);
         end;
      else
         declare
            use ada.Text_IO;
            File : File_Type;
         begin
            create (File, out_File, +Self);
            put    (File, Text);
            close  (File);
         end;
      end if;
   end save;


   procedure save (Self : in File;
                   Data : in environ.Data)
   is
   begin
      check (Self);
      declare
         type Element_Array is new environ.Data  (Data'Range);
         package Binary_IO  is new ada.Direct_IO (Element_Array);
         use     Binary_IO;
         File :  File_Type;
      begin
         create (File, out_File, +Self);
         write  (File, Element_Array (Data));
         close  (File);
      end;
   end save;


   function load (Self : in File) return String
   is
      use type ada.Directories.File_Size;
      Size : ada.Directories.File_Size;
   begin
      check (Self);
      Size := ada.Directories.Size (+Self);

      if Size = 0
      then
         return "";
      end if;

      declare
         type my_String is new String (1 .. Natural (Size));

         package String_IO is new ada.Direct_IO (my_String);
         use     String_IO;

         File   : File_Type;
         Result : my_String;
      begin
         open  (File, in_File, +Self);
         read  (File, Result);
         close (File);

         return String (Result);
      end;

   exception
      when ada.IO_Exceptions.Name_Error =>
         raise Error with "Cannot load missing file: '" & (+Self) & "'";
   end load;


   function load (Self : in File) return Data
   is
   begin
      check (Self);
      declare
         use ada.Streams;
         Size : constant ada.Directories.File_Size := ada.Directories.Size (+Self);

         type Element_Array is new Data (0 .. Stream_Element_Offset (Size) - 1);

         package Binary_IO  is new ada.Direct_IO (Element_Array);
         use     Binary_IO;

         File   : Binary_IO.File_Type;
         Result : Element_Array;
      begin
         open  (File, out_File, +Self);
         read  (File, Result);
         close (File);

         return Data (Result);
      end;

   exception
      when ada.IO_Exceptions.Name_Error =>
         raise Error with "Cannot load missing file: '" & (+Self) & "'";
   end load;


   procedure copy_File (Self : in File;   To : in File)
   is
   begin
      check (Self);
      check (To);

      ada.Directories.copy_File (+Self, +To);
   end copy_File;


   procedure copy_Files (Named : in String;   To : in Folder)
   is
      use lace.Text,
          lace.Text.all_Tokens,
          ada.Strings.fixed;

      all_Files : constant String        := (if Index (Named, "*") /= 0 then Expand_GLOB (Named)
                                                                        else Named);
      file_List : constant Text.items_1k := Tokens (to_Text (all_Files));
   begin
      check (To);

      for Each of file_List
      loop
         declare
            use ada.Directories;
            Name : constant String := +Each;
         begin
            if Kind (Name) = Directory
            then
               copy_Folder (+Name,
                            To);
            else
               copy_File (to_File (Name),
                          To + to_File (simple_Name (Name)));
            end if;
         end;
      end loop;
   end copy_Files;


   procedure move_File (Self : in File;   To : in File)
   is
   begin
      check (Self);
      check (To);

      -- 'Ada.Directories.Rename' fails when the file is moved across a device.
      -- For instance     Rename ("/tmp/a_file", "/home/user/a_file");

      ada.Directories.copy_File (+Self, +To);
      rid_File (Self);
   end move_File;


   procedure move_Files (Named : in String;   To : in Folder)
   is
   begin
      check (To);

      declare
         use lace.Text,
             lace.Text.all_Tokens,
             ada.Strings.fixed;

         all_Files : constant String        := (if Index (Named, "*") /= 0 then Expand_GLOB (Named)
                                                                           else Named);
         file_List : constant Text.items_1k := Tokens (to_Text (all_Files));
      begin
         for Each of file_List
         loop
            if +Each /= +To   -- Don't move a directory to a subdirectory of itself.
            then
               declare
                  use ada.Directories;
                  Name : constant String := +Each;
               begin
                  if Kind (Name) = Directory
                  then
                     move_Folder (+Name,
                                  To);
                  else
                     move_File (to_File (Name),
                                To + to_File (simple_Name (Name)));
                  end if;
               end;
            end if;
         end loop;
      end;
   end move_Files;


   procedure append (Self : in File;   Text : in String)
   is
   begin
      check (Self);

      declare
         use ada.Text_IO;
         Target : File_type;
      begin
         open  (Target, append_File, Name => +Self);
         put   (Target, Text);
         close (Target);
      end;
   end append;


   procedure append_File (Self : in File;   To : in File)
   is
   begin
      check (Self);
      check (To);

      declare
         use ada.Text_IO;

         Text   : constant String   := load (Self);
         Target :          File_type;
      begin
         open  (Target, append_File, Name => +To);
         put   (Target, Text);
         close (Target);
      end;
   end append_File;


   procedure rid_File (Self : in File)
   is
   begin
      check (Self);
      ada.Directories.delete_File (+Self);
   end rid_File;


   procedure rid_Files (Named : in String)
   is
      use lace.Text,
          lace.Text.all_Tokens,
          ada.Strings.fixed;

      all_Files : constant String        := (if Index (Named, "*") /= 0 then Expand_GLOB (Named)
                                                                        else Named);
      file_List : constant Text.items_1k := Tokens (to_Text (all_Files));
   begin
      for Each of file_List
      loop
         check    (to_File (+Each));
         rid_File (to_File (+Each));
      end loop;
   end rid_Files;


   procedure touch (Self : in File)
   is
      use lace.Environ.OS_Commands;
      Output : constant String := run_OS ("touch " & (+Self));
   begin
      if Output /= ""
      then
         raise Error with Output;
      end if;
   end touch;


   function Relative (Self : in File;   To : in Folder'Class) return File
   is
      use lace.Text,
          lace.Text.utility;
      Filename      : constant lace.Text.item := to_Text (+Self);
      relative_File : constant lace.Text.item := replace (Filename, pattern => +To & "/",
                                                                    by      => "");
   begin
      return to_File (+relative_File);
   end Relative;


   function rid_Extension (Self : in File) return File
   is
      use ada.Directories;

      Parent : constant Folder := Self.Parent;
      Name   : constant String := base_Name (+Self.Name);
   begin
      return Parent + to_File (Name);
   end rid_Extension;



   ---------------
   --- Compression
   --

   procedure compress (the_Path   : in Path'Class;
                       the_Format : in compress_Format := Tar_Xz;
                       the_Level  : in compress_Level  := 6)
   is
      use lace.Environ.OS_Commands;

      function level_Flag return String
      is
         use ada.Strings,
             ada.Strings.fixed;
      begin
         return " -"
              & Trim (compress_Level'Image (the_Level),
                      Left)
              & " ";
      end level_Flag;

   begin
      check (the_Path);

      case the_Format
      is
         when Tar |Tar_Bz2 | Tar_Gz | Tar_Xz =>
            declare
               Options : constant String := (case the_Format
                                             is
                                                when Tar     => "-cf",
                                                when Tar_Bz2 => "-cjf",
                                                when Tar_Gz  => "-czf",
                                                when Tar_Xz  => "-cJf",
                                                when others  => raise program_Error);
               Output  : constant String := run_OS (  "tar " & Options
                                                    & " "    & (+the_Path) & format_Suffix (the_Format)
                                                    & " "    & (+the_Path));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;

         when Gz =>
            declare
               Output : constant String := run_OS (  "gzip --force --keep --rsyncable"
                                                   & level_Flag
                                                   & " " & (+the_Path));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;

         when Bz2 =>
            declare
               Output : constant String := run_OS (  "bzip2 --force --keep"
                                                   & level_Flag
                                                   & " " & (+the_Path));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;

         when Xz =>
            declare
               Output : constant String := run_OS ("xz --force --keep --threads=0 " & (+the_Path));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;
      end case;
   end compress;


   procedure decompress (Name : in File)
   is
      use lace.Environ.OS_Commands;
   begin
      check (Name);

      declare
         use ada.Strings.fixed;

         the_Format : constant compress_Format := (if    Tail (+Name, 4) = ".tar"     then Tar
                                                   elsif Tail (+Name, 8) = ".tar.bz2" then Tar_Bz2
                                                   elsif Tail (+Name, 7) = ".tar.gz"
                                                      or Tail (+Name, 4) = ".tgz"     then Tar_Gz
                                                   elsif Tail (+Name, 7) = ".tar.xz"  then Tar_Xz
                                                   elsif Tail (+Name, 3) = ".gz"      then Gz
                                                   elsif Tail (+Name, 4) = ".bz2"     then Bz2
                                                   elsif Tail (+Name, 3) = ".xz"      then Xz
                                                   else  raise Error with "Unknown decompress format: " & (+Name));
      begin
         case the_Format
         is
         when Tar |Tar_Bz2 | Tar_Gz | Tar_Xz =>
            declare
               Options : aliased constant String := (case the_Format
                                                     is
                                                        when Tar     => "-xf",
                                                        when Tar_Bz2 => "-xjf",
                                                        when Tar_Gz  => "-xzf",
                                                        when Tar_Xz  => "-xJf",
                                                        when others  => raise program_Error);
               Output  : constant String := run_OS ("tar " & Options & " " & (+Name));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;

         when Gz =>
            declare
               Output : constant String := run_OS ("gunzip --force --keep " & (+Name));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;

         when Bz2 =>
            declare
               Output : constant String := run_OS ("bunzip2 --force --keep " & (+Name));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;

         when Xz =>
            declare
               Output : constant String := run_OS ("xz --decompress --force --keep " & (+Name));
            begin
               if Output /= ""
               then
                  raise Error with Output;
               end if;
            end;
         end case;
      end;

   end decompress;


   function format_Suffix (Format : compress_Format) return String
   is
   begin
      case Format
      is
         when Tar     =>   return ".tar";
         when Tar_Bz2 =>   return ".tar.bz2";
         when Tar_Gz  =>   return ".tar.gz";
         when Tar_Xz  =>   return ".tar.xz";
         when Bz2     =>   return ".bz2";
         when Gz      =>   return ".gz";
         when Xz      =>   return ".xz";
      end case;
   end format_Suffix;


end lace.Environ.Paths;