1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2000-2003 --
-- ACT-Europe --
-- --
-- Authors: Dmitriy Anisimkov - Pascal Obry --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
------------------------------------------------------------------------------
-- $Id: aws-status-set.adb,v 1.1 2003/10/05 20:00:01 Jano Exp $
with Ada.Characters.Handling;
with Ada.Exceptions;
with Ada.Strings.Fixed;
with AWS.Headers.Set;
with AWS.Headers.Values;
with AWS.Messages;
with AWS.Translator;
with AWS.Parameters.Set;
package body AWS.Status.Set is
use Ada.Strings;
procedure Authorization (D : in out Data);
-- Parse the Authorization parameters from the Authorization header value.
procedure Update_Data_From_Header (D : in out Data);
-- Update some Data fields from the internal Data header container.
-- The Update_Data_From_Header should be called after the complete
-- header parsing.
-------------------
-- Authorization --
-------------------
procedure Authorization (D : in out Data) is
Header_Value : constant String
:= AWS.Headers.Get (D.Header, Messages.Authorization_Token);
procedure Named_Value (Name, Value : in String; Quit : in out Boolean);
procedure Value (Item : in String; Quit : in out Boolean);
-----------------
-- Named_Value --
-----------------
procedure Named_Value
(Name, Value : in String;
Quit : in out Boolean)
is
type Digest_Attribute
is (Username, Realm, Nonce, NC, CNonce,
QOP, URI, Response, Algorithm);
-- The enumeration type is using to be able to
-- use the name in the case statement.
-- The case statement has usially faster implementation.
Attribute : Digest_Attribute;
function "+"
(Item : in String)
return Unbounded_String
renames To_Unbounded_String;
begin
begin
Attribute := Digest_Attribute'Value (Name);
exception
when Constraint_Error =>
-- Ignoring unrecognized attribute
return;
end;
-- Check if the attributes is for the Digest authenticatio schema.
-- AWS does not support othe authentication schemas with attributes
-- now.
if D.Auth_Mode /= Digest then
Quit := True;
end if;
case Attribute is
when Username => D.Auth_Name := +Value;
when Realm => D.Auth_Realm := +Value;
when NC => D.Auth_NC := +Value;
when CNonce => D.Auth_CNonce := +Value;
when QOP => D.Auth_QOP := +Value;
when Nonce => D.Auth_Nonce := +Value;
when Response => D.Auth_Response := +Value;
when URI => D.URI
:= URL.Parse (Value, False, False);
when Algorithm =>
if Value /= "MD5" then
Ada.Exceptions.Raise_Exception
(Constraint_Error'Identity,
"Only MD5 algorithm is supported.");
end if;
end case;
end Named_Value;
-----------
-- Value --
-----------
procedure Value (Item : in String; Quit : in out Boolean) is
Upper_Item : constant String
:= Ada.Characters.Handling.To_Upper (Item);
begin
if Upper_Item = "BASIC" then
D.Auth_Mode := Basic;
Quit := True;
-- We could not continue to parse Basic authentication
-- by the regular way, becouse next value is Base64
-- encoded username:password, it is possibe to be
-- symbol '=' there, our parser could
-- think that it is name/value delimiter.
declare
use Ada.Streams;
Auth_Str : constant String
:= Translator.To_String (Translator.Base64_Decode
(Header_Value (Item'Length + 2 .. Header_Value'Last)));
Delimit : constant Natural := Fixed.Index (Auth_Str, ":");
begin
if Delimit = 0 then
D.Auth_Name := To_Unbounded_String (Auth_Str);
else
D.Auth_Name
:= To_Unbounded_String (Auth_Str (1 .. Delimit - 1));
D.Auth_Password
:= To_Unbounded_String
(Auth_Str (Delimit + 1 .. Auth_Str'Last));
end if;
end;
elsif Upper_Item = "DIGEST" then
D.Auth_Mode := Digest;
end if;
end Value;
procedure Parse is new Headers.Values.Parse (Value, Named_Value);
begin
Parse (Header_Value);
end Authorization;
------------
-- Binary --
------------
procedure Binary
(D : in out Data;
Parameter : in Stream_Element_Array) is
begin
D.Binary_Data := new Stream_Element_Array'(Parameter);
end Binary;
----------
-- Free --
----------
procedure Free (D : in out Data) is
begin
Utils.Free (D.Binary_Data);
AWS.Parameters.Set.Free (D.Parameters);
AWS.Headers.Set.Free (D.Header);
end Free;
----------------
-- Keep_Alive --
----------------
procedure Keep_Alive
(D : in out Data;
Flag : in Boolean) is
begin
D.Keep_Alive := Flag;
end Keep_Alive;
----------------
-- Parameters --
----------------
procedure Parameters (D : in out Data; Set : in AWS.Parameters.List) is
begin
D.Parameters := Set;
end Parameters;
-------------
-- Payload --
-------------
procedure Payload
(D : in out Data;
Payload : in String) is
begin
D.Payload := To_Unbounded_String (Payload);
end Payload;
--------------
-- Peername --
--------------
procedure Peername
(D : in out Data;
Peername : in String) is
begin
D.Peername := To_Unbounded_String (Peername);
end Peername;
-----------------
-- Read_Header --
-----------------
procedure Read_Header
(Socket : in Net.Socket_Type'Class;
D : in out Data) is
begin
Headers.Set.Read (Socket, D.Header);
Update_Data_From_Header (D);
end Read_Header;
-------------
-- Request --
-------------
procedure Request
(D : in out Data;
Method : in Request_Method;
URI : in String;
HTTP_Version : in String) is
begin
D.Method := Method;
D.URI := URL.Parse (URI, False, False);
D.HTTP_Version := To_Unbounded_String (HTTP_Version);
end Request;
-----------
-- Reset --
-----------
procedure Reset (D : in out Data) is
begin
Utils.Free (D.Binary_Data);
D.Method := GET;
D.HTTP_Version := Null_Unbounded_String;
D.Content_Length := 0;
D.Auth_Mode := None;
D.Auth_Name := Null_Unbounded_String;
D.Auth_Password := Null_Unbounded_String;
D.Auth_Realm := Null_Unbounded_String;
D.Auth_Nonce := Null_Unbounded_String;
D.Auth_NC := Null_Unbounded_String;
D.Auth_CNonce := Null_Unbounded_String;
D.Auth_QOP := Null_Unbounded_String;
D.Auth_Response := Null_Unbounded_String;
D.Session_ID := AWS.Session.No_Session;
D.Session_Created := False;
AWS.Parameters.Set.Reset (D.Parameters);
AWS.Headers.Set.Reset (D.Header);
end Reset;
-------------
-- Session --
-------------
procedure Session
(D : in out Data) is
begin
D.Session_ID := AWS.Session.Create;
D.Session_Created := True;
end Session;
------------
-- Socket --
------------
procedure Socket
(D : in out Data;
Sock : in Net.Socket_Access) is
begin
D.Socket := Sock;
end Socket;
-----------------------------
-- Update_Data_From_Header --
-----------------------------
procedure Update_Data_From_Header (D : in out Data) is
begin
Authorization (D);
declare
Content_Length : String := AWS.Headers.Get
(D.Header, Messages.Content_Length_Token);
begin
if Content_Length /= "" then
D.Content_Length := Integer'Value (Content_Length);
end if;
end;
D.SOAP_Action := AWS.Headers.Exist (D.Header, Messages.SOAPAction_Token);
declare
use AWS.Headers;
Cookies_Set : constant VString_Array
:= Get_Values (D.Header, Messages.Cookie_Token);
begin
for Idx in Cookies_Set'Range loop
declare
-- The expected Cookie line is:
-- Cookie: ... AWS=<cookieID>[,;] ...
use type AWS.Session.ID;
procedure Value
(Item : in String;
Quit : in out Boolean);
-- Called for every un-named value read from the header value
procedure Named_Value
(Name : in String;
Value : in String;
Quit : in out Boolean);
-- Called for every named value read from the header value
-----------------
-- Named_Value --
-----------------
procedure Named_Value
(Name : in String;
Value : in String;
Quit : in out Boolean) is
begin
-- Check if it is AWS Cookie.
if Name /= "AWS" then
return;
end if;
D.Session_ID := AWS.Session.Value (Value);
-- Check if the cookie value was correct.
if D.Session_ID = AWS.Session.No_Session then
return;
end if;
-- Check if cookie exists in the server.
if not AWS.Session.Exist (D.Session_ID) then
-- Reset to empty cookie if session does not exists.
-- We are not interested by non existing values.
D.Session_ID := AWS.Session.No_Session;
return;
end if;
-- If all filters done, we found our cookie !
Quit := True;
end Named_Value;
-----------
-- Value --
-----------
procedure Value
(Item : in String;
Quit : in out Boolean)
is
pragma Warnings (Off, Item);
pragma Warnings (Off, Quit);
begin
-- Just ignore for now.
-- We are looking only for AWS=<cookieID>
null;
end Value;
-----------
-- Parse --
-----------
procedure Parse is
new AWS.Headers.Values.Parse (Value, Named_Value);
begin
Parse (To_String (Cookies_Set (Idx)));
-- exit when we found existing cookie.
exit when D.Session_ID /= AWS.Session.No_Session;
end;
end loop;
end;
end Update_Data_From_Header;
end AWS.Status.Set;
|