aaa_0.2.6_dfd6339b/src/aaa-caches-files.adb

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
package body AAA.Caches.Files is

   -------------
   -- Discard --
   -------------

   overriding
   procedure Discard (This : in out Cache) is
   begin
      This.Data := (Valid => False);
   end Discard;

   -------------
   -- Element --
   -------------

   function Element (This     : in out Cache;
                     Filename : String)
                     return Cached is

      use type Ada.Calendar.Time;
      use type Ada.Directories.File_Size;

      function Unchanged return Boolean
      is (This.Data.Valid and then
          This.Data.Size = Ada.Directories.Size (Filename) and then
          This.Data.Time = Ada.Directories.Modification_Time (Filename));

   begin
      if This.Has_Element and then Unchanged then
         return This.Data.Value;
      else
         This.Data :=
           (Valid => True,
            Size  => Ada.Directories.Size (Filename),
            Time  => Ada.Directories.Modification_Time (Filename),
            Value => Load (Filename));

         return This.Data.Value;
      end if;
   end Element;

   ---------
   -- Set --
   ---------

   procedure Set (This     : in out Cache;
                  Value    : Cached;
                  Filename : String)
   is
   begin
      Write (Value, Filename);
      This.Data :=
        (Valid => True,
         Size  => Ada.Directories.Size (Filename),
         Time  => Ada.Directories.Modification_Time (Filename),
         Value => Load (Filename));
   end Set;

end AAA.Caches.Files;