1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302 | ------------------------------------------------------------------------------
-- Language Server Protocol --
-- --
-- Copyright (C) 2018-2020, AdaCore --
-- --
-- This is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 3, or (at your option) any later ver- --
-- sion. This software is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public --
-- License for more details. You should have received a copy of the GNU --
-- General Public License distributed with this software; see file --
-- COPYING3. If not, go to http://www.gnu.org/licenses for a complete copy --
-- of the license. --
------------------------------------------------------------------------------
with Spawn.Processes.Monitor;
with Spawn.Posix;
with GNAT.OS_Lib;
with Interfaces.C;
package body Spawn.Processes is
function Errno return Interfaces.C.int;
-- return errno, number of last error
---------------
-- Arguments --
---------------
function Arguments (Self : Process'Class)
return Spawn.String_Vectors.UTF_8_String_Vector is
begin
return Self.Arguments;
end Arguments;
--------------------------
-- Close_Standard_Error --
--------------------------
procedure Close_Standard_Error (Self : in out Process'Class) is
begin
Monitor.Enqueue ((Monitor.Close_Pipe, Self'Unchecked_Access, Stderr));
end Close_Standard_Error;
--------------------------
-- Close_Standard_Input --
--------------------------
procedure Close_Standard_Input (Self : in out Process'Class) is
begin
Monitor.Enqueue ((Monitor.Close_Pipe, Self'Unchecked_Access, Stdin));
end Close_Standard_Input;
---------------------------
-- Close_Standard_Output --
---------------------------
procedure Close_Standard_Output (Self : in out Process'Class) is
begin
Monitor.Enqueue ((Monitor.Close_Pipe, Self'Unchecked_Access, Stdout));
end Close_Standard_Output;
-----------------
-- Environment --
-----------------
function Environment
(Self : Process'Class)
return Spawn.Environments.Process_Environment is
begin
return Self.Environment;
end Environment;
-----------
-- Errno --
-----------
function Errno return Interfaces.C.int is
begin
return Interfaces.C.int (GNAT.OS_Lib.Errno);
end Errno;
---------------
-- Exit_Code --
---------------
function Exit_Code (Self : Process'Class) return Integer is
begin
return Self.Exit_Code;
end Exit_Code;
--------------
-- Finalize --
--------------
overriding procedure Finalize (Self : in out Process) is
begin
if Self.Status /= Not_Running then
raise Program_Error;
end if;
end Finalize;
--------------
-- Listener --
--------------
function Listener (Self : Process'Class) return Process_Listener_Access is
begin
return Self.Listener;
end Listener;
-------------
-- Program --
-------------
function Program (Self : Process'Class) return UTF_8_String is
begin
return Ada.Strings.Unbounded.To_String (Self.Program);
end Program;
-------------------------
-- Read_Standard_Error --
-------------------------
procedure Read_Standard_Error
(Self : in out Process'Class;
Data : out Ada.Streams.Stream_Element_Array;
Last : out Ada.Streams.Stream_Element_Offset)
is
use type Ada.Streams.Stream_Element_Offset;
use type Interfaces.C.int;
use type Interfaces.C.size_t;
Count : constant Interfaces.C.size_t :=
Posix.read (Self.pipe (Stderr), Data, Data'Length);
begin
if Count = Interfaces.C.size_t'Last then
if Errno in Posix.EAGAIN | Posix.EINTR then
Last := Data'First - 1;
Monitor.Enqueue
((Monitor.Watch_Pipe, Self'Unchecked_Access, Stderr));
else
raise Program_Error with
"read error: " & GNAT.OS_Lib.Errno_Message;
end if;
else
Last := Data'First + Ada.Streams.Stream_Element_Offset (Count) - 1;
end if;
end Read_Standard_Error;
--------------------------
-- Read_Standard_Output --
--------------------------
procedure Read_Standard_Output
(Self : in out Process'Class;
Data : out Ada.Streams.Stream_Element_Array;
Last : out Ada.Streams.Stream_Element_Offset)
is
use type Ada.Streams.Stream_Element_Offset;
use type Interfaces.C.int;
use type Interfaces.C.size_t;
Count : constant Interfaces.C.size_t :=
Posix.read (Self.pipe (Stdout), Data, Data'Length);
begin
if Count = Interfaces.C.size_t'Last then
if Errno in Posix.EAGAIN | Posix.EINTR then
Last := Data'First - 1;
Monitor.Enqueue
((Monitor.Watch_Pipe, Self'Unchecked_Access, Stdout));
else
raise Program_Error with
"read error: " & GNAT.OS_Lib.Errno_Message;
end if;
else
Last := Data'First + Ada.Streams.Stream_Element_Offset (Count) - 1;
end if;
end Read_Standard_Output;
-------------------
-- Set_Arguments --
-------------------
procedure Set_Arguments
(Self : in out Process'Class;
Arguments : Spawn.String_Vectors.UTF_8_String_Vector) is
begin
Self.Arguments := Arguments;
end Set_Arguments;
---------------------
-- Set_Environment --
---------------------
procedure Set_Environment
(Self : in out Process'Class;
Environment : Spawn.Environments.Process_Environment) is
begin
Self.Environment := Environment;
end Set_Environment;
------------------
-- Set_Listener --
------------------
procedure Set_Listener
(Self : in out Process'Class;
Listener : Process_Listener_Access)
is
begin
Self.Listener := Listener;
end Set_Listener;
-----------------
-- Set_Program --
-----------------
procedure Set_Program
(Self : in out Process'Class;
Program : UTF_8_String) is
begin
Self.Program := Ada.Strings.Unbounded.To_Unbounded_String (Program);
end Set_Program;
---------------------------
-- Set_Working_Directory --
---------------------------
procedure Set_Working_Directory
(Self : in out Process'Class;
Directory : UTF_8_String) is
begin
Self.Directory := Ada.Strings.Unbounded.To_Unbounded_String (Directory);
end Set_Working_Directory;
-----------
-- Start --
-----------
procedure Start (Self : in out Process'Class) is
begin
Self.Status := Starting;
Self.Exit_Code := -1;
Monitor.Enqueue ((Monitor.Start, Self'Unchecked_Access));
end Start;
------------
-- Status --
------------
function Status (Self : Process'Class) return Process_Status is
begin
return Self.Status;
end Status;
-----------------------
-- Working_Directory --
-----------------------
function Working_Directory (Self : Process'Class) return UTF_8_String is
begin
return Ada.Strings.Unbounded.To_String (Self.Directory);
end Working_Directory;
--------------------------
-- Write_Standard_Input --
--------------------------
procedure Write_Standard_Input
(Self : in out Process'Class;
Data : Ada.Streams.Stream_Element_Array;
Last : out Ada.Streams.Stream_Element_Offset)
is
use type Ada.Streams.Stream_Element_Offset;
use type Interfaces.C.int;
use type Interfaces.C.size_t;
Count : constant Interfaces.C.size_t :=
Posix.write (Self.pipe (Stdin), Data, Data'Length);
begin
Last := Data'First - 1;
if Count = Interfaces.C.size_t'Last then
if Errno not in Posix.EAGAIN | Posix.EINTR then
raise Program_Error with
"write error: " & GNAT.OS_Lib.Errno_Message;
end if;
else
Last := Data'First + Ada.Streams.Stream_Element_Offset (Count) - 1;
end if;
if Count /= Data'Length then
Monitor.Enqueue
((Monitor.Watch_Pipe, Self'Unchecked_Access, Stdin));
end if;
end Write_Standard_Input;
end Spawn.Processes;
|