1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2007-2015, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under terms of the GNU General Public License as published by the --
-- Free Software Foundation; either version 3, or (at your option) any --
-- later version. This library is distributed in the hope that it will be --
-- useful, but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are --
-- granted additional permissions described in the GCC Runtime Library --
-- Exception, version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- As a special exception, if other files instantiate generics from this --
-- unit, or you link this unit with other files to produce an executable, --
-- this unit does not by itself cause the resulting executable to be --
-- covered by the GNU General Public License. This exception does not --
-- however invalidate any other reasons why the executable file might be --
-- covered by the GNU Public License. --
------------------------------------------------------------------------------
with Ada.Calendar;
with Ada.Containers.Hashed_Maps;
with AWS.Config;
with AWS.Utils.Streams;
package body AWS.Services.Web_Block.Context is
Max_Id_Deleted : constant := 100;
-- Maximum number of contexts deleted in one pass
function Hash (Key : Id) return Containers.Hash_Type;
type Context_Stamp is record
C : Object;
Created : Calendar.Time; -- used to delete when expired
end record;
package Contexts is new Containers.Hashed_Maps
(Id, Context_Stamp, Hash, "=");
-- Concurrent Database
protected Database is
procedure Clean;
-- Removes expired contexts
function Contains (CID : Id) return Boolean;
-- Returns True if context CID is in the database
function Get (CID : Id) return Object;
-- Retruns the context object
procedure Include (Context : Object; CID : Id)
with Post => Contains (CID);
-- Add or update context into the database
private
DB : Contexts.Map;
end Database;
--------------
-- Database --
--------------
protected body Database is
-----------
-- Clean --
-----------
procedure Clean is
use type Ada.Calendar.Time;
Now : constant Calendar.Time := Calendar.Clock;
Elapsed : constant Duration := Config.Context_Lifetime;
CIDS : array (1 .. Max_Id_Deleted) of Id;
Last : Natural := 0;
Position : Contexts.Cursor := DB.First;
begin
-- First check for obsolete context
while Contexts.Has_Element (Position) and then Last < CIDS'Last loop
if Now - Contexts.Element (Position).Created > Elapsed then
Last := Last + 1;
CIDS (Last) := Contexts.Key (Position);
end if;
Contexts.Next (Position);
end loop;
for K in CIDS'First .. Last loop
DB.Delete (CIDS (K));
end loop;
end Clean;
--------------
-- Contains --
--------------
function Contains (CID : Id) return Boolean is
begin
return DB.Contains (CID);
end Contains;
---------
-- Get --
---------
function Get (CID : Id) return Object is
begin
if DB.Contains (CID) then
return DB.Element (CID).C;
else
return Empty;
end if;
end Get;
-------------
-- Include --
-------------
procedure Include (Context : Object; CID : Id) is
begin
Clean;
-- Register new context
DB.Include (CID, Context_Stamp'(Context, Calendar.Clock));
end Include;
end Database;
-----------
-- Exist --
-----------
function Exist (Context : Object; Name : String) return Boolean is
begin
return Context.Contains (Name);
end Exist;
function Exist (CID : Id) return Boolean is
begin
return Database.Contains (CID);
end Exist;
---------
-- Get --
---------
function Get (CID : Id) return Object is
begin
return Database.Get (CID);
end Get;
---------------
-- Get_Value --
---------------
function Get_Value (Context : Object; Name : String) return String is
begin
if Context.Contains (Name) then
return Context.Element (Name);
else
return "";
end if;
end Get_Value;
----------
-- Hash --
----------
function Hash (Key : Id) return Containers.Hash_Type is
begin
return Strings.Hash (String (Key));
end Hash;
-----------
-- Image --
-----------
function Image (CID : Id) return String is
begin
return String (CID);
end Image;
--------------
-- Register --
--------------
function Register (Context : Object) return Id is
Stream : aliased Utils.Streams.SHA1;
CID : Id;
begin
Object'Output (Stream'Access, Context);
CID := Id (Utils.Streams.Value (Stream'Access));
Database.Include (Context, CID);
return CID;
end Register;
------------
-- Remove --
------------
procedure Remove (Context : in out Object; Name : String) is
begin
Context.Exclude (Name);
end Remove;
---------------
-- Set_Value --
---------------
procedure Set_Value (Context : in out Object; Name, Value : String) is
begin
Context.Include (Name, Value);
end Set_Value;
-----------
-- Value --
-----------
function Value (CID : String) return Id is
begin
if CID'Length = Id'Length then
return Id (CID);
else
return Id'(others => 'x');
end if;
end Value;
------------------
-- Generic_Data --
------------------
package body Generic_Data is
---------------
-- Get_Value --
---------------
function Get_Value (Context : Object; Name : String) return Data is
Position : constant KV.Cursor := Context.Find (Name);
begin
if KV.Has_Element (Position) then
declare
Result : constant String := KV.Element (Position);
Str : aliased Utils.Streams.Strings;
Value : Data;
begin
Utils.Streams.Open (Str, Result);
Data'Read (Str'Access, Value);
return Value;
end;
else
return Null_Data;
end if;
end Get_Value;
---------------
-- Set_Value --
---------------
procedure Set_Value
(Context : in out Object;
Name : String;
Value : Data)
is
Str : aliased Utils.Streams.Strings;
begin
Data'Write (Str'Access, Value);
Context.Include (Name, Utils.Streams.Value (Str'Access));
end Set_Value;
end Generic_Data;
end AWS.Services.Web_Block.Context;
|